AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Multimedia Delphi Bei TImage Bild wechseln, wenn mit Maus darüber

Bei TImage Bild wechseln, wenn mit Maus darüber

Ein Thema von Dagon · begonnen am 21. Dez 2003 · letzter Beitrag vom 21. Dez 2003
Antwort Antwort
Dagon

Registriert seit: 13. Jul 2003
505 Beiträge
 
Delphi 7 Professional
 
#1

Bei TImage Bild wechseln, wenn mit Maus darüber

  Alt 21. Dez 2003, 12:30
Ich habe eine TImage-Kompo auf meiner Form. In der Komponente ist ein Bild geladen. Wenn ich nun mit der Maus darauf bin (auf der TImage-Kompo) soll ein anderes Bild angezeigt werden und wenn ich mit der Maus wider weg gehe, soll wieder das ursprüngliche Bild gezeigt werden.
Wie kann ich das am besten realisieren, ohne jedesmal die Bitmaps aus einer File zu laden?
  Mit Zitat antworten Zitat
Nightshade

Registriert seit: 7. Jan 2003
Ort: Menden
192 Beiträge
 
Delphi 7 Enterprise
 
#2

Re: Bei TImage Bild wechseln, wenn mit Maus darüber

  Alt 21. Dez 2003, 12:48
Für den Zweck habe ich mir mal eine Komponente gebaut :

Delphi-Quellcode:
unit MyImage;

interface

uses
  SysUtils, Classes, Controls, ExtCtrls, Graphics, Messages;

type TMyImage =class(TImage)
  private
    FOnMouseEnter: TNotifyEvent;
    FOnMouseLeave: TNotifyEvent;
    FMLPic: TPicture;
    FMEPic: TPicture;
    procedure CMMouseEnter(var Message: TMessage); message CM_MOUSEENTER;
    procedure CMMouseLeave(var Message: TMessage); message CM_MOUSELEAVE;
    procedure SetMEPic(const Value: TPicture);
    procedure SetMLPic(const Value: TPicture);
  protected
  public
    constructor Create(AOwner : TComponent); override;
    destructor Destroy; override;
  published
    property OnMouseEnter : TNotifyEvent read FOnMouseEnter Write FOnMouseEnter;
    property OnMouseLeave : TNotifyEvent read FOnMouseLeave Write FOnMouseLeave;
    property MouseEnterPicture : TPicture read FMEPic write SetMEPic;
    property MouseLeavePicture : TPicture read FMLPic write SetMLPic;
end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Beispiele', [TMyImage]);
end;

{ TMyImage }

procedure TMyImage.CMMouseEnter(var Message: TMessage);
begin
  if Message.Msg=CM_MOUSEENTER then begin
    if csDesigning in ComponentState then begin
      if FMLPic <> NIL then picture.Assign(FMLPic);
    end
    else begin
      if FMEPic <> NIL then picture.Assign(FMEPic);
    end;
    if ( Assigned(FOnMouseEnter) ) then FOnMouseEnter(self);
    repaint;
  end;
end;

procedure TMyImage.CMMouseLeave(var Message: TMessage);
begin
  if Message.Msg=CM_MOUSELEAVE then begin
    if FMLPic <> NIL then picture.Assign(FMLPic);
    if ( Assigned(FOnMouseLeave) ) then FOnMouseLeave(self);
    repaint;
  end;
end;

constructor TMyImage.Create(AOwner: TComponent);
begin
  inherited;
  FMLPic := TPicture.Create;
  FMEPic := TPicture.Create;
end;

destructor TMyImage.Destroy;
begin
  FreeAndNil(FMLPic);
  FreeAndNil(FMEPic);
  inherited;
end;

procedure TMyImage.SetMEPic(const Value: TPicture);
begin
  FMEPic.Assign(Value);
end;

procedure TMyImage.SetMLPic(const Value: TPicture);
begin
  FMLPic.Assign(Value);
end;


end.
Villeicht hilft dir das weiter ...

------------------------

Nightshade
Christian
  Mit Zitat antworten Zitat
Dagon

Registriert seit: 13. Jul 2003
505 Beiträge
 
Delphi 7 Professional
 
#3

Re: Bei TImage Bild wechseln, wenn mit Maus darüber

  Alt 21. Dez 2003, 13:13
Zitat von Nightshade:
Villeicht hilft dir das weiter ...
Ja, das hat es!!! Danke!
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 22:23 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz