Bestimmtes Icon aus Shell32.dll laden

[Neutral General]

Zitat von OregonGhost:

Ich werfe nur mal dies ein:

When programs assume that the system will never change, episode 1

Fazit: Wenn's ein Ordner sein soll, kannst du dir das Icon des Ordners (oder eines beliebigen) mit SHGetFileInfo besorgen. Aber lieber nicht aus irgendeiner System-DLL klauen.

Ich assume eigentlich normalerweise nicht, dass das System will never change
Deswegen habe ich ursprünglich ja nach irgendwelchen Konstanten gefragt

Die Methode mit SHGetFileInfo funktioniert soweit ganz gut
Die Icons sehen nur nicht.. so schön aus.. Mein Code:

Delphi-Quellcode:

var ico: TIcon;
    fi: TSHFILEINFO;
    len: Cardinal;
begin
  ico := TIcon.Create;
  try
    len := SizeOf(TSHFILEINFO);
    FillChar(fi,len,0);
    SHGetFileInfo('C:\Windows',0,fi,len,SHGFI_ICON or SHGFI_SMALLICON);
    ico.Handle := fi.hIcon;
    imlTreeView.AddIcon(ico); // TImageList
  finally
    ico.Free;
  end;
end;

Keine Angst - Das 'C:\Windows' ist nur testweise

[OregonGhost]

Was heißt denn das, sie sehen nicht so schön aus? Fehlt die Transparenz? Falsche Farbtiefe? Unscharf?

[Mithrandir]

Zitat von Neutral General:

Deswegen habe ich ursprünglich ja nach irgendwelchen Konstanten gefragt

Konstanten sind och nix anderes als Zahlen, die ins Programm einkompilliert werden.

Es gibt sie aber, imho habe ich sie in der MSDN mal gesehen... Erinnere mich nur gerade nicht mehr an die passenden Suchbegriffe...

[OregonGhost]

Es gibt Konstanten für die ganzen MessageBox-Icons und so, aber ich glaube nicht für die Shell. Kann mich natürlich irren.

Zum Thema: Mir fiel gerade noch auf, du könntest bei SHGetFileInfo ja mal SHGFI_ICONLOCATION übergeben, mit den Informationen müsstest du das Icon ja selbst laden können. Vielleicht hast du dann mehr Kontrolle über Auflösung, Farbtiefe und so weiter.

[Neutral General]

Siehe Anhang.

Edit:

Zitat von OregonGhost:

Es gibt Konstanten für die ganzen MessageBox-Icons und so, aber ich glaube nicht für die Shell. Kann mich natürlich irren.

Zum Thema: Mir fiel gerade noch auf, du könntest bei SHGetFileInfo ja mal SHGFI_ICONLOCATION übergeben, mit den Informationen müsstest du das Icon ja selbst laden können. Vielleicht hast du dann mehr Kontrolle über Auflösung, Farbtiefe und so weiter.

Ich habe es ja vorher selbst geladen. Da sah es aber genauso aus.

[wicht]

SHGetFileInfo('C:\Windows',0,fi,len,SHGFI_ICON or SHGFI_SMALLICON); Der Aufruf führt glaube ich nicht immer zum Ziel, weil man ja auch Eigene Ordner-Icons (z.B. mit Hilfe des Explorers in den Ordnereigenschaften) setzen kann. Es gibt da noch ein Flag für, SHGFI_USEFILEATTRIBUTES, ich könnte mir vorstellen, dass das für Abhilfe sorgt. Wollte nur drauf hinweisen...

[Neutral General]

Zitat von wicht:

SHGetFileInfo('C:\Windows',0,fi,len,SHGFI_ICON or SHGFI_SMALLICON); Der Aufruf führt glaube ich nicht immer zum Ziel, weil man ja auch Eigene Ordner-Icons (z.B. mit Hilfe des Explorers in den Ordnereigenschaften) setzen kann. Es gibt da noch ein Flag für, SHGFI_USEFILEATTRIBUTES, ich könnte mir vorstellen, dass das für Abhilfe sorgt. Wollte nur drauf hinweisen...

Hi,

Wenn ich dieses Flag setze, bekomme ich ein falsches Icon. Also im Moment hat diese Methode 2 Nachteile:

1. SHGetFileInfo braucht ziemlich lange!
2. Das Icon sieht nicht so schön aus..

wenn noch jemand ne Idee hat wäre das super.

[wicht]

Mal zuhause eingewählt, das hier habe ich gefunden. Ich benutze ein TListView, um die Icons anzuzeigen, und die sehen eigentlich alle ganz cremig aus. Vielleicht hilft das noch (obwohl es genau so aussieht wie dein Code...), ansonsten bin ich raus...

Delphi-Quellcode:

unit IconManager;

interface

uses
  Windows, SysUtils, Controls, ShellApi, Generics.Collections, Functions;

type
  TIconManager = class
  private
    FDirIndex: Integer;
    FImages: TImageList;
    FData: TDictionary<string, Integer>;
    function FGetIconIndex(Extension: string): Integer;
  public
    constructor Create;
    destructor Destroy; override;
    property DirIndex: Integer read FDirIndex;
    property Images: TImageList read FImages;
    property Icon[Extension: string]: Integer read FGetIconIndex;
  end;

implementation

{ TIconManager }

constructor TIconManager.Create;
var
  SysIL: uint;
  SFI: TSHFileInfoW;
begin
  FData := TDictionary<string, Integer>.Create();
  FImages := TImageList.Create(nil);
  SysIL := SHGetFileInfoW('', 0, SFI, SizeOf(SFI), SHGFI_ICON or SHGFI_SMALLICON or SHGFI_SYSICONINDEX);
  if SysIL <> 0 then
  begin
    FImages.Handle := SysIL;
  end;

  SHGetFileInfoW(PChar(GetSystemDir), 0, SFI, SizeOf(TSHFileInfoW), SHGFI_ICON or SHGFI_SMALLICON);
  FDirIndex := SFI.iIcon;
end;

destructor TIconManager.Destroy;
begin
  FImages.Free;
  FData.Free;
  inherited;
end;

function TIconManager.FGetIconIndex(Extension: string): Integer;
var
  SFI: TSHFileInfoW;
begin
  if not FData.ContainsKey(Extension) then
  begin
    SHGetFileInfoW(PChar(Extension), 0, SFI, SizeOf(TSHFileInfoW), SHGFI_ICON or SHGFI_SMALLICON or SHGFI_USEFILEATTRIBUTES);
    FData.Add(Extension, SFI.iIcon);
  end;
  Result := FData[Extension];
end;

end.

[Neutral General]

@wicht: Danke, das hat mir geholfen

[wicht]

Danke für die Rückmeldung
Dann mal ein schönes Wochenende ...