AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Code-Bibliothek Neuen Beitrag zur Code-Library hinzufügen Delphi Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

Ein Thema von Luckie · begonnen am 8. Mär 2010 · letzter Beitrag vom 8. Nov 2016
Antwort Antwort
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#1

Drag & Drop vom Explorer auf unterschiedliche Steuerelem

  Alt 8. Mär 2010, 09:41
Mit folgendem Beispiel kann man Dateien aus dem Explorer auf unterschiedliche Steuerelemente seines Formulares ziehen:
Delphi-Quellcode:
unit Unit6;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm6 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure AppMessage(var Msg: Tmsg; var Handled: Boolean);
    function IsDropPointInside(const aDropPoint: TPoint; const aControl: TControl): Boolean;
  public
    { Public-Deklarationen }
  end;

var
  Form6: TForm6;

implementation

{$R *.dfm}

uses
  ShellAPI;

procedure TForm6.AppMessage(var Msg: Tmsg; var Handled: Boolean);
const
  BufferLength: word = 255;
var
  DroppedFilename: string;
  FileIndex: Word;
  QtyDroppedFiles: Word;
  pDroppedFilename: array[0..255] of Char;
  DropPoint: TPoint;
begin
  if Msg.Message = WM_DROPFILES then
  begin
    FileIndex := $FFFF;
    QtyDroppedFiles := DragQueryFile(Msg.WParam, FileIndex, pDroppedFilename, BufferLength);
    for FileIndex := 0 to (QtyDroppedFiles - 1) do
    begin
      DragQueryFile(Msg.WParam, FileIndex, pDroppedFilename, BufferLength);
      DroppedFilename := StrPas(pDroppedFilename);
      DropPoint := Msg.pt;
      if IsDropPointInside(DropPoint, Edit1) then
        Edit1.Text := DroppedFilename
      else if IsDropPointInside(DropPoint, Edit2) then
        Edit2.Text := DroppedFilename;
    end;
    DragFinish(Msg.WParam);
    Handled := true;
  end;
end;

procedure TForm6.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Edit1.Handle, true);
  DragAcceptFiles(Edit2.Handle, true);
  Application.OnMessage := AppMessage;
end;

function TForm6.IsDropPointInside(const aDropPoint: TPoint; const aControl: TControl): Boolean;
begin
  Result := PtInRect(aControl.ClientRect, aControl.ScreenToClient(aDropPoint));
end;

end.
Danke auch an Dezipaitor für seine Hilfe.

Stichwörter: WM_DROPPFILES, Drag and drop, DragAcceptFiles
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu
Online

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.013 Beiträge
 
Delphi 12 Athens
 
#2

Re: Drag & Drop vom Explorer auf unterschiedliche Steuer

  Alt 8. Mär 2010, 10:20
Zitat:
FileIndex := $FFFF;
MSDN
If the value of this parameter is 0xFFFFFFFF


Und es sollte erwähnt werden, daß Application.OnMessage überschrieben wird (falls dieses wer übersieht) und in seinem Programm selber dort schon etwas Anderes zugewiesen hat, bzw. noch zuweisen tut.

Delphi-Quellcode:
type
  TForm1 = class(TForm)
    procedure AppMessage(var Msg: TMsg; var Handled: Boolean);
  end;

uses
  ShellAPI;

procedure TForm1.AppMessage(var Msg: TMsg; var Handled: Boolean);
const
  BufferLength = 255;
var
  QtyDroppedFiles, FileIndex: Integer; // eigentlich Cardinal, aber für ein sicheres
                                        // Beenden der For-Schleife, bei QtyDroppedFiles=0
  pDroppedFilename: array[0..BufferLength] of Char;
begin
  if Msg.message = WM_DROPFILES then
  begin
    QtyDroppedFiles := DragQueryFile(Msg.wParam, Cardinal(-1), nil, 0);
    try
      for FileIndex := 0 to QtyDroppedFiles - 1 do
      begin
        DragQueryFile(Msg.wParam, FileIndex, @pDroppedFilename, BufferLength);
        if Msg.hwnd = Edit1.Handle then
          Edit1.Text := PChar(@pDroppedFilename)
        else if Msg.hwnd = Edit2.Handle then
          Edit2.Text := PChar(@pDroppedFilename);
      end;
    finally
      DragFinish(Msg.wParam);
      Handled := True;
    end;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Edit1.Handle, True);
  DragAcceptFiles(Edit2.Handle, True);
  Application.OnMessage := AppMessage;
end;
PS: bei Windows 7 und einer Anwendung mit Admin-Rechten geht dieses vom "normalen" Explorer nicht mehr.

Da man nur noch Messages zu Anwendungen mit gleichen oder geringeren Rechten verschicken darf,
also müßte da z.B. der Explorer auch mit Admin-Rechten gestartet sein.

PSS: mit "Explorer" ist übrigen vieles gemeint ... der Desktop, der Explorer, die Dateilisten von Open-/Savedialogen ... also alles worin sich ein Explorer versteckt oder welches die hierfür nötigen Messages/Speicherbereiche erstellt.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#3

Re: Drag & Drop vom Explorer auf unterschiedliche Steuer

  Alt 8. Mär 2010, 10:25
Jupp, eigentlich Cardinal, aber dann bekommt man für die for-Schleife eine Warnung, deswegen Integer.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Jim Carrey
(Gast)

n/a Beiträge
 
#4

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 16:12
Darf ich diesen Thread mal ausgraben und eine Frage stellen?

Der Code hier beinhaltet Folgendes im FormCreate
Delphi-Quellcode:
//
DragAcceptFiles(Edit1.Handle, True);
Einige schreiben Folgendes im FormDestroy zusätzlich
Delphi-Quellcode:
//
DragAcceptFiles(Edit1.Handle, False);
Ist es im FormDestroy notwendig zu sagen, dass Drag&Drop jetzt vorbei ist? Ich meine... die Anwendung wird doch eh beendet.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu
Online

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.013 Beiträge
 
Delphi 12 Athens
 
#5

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 17:37
Wer sagt, dass die Anwendung beendet wird, nur weil "eine" Form geschlossen/freigegeben wird?

Nee, es wäre nicht nötig, denn wenn das Handle (HWND) gelöscht wird, dann ist auch das daran aktivierte Drag&Drop mit weg.
Aber wer verbietet es dir, dennoch brav aufzuräumen? (siehe meine Signatur und RAM gibt man doch auch ordentlich frei, obwohl Windows das beim Programmende ebenfalls macht)

Nein, sowas kommt nicht (nur) ins FormCreate oder Create rein, sondern in CreateWnd, wenn es direkt an der Form hängt. Bei Subcontrols isses eventuell bissl schwerer.
Ansonsten darf man auch noch mit CM_RECREATEWND und Dergleichen rumkämpfen, denn werden die internen Controls freigegeben und später wieder neu erstellt, dann ist dieses auch weg.
Und sowas passiert gern, wenn man z.B. nach dem DragAcceptFiles(True) an TopMost und am Fensterrahmen rumspielt, wobei wofür Fenster neu generiert wird,
oder wenn man das Fenster minimiert oder ausblendet (Hide), denn was man nicht sieht, muß nicht unbedingt sinnlos Speicher/Handles belegen, weswegen man es dann doch auch freigeben könnte.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu ( 8. Nov 2016 um 17:42 Uhr)
  Mit Zitat antworten Zitat
Jim Carrey
(Gast)

n/a Beiträge
 
#6

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 17:40
Nein, sowas kommt nicht ins FormCreate oder Create rein, sondern in CreateWnd, wenn es direkt an der Form hängt.
Mh?
Delphi-Quellcode:
procedure TForm1.FormCreate(Sender: TObject); // <==
begin
  DragAcceptFiles(Edit1.Handle, True);
  DragAcceptFiles(Edit2.Handle, True);
  Application.OnMessage := AppMessage;
end;
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu
Online

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.013 Beiträge
 
Delphi 12 Athens
 
#7

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 17:47
Ich hab ihn nochmal bissl ausgeschmückt, meinen Text.


Delphi-Quellcode:
procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Edit1.Handle, True);
  DragAcceptFiles(Edit2.Handle, True);
  Application.OnMessage := AppMessage;
  PopupMode := pmAuto; //BorderIcons := [biSystemMenu];
end;
Und jetzt sag mir, ob deine Edits immernoch Drag&Drop akzeptieren?
[edit] doch nicht BorderIcons ... da wird es nur bei MDI-Childs ausgelöst , aber auch durch anderen Aktionen wird Delphi-Referenz durchsuchenTWinControl.RecreateWnd ausgelöst.



Ach ja, noch was gaaaaaaanz Wichtiges .. Niemals Application.OnMessage verwenden, sondern Delphi-Referenz durchsuchenTApplicationEvents.OnMessage ,
denn wenn man das hier auf zwei Forms so macht, dann wird es nur bei einer Form funktionieren, da man das Application.OnMessage der ersten Form überschreibt.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu ( 8. Nov 2016 um 17:54 Uhr)
  Mit Zitat antworten Zitat
Jim Carrey
(Gast)

n/a Beiträge
 
#8

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 17:58
Zitat:
Ach ja, noch was gaaaaaaanz Wichtiges ..
Und wenn ich Application.OnMessage nur ein einziges Mal verwende, ist das dann OK so?

Zitat:
Und jetzt sag mir, ob deine Edits immernoch Drag&Drop akzeptieren?
Muss ich gleich mal austesten
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu
Online

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.013 Beiträge
 
Delphi 12 Athens
 
#9

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 19:01
Joar, ist es, aber in 10 Monaten hast du es vergessen und willst es nochmal für was Anderes benutzen.
Und ich wette du würdest Application.OnMessage nicht auf Assigned prüfen, vor der neuen Zuweisung.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von dummzeuch
dummzeuch

Registriert seit: 11. Aug 2012
Ort: Essen
1.449 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#10

AW: Drag & Drop vom Explorer auf unterschiedliche Steuerelemente

  Alt 8. Nov 2016, 20:04
Vielleicht auch eine Moeglichkeit:

Delphi-Quellcode:
///<summary>
/// Enables dropping of files (folders) from explorer to the given WinControl
/// @param WinCtrl is a TWinControl for which dropping should be enabled
/// @param Callback is a TOnFilesDropped event that is called when files are dropped on the control.
/// @returns the TDropFilesActivator instance created.
/// NOTE: You do not need to free this object! It will automatically be freed when the
/// TWinControl is destroyed. </summary>
function TWinControl_ActivateDropFiles(_WinCtrl: TWinControl; _Callback: TOnFilesDropped): TObject;
Fuer jedes Control wird exact ein Aufruf dieser Funktion benoetigt, und natuerlich ein Callback, der aufgerufen werden soll, wenn der User eine Datei auf das Control dropt. Der Rest passiert automatisch.

https://sourceforge.net/p/dzlib/code...Utils.pas#l936
Thomas Mueller
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:21 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz