AGB  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Zuweisung für Enums überladen

Ein Thema von Codewalker · begonnen am 12. Apr 2012 · letzter Beitrag vom 12. Apr 2012
Antwort Antwort
Benutzerbild von Codewalker
Codewalker

Registriert seit: 18. Nov 2005
Ort: Ratingen
945 Beiträge
 
Delphi XE2 Professional
 
#1

Zuweisung für Enums überladen

  Alt 12. Apr 2012, 12:43
Delphi-Version: XE2
Seit einigen Delphi-Versionen kann man ja Operatoren für eigene Datentypen überladen. Wie genau funktioniert das denn z.B. für Enums. Häufig möchte ich diese konvertieren (z.B. einen repräsentativen String, also nicht genau den Enum-Namen).
Beispiel wäre TFontStyle = (fsBold, fsItalic) und bei der Zuweisung zu einem String soll dann z.B. "fett" und "kursiv" herauskommen. Bisher habe ich immer eine Hilfsfunktion gemacht, die das per Case abhandelt, würde es aber lieber direkt über einen Operator abhandeln.
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
25.782 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#2

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 12:50
Reicht auch die Billig-Variante?
Delphi-Quellcode:
type
  TMyType = (mtOne, mtTwo, mtThree);

const
  MYTYPENAMES = array[TMyType] of string = ('Eins', 'Zwei', 'Drei');

function TypeAsString(aType: TMyType): string;
begin
  Result := MYTYPENAMES[aType];
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von Codewalker
Codewalker

Registriert seit: 18. Nov 2005
Ort: Ratingen
945 Beiträge
 
Delphi XE2 Professional
 
#3

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 12:57
Naja, nicht wirklich. Jetzt habe ich eine Funktion und dazu noch ein Array und kann die meisten Vorzüge der Überladung nicht nutzen. Ist ja das gleiche nur anders
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
25.782 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#4

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 12:59
Einen Versuch war es wert
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
31.036 Beiträge
 
Delphi XE3 Professional
 
#5

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 13:50
Operatoren gehen nur bei Records.
Record-Methoden (ähnlich wie bei Klassen) gibt es seit D2006 natürlich auch nur für Records.
Class Helper und Record Helper gibt es auch nur für Klassen und Records. (Interfaces weiß ich jetzt nicht)

Einfache Typen und Interfaces fehlen leider noch.


Die Übersetzungen könnte man über Attribute und die neue RTTI regeln.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von s.h.a.r.k
s.h.a.r.k

Registriert seit: 26. Mai 2004
Ort: Offingen
3.159 Beiträge
 
Delphi XE Professional
 
#6

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 14:26
@himitsu: Meintest du etwa sowas hier?!
Armin
»Remember, the future maintainer is the person you should be writing code for, not the compiler.« (Nick Hodges)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
31.036 Beiträge
 
Delphi XE3 Professional
 
#7

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 15:20
Jupp.

Delphi macht es zwar nicht automatisch, aber selbst kann man es schon machen.

Ich bastel mir grade ein paar Basicunits zusammen, für alle meine Projekte, inklusive eigener Typendefinitionen für Integer und Co.
Dort ist auch 'ne generische Typkonvertierung drin ... da würde sowas perfekt reinpasen.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Panthrax

Registriert seit: 18. Feb 2005
286 Beiträge
 
Delphi 2010 Enterprise
 
#8

AW: Zuweisung für Enums überladen

  Alt 12. Apr 2012, 20:50
Delphi-Quellcode:
program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TSomeEnum = (seOne, seTwo, seThree);

  TMyEnum = record
  strict private
    FValue: TSomeEnum;

    class function Translate(const Value: TSomeEnum): String; overload; static;
    class function Translate(const Value: String): TSomeEnum; overload; static;

  public
    class operator Implicit(const Value: String): TMyEnum;
    class operator Implicit(const Value: TMyEnum): String;
    class operator Implicit(const Value: TMyEnum): TSomeEnum;
    class operator Implicit(const Value: TSomeEnum): TMyEnum;
  end;

{ TMyEnum }

class operator TMyEnum.Implicit(const Value: TMyEnum): String;
begin
  Result := Translate(Value.FValue);
end;

class function TMyEnum.Translate(const Value: TSomeEnum): String;
begin
  case Value of
    seOne:
      Result := 'Eins';
    seTwo:
      Result := 'Zwei';
    seThree:
      Result := 'Drei';
  end;
end;

class operator TMyEnum.Implicit(const Value: String): TMyEnum;
begin
  Result.FValue := Translate(Value);
end;

class operator TMyEnum.Implicit(const Value: TSomeEnum): TMyEnum;
begin
  Result.FValue := Value;
end;

class operator TMyEnum.Implicit(const Value: TMyEnum): TSomeEnum;
begin
  Result := Value.FValue;
end;

class function TMyEnum.Translate(const Value: String): TSomeEnum;
begin
  if Value = 'Einsthen
    Result := seOne
  else
  if Value = 'Zweithen
    Result := seTwo
  else
  if Value = 'Dreithen
    Result := seThree
  else
    raise Exception.Create('Ungültiger Wert.');
end;

var
  MyEnum: TMyEnum;
  SomeEnum: TSomeEnum;
begin
  try
    SomeEnum := seTwo;
    MyEnum := SomeEnum;
    WriteLn('MyEnum: ' + MyEnum);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  ReadLn;
end.
Code:
MyEnum: Zwei
"Es gibt keine schlimmere Lüge als die Wahrheit, die von denen, die sie hören, missverstanden wird."
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 04:55 Uhr.
Powered by vBulletin® Copyright ©2000 - 2016, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2016 by Daniel R. Wolf