Hallo DPler,

ich möchte diese C++ Struktur nach Delphi übersetzen:

C++:

markieren

Code:

typedef struct {
  PARTITION_STYLE PartitionStyle;
     union {
     CREATE_DISK_MBR Mbr;
     CREATE_DISK_GPT Gpt;
    };
  } CREATE_DISK, *PCREATE_DISK;

...meine Übersetzung nach Delphi:

markieren

Delphi-Quellcode:

  _CREATE_DISK = packed record
    PartitionsStyle: PARTITION_STYLE;
    Mbr: CREATE_DISK_MBR;
    Gpt: CREATE_DISK_GPT;
  end;
  CREATE_DISK = _CREATE_DISK;
  PCREATE_DISK = ^CREATE_DISK;

Das sollte doch so funktionieren, oder?!
Oder wie soll ich diese "union structure" sonst nach Delphi übersetzen?

Danke für jeden Tipp!

zusammenfalten · markieren

Delphi-Quellcode:

  _CREATE_DISK = packed record
    PartitionsStyle: PARTITION_STYLE;
    case Integer of
      0: (Mbr: CREATE_DISK_MBR);
      1: (Gpt: CREATE_DISK_GPT);
  end;

  // oder

  _CREATE_DISK = packed record
    case PartitionsStyle: PARTITION_STYLE of
      0: (Mbr: CREATE_DISK_MBR);
      1: (Gpt: CREATE_DISK_GPT);
  end;
  // statt 0 und 1 besser die "korrekten" Werte einsetzen oder gar die passenden Konstanten ... für die Funktion isses aber unerheblich

Auf was du aber noch aufpassen mußt, ist die Speicher-/Feldausrichtung, also daß diese wirklich korrekt ist, denn von "packed" steht in dem C-Code nichts drin.

Hallo himitsu,

danke für dieses Beispiel.

Zitat:

denn von "packed" steht in dem C-Code nichts drin.

Wie würde denn im C-Code ein "packed" stehen?

Sowas wie das "packed" selber hab ich noch nie gesehn,
aber das {$A...} , bzw. {$ALIGN ...} ist dort nicht immer so definiert, wie es in Delphi standardmäßig der Fall ist.

Und jenachdem von wo man den Code hat, gibt es in den C-Header entweder eine entsprechende Definition, bzw. dort existiert eine bestimmte "Vorgabe", in den übergeordneten Headern.


Auch die ENUMs stimmen nicht immer überein.

markieren

Delphi-Quellcode:

_PARTITION_STYLE = (
    PARTITION_STYLE_MBR,
    PARTITION_STYLE_GPT,
    PARTITION_STYLE_RAW);

z.B. in Delphi sind die standardmäßig so klein wie möglich (in diesem Fall 1 Byte)
und in C++ sind sie so wie die Register (für ein 32 Bit Programm dann 32 Bit = 4 Byte)

Danke himitsu! Du bist eine große Hilfe

Vergess jedesmal wie das MINENUMSIZE lautet ... also hier nochmal in Kurz

markieren

Delphi-Quellcode:

type
  {$MINENUMSIZE 4}
  _PARTITION_STYLE = (
    PARTITION_STYLE_MBR,
    PARTITION_STYLE_GPT,
    PARTITION_STYLE_RAW);
  {$MINENUMSIZE 1}

oder im Notfall einfach so

markieren

Delphi-Quellcode:

type
  _PARTITION_STYLE = type Integer;
const
  PARTITION_STYLE_MBR = _PARTITION_STYLE(0);
  PARTITION_STYLE_GPT = _PARTITION_STYLE(1);
  PARTITION_STYLE_RAW = _PARTITION_STYLE(2);