AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

zeichenkette erstellen

Ein Thema von mfrank · begonnen am 1. Jun 2012 · letzter Beitrag vom 9. Jun 2012
Antwort Antwort
Seite 1 von 2  1 2   
mfrank

Registriert seit: 7. Okt 2006
26 Beiträge
 
Turbo Delphi für Win32
 
#1

zeichenkette erstellen

  Alt 1. Jun 2012, 09:31
Hallo,

ich suche nach einer Lösung für folgendes Problem:
Aus vorgegebenen Zeichen a,b,c sollen alle möglichen Zusammensetzungen aufgelistet werden:
a
.
c
aa
.
ac
aaa
.
ccc
.
.
Wie kann man dies am besten bearbeiten - gibt es dafür schon Lösungen oder wonach kann ich erst mal suchen?
Vielen Dank und viele Grüße
Michael
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.752 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: zeichenkette erstellen

  Alt 1. Jun 2012, 10:24
Hallo Michael,

Dein Beispiel kann ich nicht so ganz folgen..

Du hast 3 Elemente a,b,c

Durch Vertauschung wären nur diese Kombinationen möglich (wenn ich keine vergessen habe):
a,b,c
a,c,b
c,a,b
c,b,a
b,c,a
b,a,c

Wenn Du die Anzahl einzelner Elemente erhöst,
kannst Du das bis zu unendlichkeit treiben.

Stichwort:Permutation

Grüße
Klaus
Klaus
  Mit Zitat antworten Zitat
mfrank

Registriert seit: 7. Okt 2006
26 Beiträge
 
Turbo Delphi für Win32
 
#3

AW: zeichenkette erstellen

  Alt 1. Jun 2012, 10:45
ich meine das so
a
b
c
aa
ab
ac
ba
bb
bc
ca
cb
cc
aaa
aab
aac
aba
...
Auszuwählen sollten die Zeichen z.Bsp. 'a'-'z' und die Länge der Ausgabezeichenkette sein 'aaaaa' -> 5. Permutation bringt dies nicht alles - nur jedes Zeichen einmal und eine feste Länge. Ist dies vieleicht Variation?
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#4

AW: zeichenkette erstellen

  Alt 1. Jun 2012, 11:20
Tipp: Such mal nach Hier im Forum suchenBruteforce, denn dort wird ja sowas genutzt.

Kommt drauf an in welchem Maße (Länge und Anzahl) das benötgt wird.
Am Einfachsten kann man da mathematisch rangehn.

Man zählt einen Integer/Int64 hoch.
Und zerlegt ihn bei jedem Schritt in seine Einzelzeile, welche man mit den gewünschen Zeichen gleichsetzt.
Delphi-Quellcode:
function Zerlege(Num: Cardinal; Chars: string): string;
begin
  Result := '';
  while Num > 0 do begin
    Result := Result + Chars[Num mod Length(Chars) + 1];
    Num := Num div Length(Chars);
  end;
end;

Label1.Caption := Zerlege(0815, 'abc');
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
gammatester

Registriert seit: 6. Dez 2005
999 Beiträge
 
#5

AW: zeichenkette erstellen

  Alt 1. Jun 2012, 11:47
Am einfachsten geht's wohl rekursiv. Hier ein Beispielcode
Delphi-Quellcode:
{$apptype console}
program kette;

const
  maxlen = 3;
  zeichen: string='abc';

procedure genlen(pre: string; len: integer);
var
  i: integer;
begin
  if len<2 then for i:=1 to length(zeichen) do writeln(pre,zeichen[i])
  else for i:=1 to length(zeichen) do genlen(pre+zeichen[i],len-1)
end;

var
  len: integer;
begin
  for len:=1 to maxlen do genlen('', len);
end.
mit der Ausgabe:
Code:
a
b
c
aa
ab
ac
ba
bb
bc
ca
cb
cc
aaa
aab
aac
aba
abb
abc
aca
acb
acc
baa
bab
bac
bba
bbb
bbc
bca
bcb
bcc
caa
cab
cac
cba
cbb
cbc
cca
ccb
ccc
  Mit Zitat antworten Zitat
mfrank

Registriert seit: 7. Okt 2006
26 Beiträge
 
Turbo Delphi für Win32
 
#6

AW: zeichenkette erstellen

  Alt 1. Jun 2012, 12:42
ja, genau dies habe ich gesucht - es funktioniert prima und ist auch nachvollziehbar.
Vielen Dank
Michael
  Mit Zitat antworten Zitat
Horst_

Registriert seit: 22. Jul 2004
Ort: Münster Osnabrück
116 Beiträge
 
#7

AW: zeichenkette erstellen

  Alt 1. Jun 2012, 14:13
Hallo,

falls Du nur die Anzahl der verschiedenen Möglichkeiten brauchst, kannst Du diese ja jetzt leicht berechnen.
Bei k verschiedenen Zeichen mit Länge l ergibt sich
Anzahl = Summe (i= 1 bis l) [k^i]
Im Beispiel hier k=3 und l = 3
ergibt Anzahl= 3^1+3^2+3^3 = 3+9+27 = 39

Ginge die Summe mit i= 0 los ergäbe es die Zinsenszinsformel
q_l = (q^(l+1)-1)/(q-1) mit q = k
Schönerweise ist aber q^0 immer 1 für q <> 0
also geht hier

Anzahl = (k^(l+1)-1)/(k-1) -1

hier also Anzahl = (3^4-1)/2 -1 = 40-1 = 39
  Mit Zitat antworten Zitat
mfrank

Registriert seit: 7. Okt 2006
26 Beiträge
 
Turbo Delphi für Win32
 
#8

AW: zeichenkette erstellen

  Alt 7. Jun 2012, 09:59
Hallo,
ich muss dieses Thema noch einmal öffnen.
Gibt es auch eine Möglichkeit die Abfrage mit Zeichenketten abzurufen - also nicht abcd sondern 'ab', 'bc', '11'.
Ich habe schon einiges probiert aber noch keine Lösung gefunden.
Viele Grüße
Michael
  Mit Zitat antworten Zitat
Benutzerbild von Aphton
Aphton

Registriert seit: 31. Mai 2009
1.198 Beiträge
 
Turbo Delphi für Win32
 
#9

AW: zeichenkette erstellen

  Alt 7. Jun 2012, 10:38
Ich weiß nicht, ob du das programmiertechnisch implementiert haben willst, oder ob n programm (dieser thread) schon reicht :/
das Erkennen beginnt, wenn der Erkennende vom zu Erkennenden Abstand nimmt
MfG
  Mit Zitat antworten Zitat
Horst_

Registriert seit: 22. Jul 2004
Ort: Münster Osnabrück
116 Beiträge
 
#10

AW: zeichenkette erstellen

  Alt 9. Jun 2012, 11:23
Hallo,

ich habe mal die Version von Gammatester erweitert.
Was mich stutzig machte war die Angabe einer Zeichenmenge von '11', was so nicht geht.
Es geht doch um die Erstellung aller Variationen aus einer Zeichenmenge mit einer Länge von 1 bis maxlen, und dabei müßen die Elemente der Menge alle verschieden sein.

Delphi-Quellcode:
{$apptype console}
program kette;
uses
  sysutils,classes;
  
function MaxCountVariation(AnzahlverschiedeneZeichen,MaxLaengeAusgabe:cardinal):Int64;
var
  i : integer;
begin
  result := 0;
  IF MaxLaengeAusgabe> 0 then
    begin
    try
      // r = (q^(n+1)-1 )/(q-1) -1
      //q= AnzahlverschiedeneZeichen;n = MaxLaengeAusgabe
      result := AnzahlverschiedeneZeichen;
      For i := 1 to MaxLaengeAusgabe do
        result := result * AnzahlverschiedeneZeichen;
      result := (result -1) div (AnzahlverschiedeneZeichen-1)-1;
    except
      writeln('Zuviele Möglchkeiten');
      halt(-2);
    end;
    end;
end;


function BereinigeZeichenvorrat(ZV:string):string;
// keine doppelten Zeichen
var
  i,j: integer;
begin
  i := 1;
  while length(ZV)>i do
    begin
    j := i+1;
    while j <=length(ZV) do
      begin
      IF ZV[i]=ZV[j] then
        delete(ZV,j,1)
      else
        inc(j);
      end;
    inc(i);
    end;
  result := ZV;
end;

function ErzeugeVariationen(ZeichenVorrat:string;
                            Laenge:integer;
                            out SL:TStringlist):boolean;

  var
    pre : string;
  procedure genlen(len: integer);
  var
    i: integer;
  begin
    IF len = 1 then
      for i:=1 to length(Zeichenvorrat) do
        begin
        pre[len]:=Zeichenvorrat[i];
        SL.Add(pre)
        end
   else
     for i:=1 to length(Zeichenvorrat) do
       begin
       pre[len]:=Zeichenvorrat[i];
       genlen(len-1)
     end;
   end;
                      
var
  len,
  cap : integer;
begin
  Zeichenvorrat := BereinigeZeichenvorrat(Zeichenvorrat);
  result := false;
  SL.clear;
  try
    cap := MaxCountVariation(length(Zeichenvorrat),Laenge);
    IF cap < 1000000 then
      begin
      SL.capacity := MaxCountVariation(length(Zeichenvorrat),Laenge);
      for len:=1 to Laenge do
        begin
        setlength(pre,len);
        genlen( len);
        end;
        
      result := true;
      
      if SL.count < 10000 then
        writeln(SL.text);
      end
    else
      writeln('Zuviele Moeglichkeiten: ',cap,#13#10);
  finally

  end;
end;

var
  VariationenListe: TStringlist;

BEGIN
  VariationenListe:= TStringlist.create;
  try
    ErzeugeVariationen('01',2,VariationenListe);
    ErzeugeVariationen('010101010101010101',2,VariationenListe);
    ErzeugeVariationen('0111110000',2,VariationenListe);
    ErzeugeVariationen('12345',1,VariationenListe);
  finally
    VariationenListe.free;
  end;
END.
Ausgabe leicht anders als bei gammatester, da die Zeichenfolge rückwärts erstellt wird.
Code:
0
1
00
10
01
11

0
1
00
10
01
11

0
1
00
10
01
11

1
2
3
4
5
11
21
31
41
51
12
22
32
42
52
13
23
33
43
53
14
24
34
44
54
15
25
35
45
55
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 15:20 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz