AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Algorithmen, Datenstrukturen und Klassendesign FreePascal OnChange o.ä. für Speicheraufforderung

OnChange o.ä. für Speicheraufforderung

Ein Thema von philharmony · begonnen am 17. Dez 2012 · letzter Beitrag vom 20. Dez 2012
Antwort Antwort
philharmony

Registriert seit: 17. Dez 2012
37 Beiträge
 
#1

OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 16:41
Hallo zusammen
Ich habe eine immer umfangreicheres Projekt und ich möchte eine Funktion realiseren, wie man sie von Word o.ä. kennt: Sobald der Benutzer etwas an den verwendeten Daten ändert, soll u.ä. in der Caption ein Sternchen an den Namen angehängt werden und vor dem Beenden eine Speicheraufforderung kommen. Ohne etwas geändert zu haben, soll das natürlich nicht passieren.
Die Daten selbst liegen in einer Eigenen Klasse mit einigen Read und Write Methoden. Jetzt dachte ich zum Beispiel an ein onChange - Ereignis, das triggert, wenn Daten verändert werden:

Delphi-Quellcode:
//Die Deklarationen
type
  TValueChange = procedure of object;

  TCompany = Class
  Private
    ...
  Public
    OnChange : TValueChange;
    ...
    procedure Edit(CName : String; CNFltPa : Integer);
    ...
  end;

//Eine der Prozeduren, die das OnChange auslösen sollen
procedure TCompany.Edit(CName : String; CNFltPa : integer);
begin
  FName := CName;
  FNFltPa := CNFltPa;
  if Assigned(OnChange) then OnChange;
end;

//Und in der Main die Zuweisung
procedure TForm1.CreateCompany(CName : String; CNFltPa : integer);
begin
  Company := TCompany.Create(cName, cNfltPa);
  Company.OnChange := @Unsaved;
end;

procedure TForm1.Unsaved;
begin
  DataChanged := true;
  UpdateForm;
end;
Leider wird aber nichts getriggert, wenn ich die Company.Edit ausführe. Dhaer die Frage: Ist das überhaupt der richtige Weg, wo liegt der Fehler, geht das auch anders?
Es gibt relativ viele Möglichkeiten, etwas an den Daten zu ändern, daher möchte ich "Form1.Unsaved" nicht an jeder dieser Stellen in der Main aufrufen.
Da dies mein erstes großes Projekt mit Pascal/Delphi ist, ist mein Repertoir noch nicht besonders groß, daher bin ich um jeden Tip dankbar.
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.629 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#2

AW: OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 16:56
Ist prinzipiell schon der richtige Weg. Normalerweise wird das OO konform leicht anders umgesetzt:
Delphi-Quellcode:
TCompany = class
private
  FOnChange: TNotifyEvent;
public
  property OnChange read FOnChange write FOnChange;
end;

..

if Assigned(FOnChange) then FOnChange;
Delphi-Quellcode:
TForm1 = class(TForm)
..
private
  procedure OnChange(Sender: TObject);
end;

..

MyCompany.OnCange := OnChange;
Sollte eigentlich funktionieren. Sehe zwar in deinem Code auch keinen Fehler, aber vielleicht hat Delphi da ja irgendwo eine Macke, wenn du es nicht korrekt über eine property machst.
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 17:53
Da im Threadtitel FreePascal steht, vermute ich, es geht um Lazarus. Den folgenden Code habe ich gerade eben unter Lazarus 1.1 ausprobiert (komplette Unit):
Delphi-Quellcode:
unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TTestClass }

  TTestClass = class
  private
    FName: string;
    FFirstname: string;
    FOnChanged: TNotifyEvent;
    FOnSaved: TNotifyEvent;
    procedure Change;
    procedure SetName(AValue: string);
    procedure SetFirstname(AValue: string);
  public
    procedure Save;
    property Name: string read FName write SetName;
    property Firstname: string read FFirstname write SetFirstname;
    property OnChanged: TNotifyEvent read FOnChanged write FOnChanged;
    property OnSaved: TNotifyEvent read FOnSaved write FOnSaved;
  end;

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { private declarations }
    FTest: TTestClass;
    procedure DoOnTestChanged(Sender: TObject);
    procedure DoOnTestSaved(Sender: TObject);
  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  FTest := TTestClass.Create;
  FTest.OnChanged := @DoOnTestChanged;
  FTest.OnSaved := @DoOnTestSaved;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FTest.Name := 'Hanswurst';
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  FTest.Firstname := 'Pumuckl';
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  FTest.Save;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FTest.Free;
end;

procedure TForm1.DoOnTestChanged(Sender: TObject);
begin
  Caption := Name + '*';
end;

procedure TForm1.DoOnTestSaved(Sender: TObject);
begin
  Caption := Name;
end;

{$R *.lfm}

{ TTestClass }

procedure TTestClass.Change;
begin
  if Assigned(FOnChanged) then
    FOnChanged(self);
end;

procedure TTestClass.SetName(AValue: string);
begin
  if FName=AValue then Exit;
  FName:=AValue;
  Change;
end;

procedure TTestClass.SetFirstname(AValue: string);
begin
  if FFirstname=AValue then Exit;
  FFirstname:=AValue;
  Change;
end;

procedure TTestClass.Save;
begin
  if Assigned(FOnSaved) then
    FOnSaved(self);
end;

end.
So sollte das vermutlich in etwa aussehen, bei mir hat das wie erwartet funktioniert. Die "Exits" hat Lazarus BTW selbst eingefügt, ich habe es dabei belassen, falls jemand meckern möchte *g*.
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#4

AW: OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 19:07
  Company.OnChange := @Unsaved;
Lass mal das @ weg.

  Company.OnChange := Unsaved;
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 19:21
Das mag Lazarus im objfpc-Mode aber gar nicht.
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#6

AW: OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 19:25
Das mag Lazarus im objfpc-Mode aber gar nicht.
Hatte ich nicht gesehen - dann ist das hier nicht meine Spielwiese...
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#7

AW: OnChange o.ä. für Speicheraufforderung

  Alt 17. Dez 2012, 19:27
Nunja, deshalb steht das @ ja auch in meinem obigen Code
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
philharmony

Registriert seit: 17. Dez 2012
37 Beiträge
 
#8

AW: OnChange o.ä. für Speicheraufforderung

  Alt 20. Dez 2012, 12:52
Funktioniert, vielen Dank!
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 19:03 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz