AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Sonstige Fragen zu Delphi Delphi Delphi XE3 FMX Standardbrowser öffnen

Delphi XE3 FMX Standardbrowser öffnen

Offene Frage von "niao"
Ein Thema von niao · begonnen am 23. Dez 2012 · letzter Beitrag vom 25. Dez 2012
Antwort Antwort
niao

Registriert seit: 15. Nov 2006
Ort: Erfurt
27 Beiträge
 
Delphi XE4 Professional
 
#1

Delphi XE3 FMX Standardbrowser öffnen

  Alt 23. Dez 2012, 21:46
Hallo!

Kann mir jemand schreiben wie ich unter Delphi XE3 mit einer FireMonkey Anwendung
einen Standardbrowser mit vorgegebener URL öffnen kann.
Das ganze sollte natürlich auch unter OS X funktioneren.
ShellExecute geht nur unter Windows, also nicht anwendbar bzw nur mit Compileroptionen.
Für Eure Antworten bin ich im Voraus dankbar!

Viele Grüße und schöne Feiertage

Niao
Eduard
  Mit Zitat antworten Zitat
daywalker9

Registriert seit: 1. Jan 2010
Ort: Leer
594 Beiträge
 
Delphi XE3 Professional
 
#2

AW: Delphi XE3 FMX Standardbrowser öffnen

  Alt 23. Dez 2012, 22:43
Du wirst mit ifdefs arbeiten müssen.

Unter OSX kannst so eine URL öffnen:

Delphi-Quellcode:
Workspace := TNSWorkspace.create;
Workspace.openURL(...);
Workspace.free;
//Edit: Ich hab mir sowas gebastelt, in XE3 kann man ja PlatformServices registrieren:

Delphi-Quellcode:
unit FMX.PlatformExtensions;

interface

type
  IFMXOpenWebbrowser = interface['{9CA18562-C56D-489C-AE97-D069B9C58427}']
    function OpenURL(const AURL: String) : boolean;
  end;

implementation

uses
{$IFDEF MACOS}
  FMX.PlatFormExtensions.Mac
{$ELSE IF WINDOWS}
  FMX.PlatformExtensions.Win
{$ENDIF}
  ;
end.
Delphi-Quellcode:
unit FMX.PlatformExtensions.Mac;

interface

implementation

uses
  IdURI,
  MacApi.Foundation,
  MacApi.AppKit,
  FMX.PlatForm,
  FMX.PlatFormExtensions;

type
  TFMXOpenWebbrowser = class(TInterfacedObject, IFMXOpenWebbrowser)
  public
    function OpenURL(const AURL: string): Boolean;
  end;



{ TFMXOpenWebbrowser }

function TFMXOpenWebbrowser.OpenURL(const AURL: string): Boolean;
begin
  TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorkspace)
    .openURL(
      TNSURL.Wrap(
        TNSURL.OCClass.URLWithString(NSSTR(TIdURI.URLEncode(AURL)))
      )
    );
end;

initialization

  TPlatformServices.Current.AddPlatformService(IFMXOpenWebbrowser, TFMXOpenWebbrowser.Create());
Delphi-Quellcode:
unit FMX.PlatformExtensions.Win;

interface

implementation

uses
  ShellAPI,
  WinApi.Windows,
  FMX.PlatForm,
  FMX.PlatFormExtensions;

type
  TFMXOpenWebbrowser = class(TInterfacedObject, IFMXOpenWebbrowser)
  public
    function OpenURL(const AURL: string): Boolean;
  end;



{ TFMXOpenWebbrowser }

function TFMXOpenWebbrowser.OpenURL(const AURL: string): Boolean;
begin
  ShellExecute(0, 'open', pChar(AURL), nil, nil, SW_SHOW);
end;

initialization

  TPlatformServices.Current.AddPlatformService(IFMXOpenWebbrowser, TFMXOpenWebbrowser.Create());



end.
Und zum Testen:

Delphi-Quellcode:
uses
  FMX.PlatFormExtensions;

procedure TForm50.Button1Click(Sender: TObject);
var
  lOpenWeb: IFMXOpenWebbrowser;
begin
  lOpenWeb := IFMXOpenWebbrowser(TPlatformServices.Current.GetPlatformService(IFMXOpenWebbrowser));
  if lOpenWeb <> nil then
    lOpenWeb.OpenURL(Edit1.Text);

end;
Lars

Geändert von daywalker9 (23. Dez 2012 um 23:46 Uhr)
  Mit Zitat antworten Zitat
niao

Registriert seit: 15. Nov 2006
Ort: Erfurt
27 Beiträge
 
Delphi XE4 Professional
 
#3

AW: Delphi XE3 FMX Standardbrowser öffnen

  Alt 25. Dez 2012, 17:47
Hallo Lars,

vielen Dank!
Habe es am Ende so umgesetzt.

{$IFDEF MSWINDOWS} WInApi.ShellApi.shellExecute(Handle,PChar('open'), PChar(f_URL),nil,nil, 1); {Do not Localize}
{$ENDIF}
{$IFDEF MACOS}
TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorks pace)
.openURL(TNSURL.Wrap(TNSURL.OCClass.URLWithString( NSSTR(f_URL))));
{$ENDIF}

Viele Grüße
Niao
Eduard
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 20:28 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz