Hilfe: Delphi Taschrechner

[knightfire66]

Hallo
ich erstelle zum ersten mal ein neues Thema, also bitte nicht sauer sein, wenn etwas falsch ist

ich habe lange im Internet gesucht und auch im Forum aber keine Antwort auf mein Problem gefunden.

ich programmiere zurzeit ein Taschenrechner für mein Informatikunterricht (die Note zählt fast wie ne ganze Klasur).

Ich benutze Delphi7 und haben folgendes Problem:

Ich versuche seit Tagen hinzubekommen, dass ich nur ein Komma in meinem Edit Feld haben kann und das dann nur, wenn mein Editfeld leer ist (zumindestens >0 ist). Also das soll folgendes verhinden.

,00,,5 + ,5,0 .... wenn das so aussieht geht das ja nicht das sollte so aussehen:

0,5 + 5,0 DD

Einige Quelltexte habe ich schon gefunden, aber die lösen nicht mein Problem

Delphi-Quellcode:

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
if not (Key in ['0'..'9', ',', #8])then
    Key := #0;
if (key = ',') and (pos(',',(sender as TEdit).text) >0) then
    key := #0;
end;

Dies geht halt nur, dass man nur 1 Komma macht aber ich kann nicht dafür sorgen , dass man erst ein Komma setzen kann, wenn davor zunächst auch eine Zahl steht.

folgendes habe ich auch getestet funktioniert aber auch
nicht...

Delphi-Quellcode:

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
if not (Key in ['0'..'9', ',', #8])and (Length(Edit1.Text) < 1)then
    Key := #0;
if (key = ',') and (pos(',',(sender as TEdit).text) >0) then
    key := #0;
end;

Und dies alles soll aber auch mit einem, im Program integriertem KommaButton (',') funktionieren...aber bin mit dem Button erst soweit gekommen:

Delphi-Quellcode:

procedure TForm1.ButtonKomClick(Sender: TObject);
begin
If not (Edit1.Text= '') then
Edit1.Text:= Edit1.Text+',';
end;

Danke im Vorraus

[DeddyH]

Die "Kommabafrage" brauchst Du ja 2 mal, da bietet sich eine eigene Funktion an. Auf die Schnelle (kann sicherlich noch verbessert werden):

Delphi-Quellcode:

function SeparatorAllowed(const s: string): Boolean;
begin
  Result := (s <> '') and (Pos(DecimalSeparator, s) = 0);
end;

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
var
  valid: Boolean;
begin
  valid := false;
  case Key of
    '0'..'9', #8:
      valid := true;
    else
      if Key = DecimalSeparator then
        valid := SeparatorAllowed((Sender as TEdit).Text);
  end;
  if not valid then
    Key := #0;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if SeparatorAllowed(Edit1.Text) then
    Edit1.Text := Edit1.Text + DecimalSeparator;
end;

[Sir Rufo]

Oder eben ohne Komma-Abfrage, dafür funktioniert das aber auch, wenn der User Teile des Edit-Feldes markiert hat ...

Delphi-Quellcode:

unit NumericEditValidator;

interface

  uses
    Classes,
    StdCtrls;

  type
    TNumericEditValidator = class( TComponent )
    protected
      procedure EditKeyPress( Sender : TObject; var Key : Char );
    public
      constructor Create( AOwner : TEdit ); reintroduce;
    end;

implementation

  uses
    SysUtils;

  { TNumericEditValidator }

  constructor TNumericEditValidator.Create( AOwner : TEdit );
    begin
      inherited Create( AOwner );
      AOwner.OnKeyPress := EditKeyPress;
    end;

  procedure TNumericEditValidator.EditKeyPress( Sender : TObject; var Key : Char );
    var
      LEdit          : TEdit;
      LNewText       : string;
      LText1, LText2 : string;
      LValue         : Extended;
    begin
      LEdit := Sender as TEdit;

      LText1 := Copy( LEdit.Text, 1, LEdit.SelStart );
      LText2 := Copy( LEdit.Text, LEdit.SelStart + 1 + LEdit.SelLength );

      if ( Key = #8 )
      then
        if LEdit.SelLength > 0
        then
          LNewText := LText1 + LText2
        else
          LNewText := Copy( LText1, 1, Length( LText1 ) - 1 ) + LText2
      else
        LNewText := LText1 + Key + LText2;

      if ( LNewText <> '' ) and not TryStrToFloat( LNewText, LValue )
      then
        Key := #0;
    end;

end.

In deiner Form bindest du diese unit ein und im FormCreate das hier

Delphi-Quellcode:

uses
  NumericEditValidator;

procedure TForm1.FormCreate( Sender : TObject );
begin
  TNumericEditValidator.Create( Edit1 );
end;

[himitsu]

Und du brauchst die Komma-Abfrage noch mindestens ein drittest Mal.

- entweder du verbietest Funktionen ala Strg+V (Einfügen)
- oder du mußt auch beim Einfügen (egal auf welchem Wege) ungültige Dinge rauslöschen
- und/oder überall, wo danach nochmal gerechnet wird, muß ebenfalls nochmals auf ungültige Zeichen geprüft werden

[knightfire66]

Vielen dank für die Antworten. Die Methode von DeddyH sieht gut aus. es funktioniert soweit

PS: Thema geschlossen!

[knightfire66]

Ein letztes mal noch die Lösung für welche, die das mal interessiert:

Zitat von himitsu:

Und du brauchst die Komma-Abfrage noch mindestens ein drittest Mal.

- entweder du verbietest Funktionen ala Strg+V (Einfügen)
- oder du mußt auch beim Einfügen (egal auf welchem Wege) ungültige Dinge rauslöschen
- und/oder überall, wo danach nochmal gerechnet wird, muß ebenfalls nochmals auf ungültige Zeichen geprüft werden

Am Ende habe ich doch den Vorschlag von himitsu genommen (danke nochmal)...
so siehts nun aus und funktioniert einwandfrei:

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
begin
if not (Edit1.Text= '') then begin
if not (pos(',', Edit1.Text)<> 0) then
Edit1.Text:= Edit1.Text+ ',';
end;
end;

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
if (Edit1.Text = '') and (Key in [',']) then
    Key := #0;
if not (Key in ['0'..'9',',', #8]) then
    Key := #0;
if (key = ',') and (pos(',',(sender as TEdit).text) >0)then
  key := #0;
end;
end.

Geschlossen!