AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

XE 7 - Parallel Programming Library

Ein Thema von Alex_ITA01 · begonnen am 2. Sep 2014 · letzter Beitrag vom 3. Sep 2014
Antwort Antwort
Seite 2 von 2     12
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#11

AW: XE 7 - Parallel Programming Library

  Alt 2. Sep 2014, 17:12
Also im Code ist das doch sehr schön zu sehen
Delphi-Quellcode:
    if FParallel then
    begin

      // parallele Verarbeitung
      TParallel.For(Low(FOriginalBoard), High(FOriginalBoard),
        procedure (Value: Integer)
        begin
          ProcessCells(nil, Value);
        end);

    end else

      // sequentielle Verarbeitung
      for I := Low(FOriginalBoard) to High(FOriginalBoard) do
        ProcessCells(nil, I);
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
mkinzler
(Moderator)

Registriert seit: 9. Dez 2005
Ort: Heilbronn
39.851 Beiträge
 
Delphi 11 Alexandria
 
#12

AW: XE 7 - Parallel Programming Library

  Alt 2. Sep 2014, 17:16
Zitat:
Gibts dann eigentlich auch ein "await" ?
Nicht Out-Of-The-Box aber leicht implementierbar:
Zitat von Chris Rolliston [url:
http://delphifoundations.com/author/[/url] ]
Delphi-Quellcode:
type
  TTaskHelper = class helper for TTask
    class function Run<T>(const Sender: TObject; const Func: TFunc<T>;
      const CallOnReturn: TProc<TObject, T>): ITask; overload; static;
  end;
 
class function TTaskHelper.Run<T>(const Sender: TObject; const Func: TFunc<T>;
  const CallOnReturn: TProc<TObject, T>): ITask;
begin
  Result := Run(
    procedure
    var
      Value: T;
    begin
      Value := Func();
      TThread.Synchronize(nil,
        procedure
        begin
          CallOnReturn(Sender, Value);
        end);
    end);
end;
 
procedure TFormMain.Button1Click(Sender: TObject);
begin
  TTask.Run<string>(Self, LongTimeComing, FeedbackFromThread);
end;
http://docwiki.embarcadero.com/Libra...stem.Threading
Markus Kinzler
  Mit Zitat antworten Zitat
mquadrat

Registriert seit: 13. Feb 2004
1.113 Beiträge
 
Delphi XE2 Professional
 
#13

AW: XE 7 - Parallel Programming Library

  Alt 2. Sep 2014, 19:19
mhh das muss ich mir mal morgens anschauen, wenn das Hirn noch nicht im Ruhemodus ist. Meine Lösung sieht so ganz anders aus

EDIT: mhh ein wirklich await ist das aber nicht, oder?

Geändert von mquadrat ( 2. Sep 2014 um 19:23 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
4.007 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#14

AW: XE 7 - Parallel Programming Library

  Alt 2. Sep 2014, 19:41
mhh das muss ich mir mal morgens anschauen, wenn das Hirn noch nicht im Ruhemodus ist. Meine Lösung sieht so ganz anders aus

EDIT: mhh ein wirklich await ist das aber nicht, oder?
Nö isses nich. Das ist ne asynchrone Aktion mit einer in den Hauptthread synchronisierten Aktion im Abschluss.
Async/await für Delphi hab ich hier mal gebastelt. Für XE7 kann ich das auch einfach umstellen, dass System.Threading dafür als Backend hergenommen wird.
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight

Geändert von Stevie ( 2. Sep 2014 um 19:43 Uhr)
  Mit Zitat antworten Zitat
mquadrat

Registriert seit: 13. Feb 2004
1.113 Beiträge
 
Delphi XE2 Professional
 
#15

AW: XE 7 - Parallel Programming Library

  Alt 3. Sep 2014, 13:44
Kommt halt drauf an, was deine Tasks noch so können. Hatte mir bei DSharp damals nur das DataBinding angeschaut.
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
4.007 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#16

AW: XE 7 - Parallel Programming Library

  Alt 3. Sep 2014, 14:36
Kommt halt drauf an, was deine Tasks noch so können. Hatte mir bei DSharp damals nur das DataBinding angeschaut.
Die können nicht viel, ist nur nen kleiner Wrapper um nen TThread, ohne Threadpooling und den ganzen Zauber
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#17

AW: XE 7 - Parallel Programming Library

  Alt 3. Sep 2014, 14:54
Nur mal so zum Spass so ein einfaches Parallel
Delphi-Quellcode:
unit Parallel;

interface

uses
  System.SysUtils;

type
  TParallel = class
    class procedure Execute( ALow, AHigh : Int64; AProc : TProc<Int64> );
  end;

implementation

uses
  System.Generics.Collections,
  System.SyncObjs,
  System.Classes;

{ TParallel }

class procedure TParallel.Execute( ALow, AHigh : Int64; AProc : TProc<Int64> );
  procedure BuildThread( AEvent : TEvent; AValue : Int64 );
  var
    LThread : TThread;
  begin
    // Event zurücksetzen
    AEvent.ResetEvent;
    // Anonymen Thread erzeugen
    LThread := TThread.CreateAnonymousThread(
        procedure
      begin
        // Arbeit ausführen
        AProc( AValue );
        // Event setzen
        AEvent.SetEvent;
      end );
    // Thread starten
    LThread.Start;
  end;

var
  LMaxThreads : Integer;
  LThread : TThread;
  LIdx : Integer;
  LEvents : TList<TEvent>;
  LEventArray : THandleObjectArray;
  LSignaled : THandleObject;
  LEvent : TEvent;
  LIter : Int64;
begin

  // Events vorbereiten

  LMaxThreads := TThread.ProcessorCount;

  LEvents := TObjectList<TEvent>.Create( True );
  LEvents.Capacity := LMaxThreads;

  SetLength( LEventArray, LMaxThreads );
  for LIdx := low( LEventArray ) to high( LEventArray ) do
    begin
      LEvent := TEvent.Create( nil, True, True, '' );
      LEvents.Add( LEvent );
      LEventArray[LIdx] := LEvent;
    end;

  // Jetzt wird es parallel

  LIter := ALow;

  while LIter <= AHigh do
    begin
      // Warten, bis EIN Event wieder frei ist
      TEvent.WaitForMultiple( LEventArray, INFINITE, False, LSignaled );
      BuildThread( LSignaled as TEvent, LIter );
      Inc( LIter );
    end;
  // Warten, bis ALLE Events wieder frei sind
  TEvent.WaitForMultiple( LEventArray, INFINITE, True, LSignaled );
end;

end.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 17:07 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz