AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Delphi Codierung/Decodierung von Umlauten

Codierung/Decodierung von Umlauten

Ein Thema von Shrek_III · begonnen am 27. Okt 2014 · letzter Beitrag vom 28. Okt 2014
Antwort Antwort
Seite 1 von 2  1 2   
Shrek_III

Registriert seit: 15. Dez 2004
Ort: Handewitt
25 Beiträge
 
Delphi XE5 Enterprise
 
#1

Codierung/Decodierung von Umlauten

  Alt 27. Okt 2014, 23:32
Moin zusammen,

ich sitze gerade vor einem womöglich sehr einfachen Problem, finde aber derzeit keinen Weg dies entsprechend auszuräumen.

Nach einer Webabfrage erhalte ich als Ergebnis meines POST Nachnamen im repsonse übergeben.
Die Abfrage an sich funktioniert einwandfrei, ist jetzt jedoch jemand dabei, der Umlaute in seinem Namen hat, kommt Unicode zum tragen.

Anstelle von
Müller

erhalte ich deshalb
M\u00fcller

jetzt meine Frage, gibt es einen Befehl, der die Konvertierung generell übernimmt oder muss es tatsächlich (und das will ich nicht hoffen von Hand geschehen (Pos & RegEx)?


Zu meinen Voraussetzungen:
1. An der Webseite kann ich nichts ändern, da diese nicht von mir stammt.
2. Ich nutze Delphi XE 5

Für einen guten Ratschlag wäre ich sehr dankbar.
So long fellas

Shrek_III

Geändert von Shrek_III (27. Okt 2014 um 23:39 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#2

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 00:39
Das sieht sehr nach einer JavaScript Codierung von Unicode aus. Soweit ich weiß, gibt es standardmäßig keine Methode, die das umsetzt. Wäre mal interessant zu wissen, was ankommt, wenn der Name ein "\u" enthält.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 01:28
Das sieht sehr nach einer JavaScript Codierung von Unicode aus. Soweit ich weiß, gibt es standardmäßig keine Methode, die das umsetzt. Wäre mal interessant zu wissen, was ankommt, wenn der Name ein "\u" enthält.
Code:
\\u
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.014 Beiträge
 
Delphi 12 Athens
 
#4

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 03:04
Jupp, knuffige Escape-Sequenzen.

Escape-Zeichen ist \

\\ = \ , könnte aber notfalls auch auch \u005C sein
\uxxxx = Unicodezeichen, wobei xxxx der hexadezimale Zeichencode ist

Weitere Codes siehe Tabelle 2.1 Escape-Sequenzen bei JavaScript

Hab jetzt nur die manuelle Umwandlung in der anderen Richtung gefunden
http://forum.delphi-treff.de/index.p...enden-Unicode/

Eventuell gibt es im Indy aber schon irgendwo etwas Fertiges?
Aber sonst wäre eine Umwandlung ja nicht sooooo schwer, wenn man die beiden oben genannten Sequenzen selber behandelt. (zeichen für Zeichen durchgehn, wenn \ nach dem nächsten Zeichen gucken und bei \ die zwei Zeichen durch \ ersetzen und bei u die 6 Zeichen durch das Zeichen mit dem Char-Code "xxxx")

PS: Char(StrToInt('$' + xxxx))
und kennt schon jemand die SuFu?
http://www.delphipraxis.net/165132-u...sequenzen.html
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu (28. Okt 2014 um 03:07 Uhr)
  Mit Zitat antworten Zitat
mjustin

Registriert seit: 14. Apr 2008
3.003 Beiträge
 
Delphi 2009 Professional
 
#5

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 07:47
Dieses Escaping wird auch für JSON verwendet (das J in JSON steht ja für JavaScript), daher kann man einen Umweg über einen JSON Parser nehmen.

Dazu würde man eine JSON Dokument "manuell" als einen JSON Ausdruck zusammensetzen in dem der betroffene Name mit \u.... Escape enthalten ist. Und dann diesen Ausdruck parsen und den Wert als Unicodestring abfragen.

Unter http://stackoverflow.com/a/4901205/80901 wird aber auch eine einfache Funktion zur Umwandlung gezeigt. Ist in JavaScript, dürfte aber leicht nach Delphi umsetzbar sein.
Michael Justin
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.091 Beiträge
 
Delphi 10 Seattle Enterprise
 
#6

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 10:06
Seit XE5(?) ist doch Json rundum dabei. So ware es spontan für einen String doch ok, oder?

Delphi-Quellcode:
uses
   System.SysUtils,
   System.Json; // Unter XE5 glaube ich Data.DBXJSON statt System.Json

procedure justEncodingThings();
const
   baseStrEnc: String = 'M\u00FCller';
   baseStrDec: String = 'Müller';
var
   decodedStr: String;
   jsonValue: TJSONValue;
begin
   jsonValue := TJSONObject.ParseJSONValue( baseStrEnc.QuotedString('"') );
   decodedStr := jsonValue.Value;

   Assert( decodedStr = baseStrDec );

   jsonValue.Free();
end;
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#7

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 10:13
Oder man klimpert sich das eben fix zusammen
Delphi-Quellcode:
unit JavaString;

interface

function JavaString_Decode( const AStr: string ): string;

implementation

uses
  System.SysUtils;

function OctalStrToInt( AOctal: string ): Integer;
var
  LChar: Char;
begin
  Result := 0;
  for LChar in AOctal do
    begin
      Result := Result * 8 + Ord( LChar ) - Ord( '0' );
    end;
end;

function JavaString_Decode( const AStr: string ): string;
var
  LTempBuffer: string;
  LChar: Char;
  LState: Integer;
  procedure Normal;
  begin
    case LChar of
      '\':
        LState := 1;
    else
      Result := Result + LChar;
    end;
  end;
  procedure Escape;
  begin
    case LChar of
      '\', '/', '"', '''':
        ;
      'b': // Backspace
        LChar := #$0008;
      't': // Horizontal Tab
        LChar := #$0009;
      'n': // New Line
        LChar := #$000A;
      'v': // Vertical Tab
        LChar := #$000B;
      'f': // Form Feed
        LChar := #$000C;
      'r': // Carriage Return
        LChar := #$000D;
      '0' .. '3': // Latin1 Octal
        begin
          LTempBuffer := LChar;
          LState := 2;
          Exit;
        end;
      'x': // Latin1 Hex
        begin
          LTempBuffer := '';
          LState := 3;
          Exit;
        end;
      'u': // Unicode Hex
        begin
          LTempBuffer := '';
          LState := 4;
          Exit;
        end;
    else
      raise EArgumentException.Create( 'Parse Error' );
    end;
    Result := Result + LChar;
    LState := 0;
  end;
  procedure Latin1Octal;
  var
    LByte: Byte;
  begin
    case LChar of
      '0' .. '7':
        LTempBuffer := LTempBuffer + LChar;
    else
      raise EArgumentException.Create( 'Parse Error' );
    end;
    if Length( LTempBuffer ) = 3
    then
      begin
        LByte := OctalStrToInt( LTempBuffer );
        Result := Result + TEncoding.Default.GetString( TArray<Byte>.Create( LByte ) );
        LState := 0;
      end;
  end;
  procedure Latin1Hex;
  var
    LByte: Byte;
  begin
    case LChar of
      '0' .. '9', 'A' .. 'F', 'a' .. 'f':
        LTempBuffer := LTempBuffer + LChar;
    else
      raise EArgumentException.Create( 'Parse Error' );
    end;
    if Length( LTempBuffer ) = 2
    then
      begin
        LByte := StrToInt( '$' + LTempBuffer );
        Result := Result + TEncoding.Default.GetString( TArray<Byte>.Create( LByte ) );
        LState := 0;
      end;
  end;
  procedure UnicodeHex;
  var
    LWord: Word;
  begin
    case LChar of
      '0' .. '9', 'A' .. 'F', 'a' .. 'f':
        LTempBuffer := LTempBuffer + LChar;
    else
      raise EArgumentException.Create( 'Parse Error' );
    end;
    if Length( LTempBuffer ) = 4
    then
      begin
        LWord := StrToInt( '$' + LTempBuffer );
        Result := Result + TEncoding.Unicode.GetString( TArray<Byte>.Create( Lo( LWord ), Hi( LWord ) ) );
        LState := 0;
      end;
  end;

begin
  Result := '';
  LState := 0;
  for LChar in AStr do
    case LState of
      0:
        Normal;
      1:
        Escape;
      2:
        Latin1Octal;
      3:
        Latin1Hex;
      4:
        UnicodeHex;
    end;
  if LState <> 0
  then
    raise EArgumentException.Create( 'Parse Error' );
end;

end.
Delphi-Quellcode:
procedure Main;
begin
  Writeln( JavaString_Decode( 'Copyright \251 \xA9 \u00A9' ) );
end;
ergibt dann
Code:
Copyright © © ©
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)

Geändert von Sir Rufo (28. Okt 2014 um 10:47 Uhr)
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.091 Beiträge
 
Delphi 10 Seattle Enterprise
 
#8

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 10:19
Bist du ein Zauberer?
Miniaturansicht angehängter Grafiken
you-wizard.jpg  
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#9

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 10:46
Bist du ein Zauberer?
Wieso? Die Konvention ist doch streng logisch und ich bin ganz stumpf danach vorgegangen (wie man auch am Quellcode sehen kann).

Ich hatte allerdings das \' unterschlagen
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.014 Beiträge
 
Delphi 12 Athens
 
#10

AW: Codierung/Decodierung von Umlauten

  Alt 28. Okt 2014, 13:55
Jupp, wenn man einmal weiß wie etwas im Grundprinzip funktioniert, dann kann man es
- entweder als State-Machine umsetzen
- oder in der Art des StringReplace (so hatte ich es schon im Kopf, aber keine Zeit/Lust es vorhin umzusetzen)
- man kann es auch gern als RegEx-Replace versuchen (ich glaub da hatte ich einen Code in Java/JavaScript/PHP gesehn)

Und für State-Machines gibt es sogar Generatoren, welche den Code generieren, wenn man ihnen die Konventionen nennt.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 13:46 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz