AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Mit Datenmodul arbeiten

Ein Thema von Walter Landwehr · begonnen am 26. Apr 2016 · letzter Beitrag vom 26. Apr 2016
Antwort Antwort
Seite 2 von 2     12
Benutzerbild von p80286
p80286

Registriert seit: 28. Apr 2008
Ort: Stolberg (Rhl)
6.659 Beiträge
 
FreePascal / Lazarus
 
#11

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 16:32
*gelöscht*
Gruß
K-H
Programme gehorchen nicht Deinen Absichten sondern Deinen Anweisungen
R.E.D retired error detector
  Mit Zitat antworten Zitat
mm1256

Registriert seit: 10. Feb 2014
Ort: Wackersdorf, Bayern
640 Beiträge
 
Delphi 10.1 Berlin Professional
 
#12

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 16:40
Hallo Walter,

die Trennung macht durchaus Sinn. Wenn man es aber macht, dann bitte konsequent so wie schon mehrfach vorgeschlagen, und nicht irgend so einen Misch-Masch wo sich dann wieder Teile des Datenzugriffes auf den Formularen befinden.

Mein Vorschlag: Diese procedure gehört in das Formular

Delphi-Quellcode:
procedure TfrmMitglieder.dscMitgliederDataChange(Sender: TObject; Field: TField);
begin
  ...
end;
Beim "OnActivate" und "OnDeactivate" würde ich sie jeweils im Formular zuweisen
Delphi-Quellcode:
procedure TfrmMitglieder.FormActivate(Sender: TObject);
begin
  dmMitglieder.dscMitglieder.OnDataChange := dscMitgliederDataChange;
end;
procedure TfrmMitglieder.FormDeActivate(Sender: TObject);
begin
  dmMitglieder.dscMitglieder.OnDataChange := nil;
end;
Abgesehen davon würde ich die Datenmodule generell in der .dpr erzeugen, denn oft ist es ja so, dass bei konsequenter Anwendung der Datenmodule (absolute Trennung von Datenzugriff und GUI) dann mehrere Formulare das Datenmodul problemlos verwenden können. Unterm Strich wird zudem sogar der Bildschirmaufbau etwas schneller weil die Tabelle offen bleiben kann und das Datenmodul nicht ständig neu erzeugt werden muss.
Gruss Otto
Wenn du mit Gott reden willst, dann bete.
Wenn du ihn treffen willst, schreib bei Tempo 220 eine SMS
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#13

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 16:42
Es spricht - solange keine Master/Detail DataSources in den DataSets benötigt werden - nichts dagegen, die DataSource weiterhin auf dem Formular zu lassen. Sie vermittelt zwischen GUI Controls und Datenbank-Komponenten. Messages zu versenden würde bedeuten das "RAD" noch einmal zu erfinden. Und es ensteht so auch keine ("zirkuläre") Abhängigkeit des Datenmoduls vom Formular.
Genau so mache ich das auch immer

Der DataSource (auf dem Formular) hat ein OnDataChange-Event (auf dem Formular) das etwas ... auf dem Formular auslöst. Schön einfach und trotzdem sauber getrennt.
  Mit Zitat antworten Zitat
bcvs

Registriert seit: 16. Jun 2011
664 Beiträge
 
Delphi 12 Athens
 
#14

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 17:17
Mein Vorschlag: Diese procedure gehört in das Formular

Delphi-Quellcode:
procedure TfrmMitglieder.dscMitgliederDataChange(Sender: TObject; Field: TField);
begin
  ...
end;
Das wird in diesem Fall nicht viel weiter helfen, da der TE im dscMitgliederDataChange des DataModuls auch auf andere Komponenten im Datamodul zugreift. Deshalb mein Vorschlag mit dem Event. Dadurch werden die Aktionen des DM von denen des Formulars getrennt.
  Mit Zitat antworten Zitat
Walter Landwehr

Registriert seit: 28. Mär 2006
Ort: 32816 Schieder-Schwalenberg
379 Beiträge
 
Delphi 10.4 Sydney
 
#15

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 17:43
Hallo Otto,

Klappt, Danke
Walter Landwehr
Mfg

Walter

Geändert von Walter Landwehr (26. Apr 2016 um 19:21 Uhr)
  Mit Zitat antworten Zitat
mm1256

Registriert seit: 10. Feb 2014
Ort: Wackersdorf, Bayern
640 Beiträge
 
Delphi 10.1 Berlin Professional
 
#16

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 20:30
...mein Vorschlag mit dem Event. Dadurch werden die Aktionen des DM von denen des Formulars getrennt.
Stimmt, das ist ein gutes Argument. Man ist damit flexibler, falls doch einmal etwas im Datenmodul zu erledigen wäre (was Walter aktuell zwar nicht braucht, aber das kommt bestimmt noch

@Walter Verbesserungsvorschlag:

Delphi-Quellcode:
program Project1;

uses
  Vcl.Forms,
  Unit1 in 'Unit1.pas{Form1},
  Unit2 in 'Unit2.pas{DataModule1: TDataModule};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  // Datenmodule vor dem Hauptformular erzeugen
  Application.CreateForm(TDataModule1, DataModule1);
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

//**************************************************************************************

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Data.DB;

type
  TForm1 = class(TForm)
    procedure FormActivate(Sender: TObject);
    procedure FormDeactivate(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure FormularUpdate(DataSet: TDataSet);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses Unit2;

procedure TForm1.FormActivate(Sender: TObject);
begin
  DataModule1.FormularUpdateEvent := FormularUpdate;
end;

procedure TForm1.FormDeactivate(Sender: TObject);
begin
  DataModule1.FormularUpdateEvent := nil;
end;

procedure TForm1.FormularUpdate(DataSet: TDataSet);
begin
  // Hier das Formular updaten
end;

end.

//**************************************************************************************

unit Unit2;

interface

uses
  System.SysUtils, System.Classes, FireDAC.Stan.Intf, FireDAC.Stan.Option,
  FireDAC.Stan.Param, FireDAC.Stan.Error, FireDAC.DatS, FireDAC.Phys.Intf,
  FireDAC.DApt.Intf, FireDAC.Stan.Async, FireDAC.DApt, Data.DB,
  FireDAC.Comp.DataSet, FireDAC.Comp.Client;

type
  TFormularUpdateEvent = procedure(DataSet: TDataSet) of object;
  TDataModule1 = class(TDataModule)
    FDQuery1: TFDQuery;
    procedure FDQuery1AfterScroll(DataSet: TDataSet);
    procedure DataModuleCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    FFormularUpdateEvent: TFormularUpdateEvent;
  public
    { Public-Deklarationen }
    property FormularUpdateEvent: TFormularUpdateEvent
             read FFormularUpdateEvent write FFormularUpdateEvent;
  end;

var
  DataModule1: TDataModule1;

implementation

{%CLASSGROUP 'Vcl.Controls.TControl'}

{$R *.dfm}

procedure TDataModule1.DataModuleCreate(Sender: TObject);
begin
  FormularUpdateEvent := nil;
end;

procedure TDataModule1.FDQuery1AfterScroll(DataSet: TDataSet);
begin
  // Erledige hier alles, das mit dem direkten Zugriff auf
  // Komponenten im Datenmodul zusammen hängt
  // ...
  // Formular aktualisieren:
  if Assigned(FormularUpdateEvent)
  then FormularUpdateEvent(DataSet);
end;

end.
Was mich bei dieser Gelegenheit zu der Frage veranlasst, wie man es denn eigentlich "richtig" macht?
Delphi-Quellcode:
So:
  if Assigned(FormularUpdateEvent)
  then FormularUpdateEvent(DataSet);

oder so:

  if Assigned(FFormularUpdateEvent)
  then FFormularUpdateEvent(DataSet);
Gruss Otto
Wenn du mit Gott reden willst, dann bete.
Wenn du ihn treffen willst, schreib bei Tempo 220 eine SMS
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#17

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 21:11
Was mich bei dieser Gelegenheit zu der Frage veranlasst, wie man es denn eigentlich "richtig" macht?
Delphi-Quellcode:
So:
  if Assigned(FormularUpdateEvent)
  then FormularUpdateEvent(DataSet);

oder so:

  if Assigned(FFormularUpdateEvent)
  then FFormularUpdateEvent(DataSet);
Das ist Geschmackssache und kommt daruf an, was du genau möchtest.

Willst du das Ergebnis vom Getter oder den Wert der Variablen? Damit entscheidet sich, was du verwenden musst
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
mm1256

Registriert seit: 10. Feb 2014
Ort: Wackersdorf, Bayern
640 Beiträge
 
Delphi 10.1 Berlin Professional
 
#18

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 21:59
Na ja, in diesem Fall ist es was die Funktionalität anbelangt prinzipiell egal. Ich persönlich nehme innerhalb des Objekts lieber die "F"-Variante, wenn die Property direkt auf die Objektvariable zeigt. Mit Getter und Setter würde ich dann lieber auf die Property zugreifen.
Gruss Otto
Wenn du mit Gott reden willst, dann bete.
Wenn du ihn treffen willst, schreib bei Tempo 220 eine SMS
  Mit Zitat antworten Zitat
Rollo62

Registriert seit: 15. Mär 2007
3.882 Beiträge
 
Delphi 12 Athens
 
#19

AW: Mit Datenmodul arbeiten

  Alt 26. Apr 2016, 22:18
Die Frage wäre was wäre schneller: Getter per "read FFieldVariable" oder Fieldvariable ?

Ich gehe mal einfach davon aus das der Compiler das inline setzt und gleich schnell sein wird.
Aber ist das wirklich so ?

Zumindest wenn der Getter per "read GetFieldVariable" mit Result := FFieldVariable; gemacht wird vermute ich mal der reine Variablenzugriff ist schneller.

Rollo
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 21:00 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz