AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein GUI-Design mit VCL / FireMonkey / Common Controls VirtualTreeview 6.2.5 - Node mit Daten von einer Treeview zur anderen kopieren - Wie?

VirtualTreeview 6.2.5 - Node mit Daten von einer Treeview zur anderen kopieren - Wie?

Ein Thema von TiGü · begonnen am 25. Mai 2016 · letzter Beitrag vom 26. Mai 2016
Antwort Antwort
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
3.058 Beiträge
 
Delphi 10.4 Sydney
 
#1

VirtualTreeview 6.2.5 - Node mit Daten von einer Treeview zur anderen kopieren - Wie?

  Alt 25. Mai 2016, 16:46
Hallo Gemeinde,

ich habe folgendes Verständnisproblem:

Gegeben seien zwei VirtualTreeviews (in der Version 6.2.5 falls relevant) in Delphi Seattle.

Beide liegen auf einen Formular. vstMain liegt links und vstSub liegt rechts.
Ich möchte beim Klick auf einen Node in der linken vstMain-Treeview im OnFocusedChanged diesen Node mit all seinen Children und den dazugehörigen Daten in den rechten vstSub-Treeview kopieren.
Als Daten benutze ich ganz fancy ein Interface, anstatt den altbekannten Weg mit Records.
Aus den Interface ziehe ich mir auch den Text im OnGetText-Event.

Mein erster Versuch mit TBaseVirtualTree.CopyTo und den dazugehörigen OnNodeCopying wird zwar ausgeführt und die Nodes werden auch angelegt, aber es werden nicht die Daten mitkopiert?!? Im OnGetText-Eventhandler für die vstSub werden keine Daten in den Nodes gefunden.
Warum ist das so, was mache ich falsch?

Daher muss ich die Nodes manuell mit AddChild hinzufügen, damit es funktioniert...ist DAS der Standardweg?
Hier Quelltext, im Anhang das Projekt zum selber kompilieren:

Delphi-Quellcode:
unit frmVstCopyTest;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, VirtualTrees, Vcl.StdCtrls;

type
  ITreeNode = interface
    ['{E64AAC69-EA11-4E5B-BB9C-13A6C37FB8BC}']
    function GetText: string;
  end;

  TTreeNode = class(TInterfacedObject, ITreeNode)
  strict private
    FText: string;
  public
    constructor Create(const ANumber: Integer);
    function GetText: string;
  end;

  TForm2 = class(TForm)
    vstMain: TVirtualStringTree;
    vstSub: TVirtualStringTree;
    procedure FormCreate(Sender: TObject);
    procedure vstGetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
      var CellText: string);
    procedure vstMainFocusChanged(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex);
    procedure vstMainNodeCopying(Sender: TBaseVirtualTree; Node, Target: PVirtualNode; var Allowed: Boolean);
  private
  public
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}


procedure TForm2.FormCreate(Sender: TObject);
var
  NodeData: ITreeNode;
  NewNode: PVirtualNode;
  I, J: Integer;
begin
  for I := 1 to 3 do
  begin
    NodeData := TTreeNode.Create(I);
    NewNode := vstMain.AddChild(nil, NodeData);
    for J := 1 to 10 do
    begin
      NodeData := TTreeNode.Create(J);
      vstMain.AddChild(NewNode, NodeData);
    end;
  end;
end;

{ TTreeNode }

constructor TTreeNode.Create(const ANumber: Integer);
begin
  FText := ANumber.ToString;
end;

function TTreeNode.GetText: string;
begin
  Result := 'Hallo Welt ' + FText;
end;

procedure TForm2.vstMainFocusChanged(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex);
var
  NewNode: PVirtualNode;
  ChildNode: PVirtualNode;
begin
  vstSub.Clear;
  // Das hier funktioniert NICHT:
  // NewNode := Sender.CopyTo(Node, vstSub, TVTNodeAttachMode.amAddChildLast, False);

  // das manuelle hinzufügen funktioniert, aber das kann es ja wohl nicht sein?
  NewNode := vstSub.AddChild(nil, Node.GetData<ITreeNode>);
  ChildNode := Node.FirstChild;
  while ChildNode <> nil do
  begin
    vstSub.AddChild(NewNode, ChildNode.GetData<ITreeNode>);
    ChildNode := ChildNode.NextSibling;
  end;

  vstSub.FullExpand();
end;

//Das Event hier wird zwar aufgerufen, aber GetData vom Node liefert nil -> Hä? Wie jetzt?
procedure TForm2.vstMainNodeCopying(Sender: TBaseVirtualTree; Node, Target: PVirtualNode; var Allowed: Boolean);
var
  NodeData: ITreeNode;
begin
  NodeData := Node.GetData<ITreeNode>;
  if Assigned(NodeData) then
    Target.SetData<ITreeNode>(NodeData);
end;

procedure TForm2.vstGetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
  var CellText: string);
var
  NodeData: ITreeNode;
begin
  NodeData := Node.GetData<ITreeNode>;
  if Assigned(NodeData) then
    CellText := NodeData.GetText
  else
    CellText := 'Kein Text';
end;

end.

Geändert von TiGü (26. Mai 2016 um 14:55 Uhr)
  Mit Zitat antworten Zitat
Alter Mann

Registriert seit: 15. Nov 2003
Ort: Berlin
934 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#2

AW: VirtualTreeview 6.2.5 - Node mit Daten von einer Treeview zur anderen kopieren -

  Alt 25. Mai 2016, 18:53
Hallo,

schau mal hier, vielleicht hilft es ja.
  Mit Zitat antworten Zitat
Benutzerbild von jaenicke
jaenicke

Registriert seit: 10. Jun 2003
Ort: Berlin
9.286 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: VirtualTreeview 6.2.5 - Node mit Daten von einer Treeview zur anderen kopieren -

  Alt 26. Mai 2016, 06:59
Du gehst in OnNodeCopying von einer falschen Bedeutung der Parameter aus.

Wenn man darauf einen Haltepunkt setzt oder im Quelltext den Aufruf manuell sucht, landet man in diesem Abschnitt:
Delphi-Quellcode:
            //...
            Result := TargetTree.MakeNewNode;
            InternalConnectNode(Result, Target, TargetTree, Mode);
            TargetTree.InternalAddFromStream(Stream, VTTreeStreamVersion, Result);
            if not DoNodeCopying(Result, Target) then
            //...
Wie man sieht bekommt man den neu erstellten Knoten im Zielbaum und dessen Elternknoten übergeben. Also nicht den ursprünglichen Knoten wie du vermutet hast.

Wie funktioniert das ganze eigentlich?
Die Knoten werden in einen Stream gespeichert und dann wieder daraus gelesen. Die Daten des Benutzers kann der Tree dabei aber nicht speichern, denn diese kennt er ja nicht direkt.
Deshalb gibt es zwei Events, OnSaveNode und OnLoadNode, die dafür aufgerufen werden. Dort kannst du die Daten speichern und laden, die zu dem Knoten gehören.

Der manuelle Weg ist allerdings deutlich schneller, da das ganze Speichern und Laden weg fällt.
Sebastian Jänicke
Alle eigenen Projekte sind eingestellt, ebenso meine Homepage, Downloadlinks usw. im Forum bleiben aktiv!
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 10:05 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz