AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

VirtualStringTree Komponente

Ein Thema von Zodi · begonnen am 9. Nov 2017 · letzter Beitrag vom 11. Nov 2017
Antwort Antwort
Seite 2 von 2     12
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
3.058 Beiträge
 
Delphi 10.4 Sydney
 
#11

AW: VirtualStringTree Komponente

  Alt 10. Nov 2017, 10:28
Warum steht da Form1?
Versuchst du wieder aus einen Thread heraus auf die visuellen Komponenten zuzugreifen? Bitte lass das!
http://www.delphipraxis.net/194241-l...rtualmode.html
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.610 Beiträge
 
Delphi 10.3 Rio
 
#12

AW: VirtualStringTree Komponente

  Alt 10. Nov 2017, 10:38
Wie benutzt man denn diese 2 Befehle wenn man ne VirtualStringTree benutzt.

Beispiel ist für ne normale ListView Komponente.
Delphi-Quellcode:
ListItem := form1.ListView1.FindCaption(0, EntryString, False, True, False);
for I := form1.ListView1.Items.Count - 1 downto 0 do
weil FindCaption und Items fehlen bei der VirtualStringTree.
FindCaption und Items gibt es deshalb nicht, weil die Komponenten die Daten eben nur virtuell vorhält und diese an die Node angeflanscht sind. Theoretisch könnte in deinem Text[Node] (was übrigens die Eigenschaft ist um den angezeigten Text der Node auszulesen [aber nur ttNormal und nicht ttStatic wenn ich mich richtig erinnere]) etwas ganz anderes stehen als du eigentlich in deinem DataObject drin hast. Der Node könnte theoretisch auch ein ganz anderer Text zugewiesen werden da das im OnGetText Event passiert.

Also entweder du baust dir eine Datenstruktur aus TObject (bzw. Nachfahre davon) und TObjectList<T> was die bessere Lösung ist, oder du musst per vst.GetFirst , vst.GetNext und vst.GetNodeData arbeiten und dir den entsprechenden Text aus den der Node zugewiesenen Objects/Records auslesen.
  Mit Zitat antworten Zitat
Benutzerbild von Zodi
Zodi

Registriert seit: 19. Jul 2017
Ort: Berlin
45 Beiträge
 
Delphi XE7 Ultimate
 
#13

AW: VirtualStringTree Komponente

  Alt 10. Nov 2017, 11:20
Eigentlich will ich nur meine normale Rutine so umändern das si stat die normale ListView eben die VirtualStringTree befüllt.

Delphi-Quellcode:
procedure AddList;
var
  Data: PTreeData;
  XNode: PVirtualNode;
  Rand: Integer;

  ListItem: TListItem;
  p: Integer;
  Strings, StringList: TStringList;
  CurrentString: string;
  EntryString: string;
begin

    Strings := TStringList.Create;
    StringList := TStringList.Create;
    Strings.Clear;
    Stringlist.Clear ;
    Strings.BeginUpdate;
    StringList.BeginUpdate;

    Strings.Text := Data2;

    form1.ListView1.Items.BeginUpdate;
    i := 0;
  try
    for I := 0 to Strings.Count - 1 do
    begin
      CurrentString := Strings.Strings[I];
      EntryString := Split(CurrentString, '|', 1);
      ListItem := form1.ListView1.FindCaption(0, EntryString, False, True, False);
      if ListItem = nil then
      begin
        ListItem := form1.ListView1.Items.Add;
        ListItem.Caption := EntryString;
        ListItem.SubItems.Add(Split(CurrentString, '|', 2));
        ListItem.SubItems.Add(Split(CurrentString, '|', 3));
        ListItem.SubItems.Add(Split(CurrentString, '|', 4));
        ListItem.SubItems.Add(Split(CurrentString, '|', 5));
        ListItem.SubItems.Add(Split(CurrentString, '|', 6));
      end else begin
        ListItem.StateIndex := 0;
        EntryString := Split(CurrentString, '|', 2);
        if ListItem.SubItems[0] <> EntryString then
          ListItem.SubItems[0] := EntryString;

        EntryString := Split(CurrentString, '|', 4);
        if ListItem.SubItems[2] <> EntryString then
          ListItem.SubItems[2] := EntryString;
      end;

      StringList.Add(ListItem.Caption);
    end;
      application.ProcessMessages;
    for I := form1.ListView1.Items.Count - 1 downto 0 do
    begin
      ListItem := form1.ListView1.Items[I];
      if ListItem.StateIndex = 2 then
      begin
        ListItem.Delete;
        Continue;
      end;

      p := StringList.IndexOf(ListItem.Caption);
      if p = -1 then
        ListItem.StateIndex := 2;
    end;

  finally
    form1.ListView1.Items.EndUpdate;
    form1.ListView1.Refresh;
    StringList.EndUpdate;
    Strings.EndUpdate;
    StringList.Free;
    Strings.Free;
  end;

  end;
Pascal
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.610 Beiträge
 
Delphi 10.3 Rio
 
#14

AW: VirtualStringTree Komponente

  Alt 11. Nov 2017, 11:59
Sorry hat etwas länger gedauert. Ich hoffe du bist noch am Versuchen.

Ein VirtualTreeView arbeitet etwas anders als ein ListView. Dem ListView kannst du die Elemente mit Items.Add hinzufügen. Dem VST gibst du an der Stelle (optimalerweise) den RootNodeCount bzw. ChildNodeCount. Es geht zwar auch mit vst.AddChild(), aber das ist eigentlich nicht der korrekte Weg.

Zum Vorhalten von Daten schreibe ich mir z.B. eine Klasse in der dann die Werte gespeichert werden (es geht aber auch mit einem Record). Leider habe ich bei dir jetzt keine besonder gut bezeichneten Eigenschaften gefunden. Lediglich Column0, Column1, Column2, ... (wahrscheinlich bis 5).


Ich habe da jetzt im Editor mal etwas zusammengeschrieben um die einen kleinen Anhaltspunkt zum Erstellen eines VST zu geben. Das ist natürlich jetzt nicht vollständig, aber ich hoffe es hilf dir im Ansatz schon mal weiter. Du kannst ja mal versuchen mit dem Beispiel etwas aufzubauen und dich bei Problemen dann nochmal melden.

Aber auf jeden Fall solltest du dran bleiben. Wenn du den VST einmal richtig zum Laufen gebracht hast, dann willst du mit keiner anderen Komponente mehr arbeiten die eine Listenansicht bieten soll.


Anbei mal das Beispiel:

Delphi-Quellcode:
interface

type
  TMyData = class
  private
    FColumn0: string;
    FColumn1: string;
    FColumn2: string;
    FColumn3: string;
    FColumn4: string;
    FColumn5: string;
  public
    property Column0: string read FColumn0 write FColumn0;
    property Column1: string read FColumn1 write FColumn1;
    property Column2: string read FColumn2 write FColumn2;
    property Column3: string read FColumn3 write FColumn3;
    property Column4: string read FColumn4 write FColumn4;
    property Column5: string read FColumn5 write FColumn5;
  end;
  PMyData = ^TMyData;

  TMyDataList = TObjectList<TMyData>; // Hier wird System.Generics.Collections in den Uses benötigt


var
  MyDataList: TMyDataList; // Liste um alle Elemente vorzuhalten und zu speichern (Sollte natürlich im Private Abschnitt der Form Klasse definiert sein)

implementation

procedure TForm1.CreateData;
var
  Data: TMyData;
  s: TStringDynArray;
  i: Integer;
  sl: TStringList;
begin
  sl := TStringList.Create;
  try
    FillWithData(sl); // Deine StringListe mit Daten füllen. In deinem Beispiel wird ein Text zugewiesen. Das musst du dann eben übernehmen
    for i := 0 to sl.Count - 1 do begin
      Data := TMyData.Create;
      s := Split(sl[i], '|');
      Data.Column0 := s[0];
      Data.Column1 := s[1];
      Data.Column2 := s[2];
      Data.Column3 := s[3];
      Data.Column4 := s[4];
      Data.Column5 := s[5];
      MyDataList.Add(Data); // Daten in die Liste aufnehemen
    end;

    vst.RootNodeCount := MyDataList.Count; // RootNodeCount des Trees setzen
  finally
    sl.Free;
  end;
end;


// Achtung: Procedure Header aus dem Kopf geschrieben. Es kann sein, dass hier etwas fehlt
procedure TForm1.vstInitNode(Sender: TBaseVirtualTree; Node: PVirtualNode; var InitialStates: TVTInitialStates);
var
  NodeData: PMyData;
begin
  NodeData := Sender.GetNodeData(Node);
  // Hier wird das Element/Objekt aus der Liste mir der Node verknüpft
  // Man könnte der Node auch nur den Index des Elements zuweisen der sogar immer nur die Daten
  // an dem speziellen Index der Node aus der Liste laden. Dann muss man nur aufpassen, wenn man
  // die Liste mal sortieren will
  NodeData^ := MyDataList[Node^.Index];
end;

procedure TForm1.vstGetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; var CellText: string);
var
  NodeData: PMyData;
begin
  NodeData := Sender.GetNodeData(Node);

  case Column of
    0: CellText := NodeData^.Column0;
    1: CellText := NodeData^.Column1;
    2: CellText := NodeData^.Column2;
    3: CellText := NodeData^.Column3;
    4: CellText := NodeData^.Column4;
    5: CellText := NodeData^.Column5;
  end;
end;

Geändert von Aviator (11. Nov 2017 um 12:01 Uhr)
  Mit Zitat antworten Zitat
generic

Registriert seit: 24. Mär 2004
Ort: bei Hannover
2.415 Beiträge
 
Delphi XE5 Professional
 
#15

AW: VirtualStringTree Komponente

  Alt 11. Nov 2017, 18:37
Das mit dem Objekten im VST geht etwas einfacher - funktioniert aber auch so wie du das machst.

Falls du Inspiration brauchst, hier der Beitrag vom 2. DP Stammtisch:
http://www.delphipraxis.net/712774-post4.html
Coding BOTT - Video Tutorials rund um das Programmieren - https://www.youtube.com/@codingbott
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.610 Beiträge
 
Delphi 10.3 Rio
 
#16

AW: VirtualStringTree Komponente

  Alt 11. Nov 2017, 18:55
In deinem Beispiel benutzt du aber die AddChild() Methode die ich aber nicht verwenden will und die auch lt. Kommentar nicht verwendet werden sollte. Oder habe ich etwas übersehen?
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:15 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz