AGB  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Externes Programm ausführen

Ein Thema von Willie1 · begonnen am 11. Dez 2017 · letzter Beitrag vom 17. Jan 2018
Antwort Antwort
Seite 2 von 5     12 34     Letzte » 
Willie1

Registriert seit: 28. Mai 2008
251 Beiträge
 
Delphi 10.1 Berlin Starter
 
#11

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 15:35
Hallo,
in dem Temp-Ordner. Bei mir c:\users\nutzername\appdata\local\temp (ermittelt durch Windows-Funktion).
Auf dem Desktop-PC: Windows 10 1709 Built 16299.98 von letzter Woche. Hier gehsts nicht
Laptop: Windows 10 1709 Built 15062.726. Hier gehts.

Ich hab's gerade nochmal auf dem Laptop versucht, die Datei hänge ich an, ebenso einen Auszug aus der Doku von Phil Harvey zu Exiftool.

Ich werde ein Testprogramm entwickeln und sehen, ob ich dann heraus finde, warum die Datei nicht gespeichert wird.

Willie.
Angehängte Dateien
Dateityp: txt 2014.12.25=16-36-05.txt (6,4 KB, 8x aufgerufen)
Dateityp: txt Exiftool_Doku-Para-w.txt (2,0 KB, 4x aufgerufen)
  Mit Zitat antworten Zitat
hoika

Registriert seit: 5. Jul 2006
Ort: Magdeburg
5.993 Beiträge
 
Delphi XE4 Professional
 
#12

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 15:45
Hallo,
ist es der gleiche Benutzername?
Heiko
  Mit Zitat antworten Zitat
Willie1

Registriert seit: 28. Mai 2008
251 Beiträge
 
Delphi 10.1 Berlin Starter
 
#13

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 18:31
Ja!

Ich habe Exiftool in der "Eingabeaufforderung" ausgeführt und die Datei in den TEMP-Ordner ablegen wollen, ging nicht "Zugriff verweigert".

Willie.

Geändert von Willie1 (12. Dez 2017 um 18:43 Uhr)
  Mit Zitat antworten Zitat
LTE5

Registriert seit: 13. Nov 2017
315 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#14

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 18:33
Sicher, dass du TEMP eingegeben hast und nicht %TEMP% ?

Ist meiner Meinung nach aber kein Codeproblem sondern nur ein verkorkstes Windows 10.
  Mit Zitat antworten Zitat
Willie1

Registriert seit: 28. Mai 2008
251 Beiträge
 
Delphi 10.1 Berlin Starter
 
#15

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 18:56
Da könntest du recht haben. Es sieht wohl so aus, dass Exiftool die Datei nicht in TEMP schreiben kann.
Morgen werde ich es nochmal versuchen.
Da fällt mir gerade ein, könnte der Virenwächter dazwischen funken? Schließlich wird eine Datei erzeugt und abgelegt.

Willie.
  Mit Zitat antworten Zitat
Benmik

Registriert seit: 11. Apr 2009
190 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#16

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 21:56
EXIF Tool ist auch für mich ein extrem interessantes Programm. Nur der Weg über diese temporären Dateien stört mich enorm.
Geht eigentlich nicht der Weg über eine pipe? Auf Harveys Seite gibt es einen Link zu VB-Beispiel-Code, der das über CreatePipe macht. Siehe vielleicht auch diese Beiträge hier.

PS: Bin ja doof, ich sehe eben, die Umsetzung schlummert schon längst auf meiner Festplatte...

Hier ist die Unit:
Delphi-Quellcode:
unit ExifTool;

interface
uses Classes;

var
  ETout, ETerr: TStringList; //data from ExifTool will be here

function ExecuteET(const ETcmd,WorkDir: string): Boolean;

implementation
uses Windows;

function ExecuteET(const ETcmd,WorkDir: string): Boolean;
const
  szBuffer=255;
var
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
  PWorkDir: PChar;
  SecurityAttr: TSecurityAttributes;
  PipeOutputRead: THandle;
  PipeOutputWrite: THandle;
  PipeErrorsRead: THandle;
  PipeErrorsWrite: THandle;
  Succeed: Boolean;
  Buffer: array [0..szBuffer] of Char;
  BytesRead: DWORD;
  Stream: TMemoryStream;
begin
  //=== Usual steps to initialize data for CreateProcess:
  FillChar(Buffer,SizeOf(Buffer),0);
  FillChar(ProcessInfo, SizeOf(TProcessInformation), 0);
  FillChar(SecurityAttr, SizeOf(TSecurityAttributes), 0);
  SecurityAttr.nLength := SizeOf(SecurityAttr);
  SecurityAttr.bInheritHandle := true;
  SecurityAttr.lpSecurityDescriptor := nil;
  CreatePipe(PipeOutputRead, PipeOutputWrite, @SecurityAttr, 0);
  CreatePipe(PipeErrorsRead, PipeErrorsWrite, @SecurityAttr, 0);
  FillChar(StartupInfo, SizeOf(TStartupInfo), 0);
  StartupInfo.cb:=SizeOf(StartupInfo);
  with StartupInfo do begin
    hStdInput:=0; hStdOutput:=PipeOutputWrite; hStdError:=PipeErrorsWrite;
    wShowWindow:=SW_HIDE;
    dwFlags:=STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
  end;
  if WorkDir='then PWorkDir:=nil else PWorkDir:=PChar(WorkDir);
  ETout.Clear; ETerr.Clear;

  //=== Here is where ExifTool is called:
  if CreateProcess(nil, PChar(ETcmd), nil, nil, true,
    CREATE_DEFAULT_ERROR_MODE or CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS,
    nil, PWorkDir, StartupInfo, ProcessInfo)
  then begin //=ExifTool started successfully:
    result:=true;
    CloseHandle(PipeOutputWrite);
    CloseHandle(PipeErrorsWrite);
  end else begin //=ExifTool not started (because, i.e. not found):
    result:=false;
    CloseHandle(PipeOutputRead); CloseHandle(PipeOutputWrite);
    CloseHandle(PipeErrorsRead); CloseHandle(PipeErrorsWrite);
  end;

  if result then begin
    //= Get output written by ExifTool(tag names/values):
    Stream:=TMemoryStream.Create;
    try
      repeat
        succeed:=ReadFile(PipeOutputRead,Buffer,szBuffer,BytesRead,nil);
        if not succeed then break;
        Stream.Write(Buffer,BytesRead)
      until (BytesRead=0);
      Stream.Position:=0; ETout.LoadFromStream(Stream);
    finally Stream.Free; end;
    CloseHandle(PipeOutputRead);
    //= Get errors written by ExifTool (if any):
    Stream:=TMemoryStream.Create;
    try
      repeat
        succeed:=ReadFile(PipeErrorsRead,Buffer,szBuffer,BytesRead,nil);
        if not succeed then break;
        Stream.Write(Buffer,BytesRead);
      until (BytesRead=0);
      Stream.Position:=0; ETerr.LoadFromStream(Stream);
    finally Stream.Free; end;
    CloseHandle(PipeErrorsRead);

    WaitForSingleObject(ProcessInfo.hProcess,5000); //=5sec
    CloseHandle(ProcessInfo.hThread); CloseHandle(ProcessInfo.hProcess);
  end;
end;

initialization
begin
  ETout:=TStringList.Create;
  ETerr:=TStringList.Create;
end;

finalization
begin
  ETerr.Free;
  ETout.Free;
end;

end.
Aufruf:
Delphi-Quellcode:
  procedure FühreTestCodeAus;
  var ETool,ETCmd,Datname:string;
  begin
    ETool := 'C:\EXIFTool\exiftool.exe ';
    ETCmd := ' -k -a -u -g1 -lang de ';
    Datname := '"C:\Temp\Test\01-Testdatei.JPG"';
    ExecuteET(ETool + ETCmd + Datname,'');
  end;
Das Ergebnis ist dann in ETout
Angehängte Dateien
Dateityp: pas EXIFTool.pas (3,2 KB, 5x aufgerufen)

Geändert von Benmik (12. Dez 2017 um 23:21 Uhr) Grund: Erst nachsehen, dann posten
  Mit Zitat antworten Zitat
Delphi.Narium

Registriert seit: 27. Nov 2017
161 Beiträge
 
#17

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 23:02
Handelt es sich bei dem Inhalt der Temp-Datei um die Konsolenausgabe des ExifTools, die per > in 'ne Datei umgeleitet wurde?

Dann mal hier im Forum nach "Process Pipe" suchen. Da müsste was brauchbares zu finden sein, per Pipe bekommt man die Konsolenausgabe des ExifTools dann direkt ins Programm geliefert.
  Mit Zitat antworten Zitat
Benmik

Registriert seit: 11. Apr 2009
190 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#18

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 23:26
Handelt es sich bei dem Inhalt der Temp-Datei um die Konsolenausgabe des ExifTools, die per > in 'ne Datei umgeleitet wurde?
Nein, dafür gibt es bei EXIFTools einen eigenen Schalter. Die Erläuterung hierzu hat er ja auch als Datei beigefügt.
  Mit Zitat antworten Zitat
Delphi.Narium

Registriert seit: 27. Nov 2017
161 Beiträge
 
#19

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 23:49
Ok. Und wenn man den Schalter weglässt, dann erfolgt die Ausgabe auf die Konsole und kann dann (ohne Datei) per Pipe ins Programm übernommen werden.

Er wäre (denk ich) mal 'nen Versuch wert, ob man so die Kommunikation zwischen Programm und ExifTool vereinfachen kann und man muss sich dann nicht darum kümmern, ob man für (nur temporär benötigte) Dateien alle erforderlichen Rechte hat.
  Mit Zitat antworten Zitat
Benmik

Registriert seit: 11. Apr 2009
190 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#20

AW: Externes Programm ausführen

  Alt 12. Dez 2017, 23:59
Vielleicht hast du meine Antwort übersehen (#16).
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 23:21 Uhr.
Powered by vBulletin® Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2017 by Daniel R. Wolf