RichEdit: Farbige Zeilen

[Pseudemys Nelsoni]

Moin,

ich benutze folgenden Code um eine farbige Zeile in mein RichEdit zu bekommen:

Delphi-Quellcode:

procedure AddColoredLine(ARichEdit: TRichEdit; AText: string; AColor: TColor);
begin
  with ARichEdit do
  begin
    SelStart := Length(Text);
    SelAttributes.Color := AColor;
    SelAttributes.Size := 8;
    SelAttributes.Name := 'Tahoma';
    Lines.Add(AText);
  end;
end;

Das funktioniert auch soweit, nur wenn ich folgendes mache:

RichEdit1.Text := RichEdit1.Text + 'hi'; Dann ist der komplette Text wieder schwarz. Jemand ne Ahnung wie das kommt?

[marabu]

Hallo Mario,

wenn du mit der Text-Eigenschaft arbeitest, dann werden die DefAttributes der RichEdit-Komponente angezogen.

Grüße vom marabu

[Pseudemys Nelsoni]

Moin marabu,

hast du ne ahnung was ich da tun kann? ich bekomme naemlich immer einzelne zeichen für das richedit, und dafür kann ich kein lines.add() benutzen, da ich dann am ende von oben nach unten statt von links nach rechts lesen müsste <g>

[marabu]

Mach es so:

Delphi-Quellcode:

procedure AddColoredString(ARichEdit: TRichEdit; AText: string; AColor: TColor);
begin
  with ARichEdit do
  begin
    SelStart := Length(Text);
    SelAttributes.Color := AColor;
    SelAttributes.Size := 8;
    SelAttributes.Name := 'Tahoma';
    SelText := AText;
  end;
end;

procedure TDemoForm.ButtonClick(Sender: TObject);
begin
  // AddColoredLine(RichEdit, 'asdfhskgfsdgfjhsdfjsd', clRed);
  AddColoredString(RichEdit, 'asdfhskgfsdgfjhsdfjsd'#13#10, clRed);
end;

marabu

[Pseudemys Nelsoni]

Besten Dank, geht einwandfrei

[RavenIV]

aber dann darf man keinRichEdit.Lines.Add(...); mehr machen, weil sonst der testliche Text auch farbig ist.

[Lannes]

Hallo,

mit der geänderten Prozedur:

Delphi-Quellcode:

procedure AddColoredString(ARichEdit: TRichEdit; AText: string; AColor: TColor);
var oldColor : TColor;
begin
  with ARichEdit do
  begin
    setfocus;
    SelStart := Length(Text);
    oldColor := SelAttributes.Color;
    SelAttributes.Color := AColor;
    SelAttributes.Size := 8;
    SelAttributes.Name := 'Tahoma';
    SelText := AText;
    SelAttributes.Color := oldColor;
  end;
end;

darf man dann auch per add Zeilen hinzufügen, die die zuvor vorhandene Textfarbe annehmen.