AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) [D2010] Dateien in Zwischenablage kopieren (PDF)

[D2010] Dateien in Zwischenablage kopieren (PDF)

Ein Thema von H3llsing · begonnen am 29. Jul 2010 · letzter Beitrag vom 16. Mai 2015
Antwort Antwort
Seite 1 von 3  1 23   
H3llsing

Registriert seit: 12. Nov 2008
96 Beiträge
 
Delphi 2010 Enterprise
 
#1

[D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 29. Jul 2010, 13:06
Hallo DPler,

entschuldigt bitte wenn ich ein weiteres Thema zu den vielen anderen Clipboard-Themen erstelle, aber die anderen führen leider nicht zur Lösung.
Nun zu meinem Problem:
Ich möchte gerne Dateien in die Zwischenablage kopieren und woanders einfügen. Beim kopieren geht etwas schief

dazu verwende ich diesen Code:
Delphi-Quellcode:
//################################################
// CopyFilesToClipboard
//################################################
procedure TfrmAnfrage.CopyFilesToClipboard(FileList: string);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList) + 2;
  FileList := FileList + #0#0;
  hGlobal := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE,
    SizeOf(TDropFiles) + iLen);
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  begin
    DropFiles := GlobalLock(hGlobal);
    DropFiles^.pFiles := SizeOf(TDropFiles);
    Move(FileList[1], (PChar(DropFiles) + SizeOf(TDropFiles))^, iLen);

    GlobalUnlock(hGlobal);
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  end;
end
ich habe
(PChar(DropFiles) durch
(PAnsiChar(DropFiles) bereits ersetzt da es sonst zu einem Fehler beim kopieren führt.

dann habe ich das Tool Clipboard-Explorer besorgt
und folgende abweichung beim kopieren im Explorer und beim kopieren per Programm festgestellt:

Explorer: HDROP: C:\Users\XXX\Documents\RAD Studio\Projekte\Hexacom\SalesBoard\bin\Anhang\10_P romotion2010_Q3.pdf
Programm: HDROP: C:\Users\XXX\Documents\RAD Studio\Projekte\He????.?.lesBoard\bin\Anhang\10_Pr omotion2010_Q3.pdf

desweiteren wird per programm nur der HDROP erstellt.
Beim Explorer kopieren der PDF: an die 11 Formate (DataObject,ShellIDListArray,dataobjectAtrribute.. .usw)

Ich wäre euch für jeden Tipp sehr Dankbar!

MFG
H3llsing
  Mit Zitat antworten Zitat
H3llsing

Registriert seit: 12. Nov 2008
96 Beiträge
 
Delphi 2010 Enterprise
 
#2

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 10:44
hat niemand ne idee woran es liegen könnte ?
  Mit Zitat antworten Zitat
Benutzerbild von MarcoWarm
MarcoWarm

Registriert seit: 10. Sep 2003
Ort: Großhennersdorf
532 Beiträge
 
Delphi 10.1 Berlin Professional
 
#3

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 10:51
Was genau ist PDropFiles ?
Soll heißen ... auf welchen Typ ist das ein Pointer?
Marco Warm
TUO
TheUnknownOnes.net
  Mit Zitat antworten Zitat
H3llsing

Registriert seit: 12. Nov 2008
96 Beiträge
 
Delphi 2010 Enterprise
 
#4

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 11:44
Da ich noch Delphi-Anfänger bin kann ich dir die frage nicht genau beantworten.

MSDN MSDN-Library durchsuchenDROPFILES Structure ist zu entnehmen dass es ein Pointer aufs CF_HDROP Clipboard format ist. Dem die Daten in einer Liste von Filenamen vorliegt, die mit doppeltem #0 schließt.

ich hoffe ich lieg damit einiger maßen richtig

Die Funktion ist übrigens von den Schweizern Hier zu finden
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.454 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 11:54
Ich vermute ein Unicode-Problem. Wie sieht es so aus?
Delphi-Quellcode:
procedure TfrmAnfrage.CopyFilesToClipboard(FileList: AnsiString);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList) + 2;
  FileList := FileList + #0#0;
  hGlobal := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE,
    SizeOf(TDropFiles) + iLen);
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  begin
    DropFiles := GlobalLock(hGlobal);
    DropFiles^.pFiles := SizeOf(TDropFiles);
    Move(FileList[1], (PAnsiChar(DropFiles) + SizeOf(TDropFiles))^, iLen);

    GlobalUnlock(hGlobal);
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  end;
end
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
H3llsing

Registriert seit: 12. Nov 2008
96 Beiträge
 
Delphi 2010 Enterprise
 
#6

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 12:12
wunderbar =D
DeddyH du bist mein Held

Bin nicht draufgekommen es bei dem Funktionsparameter selbst umzustellen.

außerdem musste noch folgende Zeile geändert werden

hGlobal := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE, in
hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT,
GesamtCode:
Delphi-Quellcode:
//################################################
// CopyFilesToClipboard
//################################################
procedure TfrmAnfrage.CopyFilesToClipboard(FileList: Ansistring);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList) + 2;
  FileList := FileList + #0#0;
  hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT,
    SizeOf(TDropFiles) + iLen);
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  begin
    DropFiles := GlobalLock(hGlobal);
    DropFiles^.pFiles := SizeOf(TDropFiles);
    Move(FileList[1], (PAnsiChar(DropFiles) + SizeOf(TDropFiles))^, iLen);

    GlobalUnlock(hGlobal);
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  end;
end;

Vielen Dank an euch beide =)
  Mit Zitat antworten Zitat
Benutzerbild von MarcoWarm
MarcoWarm

Registriert seit: 10. Sep 2003
Ort: Großhennersdorf
532 Beiträge
 
Delphi 10.1 Berlin Professional
 
#7

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 12:49
*räusper*

Ein Unicode-Problem sollte man nicht damit lösen es zu ignorieren. Falls mal Unicodezeichen im Pfad vorkommen 'المسار_الأكاديمي.png' ... (oops hoffentlich hat google das richtig übersetzt) hilft dir diese routine nicht weiter. Also besser so:



Delphi-Quellcode:
procedure CopyFilesToClipboard(FileList: string);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList);
  hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT, SizeOf(TDropFiles) + ((iLen + 2) * SizeOf(Char)));
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  try
    DropFiles := GlobalLock(hGlobal);
    if (DropFiles = nil) then raise Exception.Create('Could not access allocated memory.');
    try
      DropFiles^.pFiles := SizeOf(TDropFiles);
      DropFiles^.fWide := (SizeOf(Char) = SizeOf(WideChar));

      if FileList <> 'then
        Move(FileList[1], (PByte(DropFiles) + SizeOf(TDropFiles))^, iLen * SizeOf(Char));
    finally
      GlobalUnlock(hGlobal);
    end;
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  except
    GlobalFree(hGlobal);
  end;
end;
Dann geht auch sowas:

Delphi-Quellcode:
procedure TForm2.Button1Click(Sender: TObject);
begin
  CopyFilesToClipboard('C:\Temp\المسار_الأكاديمي.png');
end;
viel Spaß

Marco
Marco Warm
TUO
TheUnknownOnes.net
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
40.460 Beiträge
 
Delphi 11 Alexandria
 
#8

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 12:57
Ich vermute ein Unicode-Problem.
Nee, hier würde mal das Unicodeproblem auftreten, wenn man den Code genauso in einem älteren Delphi ausführt.

Diese Strucktur muß als Unicode vorliegen.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list
  Mit Zitat antworten Zitat
Benutzerbild von MarcoWarm
MarcoWarm

Registriert seit: 10. Sep 2003
Ort: Großhennersdorf
532 Beiträge
 
Delphi 10.1 Berlin Professional
 
#9

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 13:01
Diese Strucktur muß als Unicode vorliegen.
Die Struktur selbst ist in jeder Version gleich, da sie selbst keine Stringdaten enthält. Da gibt es keine Unicodeversion. Daher auch das boolsche Wide-Flag
Marco Warm
TUO
TheUnknownOnes.net
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.454 Beiträge
 
Delphi 11 Alexandria
 
#10

AW: [D2010] Dateien in Zwischenablage kopieren (PDF)

  Alt 2. Aug 2010, 13:15
Eine Frage noch: müsste das letzte except nicht eigentlich ein finally sein?
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 3  1 23   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 09:32 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf