AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Cross-Platform-Entwicklung Form laden: Localizeloading in InitHeritedcomponent

Form laden: Localizeloading in InitHeritedcomponent

Ein Thema von Harry Stahl · begonnen am 10. Jun 2018 · letzter Beitrag vom 10. Jun 2018
Antwort Antwort
Benutzerbild von Harry Stahl
Harry Stahl

Registriert seit: 2. Apr 2004
Ort: Bonn
1.424 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#1

Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 12:09
Ich habe hier ein FMX-Project, wo das Laden der Mainform ca. 6-7 Sekunden dauert (ist aber erst seit einiger Zeit so).

Wenn ich per Debugging nach Application.Run durch den Code gehe, ist es der Aufruf in "InitInheritedComponent" (aus System.Classes) und zwar der Aufruf von der Procedure "NotifyGlobalLoading".

Ich verstehe dabei nicht so ganz, wie der Booleanwert für "LocalizeLoading" gesetzt wird oder ob man das irgendwie beeinflussen kann (so dass LocalizeLoading false ist und NotifiyGlobalLoading nicht aufgerufen werden muss).

Jemand eine Idee?

Delphi-Quellcode:
function InitInheritedComponent(Instance: TComponent; RootAncestor: TClass): Boolean;

  function InitComponent(ClassType: TClass): Boolean;
  begin
    Result := False;
    if (ClassType = TComponent) or (ClassType = RootAncestor) then Exit;
    Result := InitComponent(ClassType.ClassParent);
    Result := InternalReadComponentRes(ClassType.ClassName,
      FindResourceHInstance(FindClassHInstance(ClassType)), Instance) or Result;
  end;

var
  LocalizeLoading: Boolean;
begin
  GlobalNameSpace.BeginWrite; // hold lock across all ancestor loads (performance)
  try
    LocalizeLoading := (Instance.ComponentState * [csInline, csLoading]) = [];
    if LocalizeLoading then BeginGlobalLoading; // push new loadlist onto stack
    try
      Result := InitComponent(Instance.ClassType);
      if Result then Instance.ReadDeltaState;
      if LocalizeLoading then NotifyGlobalLoading; // < ---- call Loaded [das brauch Zeit!!]
    finally
      if LocalizeLoading then EndGlobalLoading; // pop loadlist off stack
    end;
  finally
    GlobalNameSpace.EndWrite;
  end;
end;
NotifyGloballoading sieht so aus:

Delphi-Quellcode:
procedure NotifyGlobalLoading;
var
  I: Integer;
  G: TList<TComponent>;
begin
  G := GlobalLoaded; // performance: eliminate repeated trips through TLS lookup
  for I := 0 to G.Count - 1 do
    TComponent(G[I]).Loaded;
end;

Geändert von Harry Stahl (10. Jun 2018 um 12:14 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
5.663 Beiträge
 
Delphi 10.2 Tokyo Architect
 
#2

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 12:20
LocalizeLoading := (Instance.ComponentState * [csInline, csLoading]) = [];
Bedeutet: LocalizeLoading wird auf True gesetzt, wenn die Schnittmenge zwischen Instance.ComponentState und [csInline, csLoading] leer ist. Mit anderen Worten, wenn Instance.ComponentState weder csInline noch csLoading enthält.

Einen Einfluss auf dieses Zustand hast du nicht, da diese Werte vom Streaming-System intern gesetzt werden.

Hast du irgendwo ein Loaded überschrieben?
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von Harry Stahl
Harry Stahl

Registriert seit: 2. Apr 2004
Ort: Bonn
1.424 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#3

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 12:28
Nein, habe da nichts überschrieben...
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
5.663 Beiträge
 
Delphi 10.2 Tokyo Architect
 
#4

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 12:57
Nein, habe da nichts überschrieben...
Kannst du irgendwie feststellen, wo die Zeit verbraucht wird?

Alternativ: Kannst du ein Testprojekt bereitstellen, das dieses Verhalten zeigt?
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von Harry Stahl
Harry Stahl

Registriert seit: 2. Apr 2004
Ort: Bonn
1.424 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#5

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 14:15
Ich habe mal eine lokale Kopie von der System.classes.pas gemacht und bin da mal durch die Procedure "NotifyGlobalLoading" mit verschiedenen Debugger-Einstellungen.

Ergebnis ist, dass es am MainMenu (laden der Komponente Menu1) liegt und zwar dann, wenn eine TImageList damit verbunden ist (ganze 6 Sekunden Unterschied).

Geändert von Harry Stahl (10. Jun 2018 um 14:23 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Harry Stahl
Harry Stahl

Registriert seit: 2. Apr 2004
Ort: Bonn
1.424 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#6

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 14:22
Habe mal eine leere Form erzeugt, da das Menu und die TImageList drauf, Project anbei.

Wenn man das compiliert und ausführt, dauert es einige Sekunden, bis sich die Form zeigt.

Wenn man den Link im Menü zur ImageList entfernt, neu kompiliert und ausführt, ist das Programm sofort da.

Wieso nur?
Angehängte Dateien
Dateityp: zip MenuTest.zip (134,6 KB, 3x aufgerufen)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
5.663 Beiträge
 
Delphi 10.2 Tokyo Architect
 
#7

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 15:23
Offenbar eine eher suboptimale Umsetzung des Windows-Menüs unter FMX. TPlatformWin.UpdateMenuItem interessiert sich nur mäßig für das aktuelle AItem (sucht immer das RootMenu) und gar nicht für AChange, den Grund des Update. Vielmehr löst jeder Aufruf dieser Routine einen Neuaufbau des gesamten Menüs aus. Da beim Setzen der ImageList aber jeder Menüpunkt durchlaufen wird, erfolgt für jeden Menüpunkt auch ein kompletter Neuaufbau.

Du kannst das einfach sehen, wenn du in deinem Beispiel einen Button mit folgendem Event zufügst:
Delphi-Quellcode:
  Menu1.Images := nil;
  Menu1.Images := imMain;
Ein Workaround ist ein bisschen tricky und auch unsauber. Deklariere vor deinem Form die folgende Interposer Class:
Delphi-Quellcode:
type
  TMenuItem = class(FMX.Menus.TMenuItem)
    procedure DoBitmapChanged; override;
  end;

type
  TForm16 = class(TForm)
    Menu1: TMainMenu;
...
procedure TMenuItem.DoBitmapChanged;
begin
  SetDesigning(True, False);
  inherited;
  SetDesigning(False, False);
end;
Das verhindert den jeweiligen Neuaufbau des Windows-Menüs. Daher musst du das selbst noch im FormCreate nachholen:
Delphi-Quellcode:
procedure TForm16.FormCreate(Sender: TObject);
begin
  Menu1.RecreateOSMenu;
end;
Kann gut sein, daß das für andere Plattformen nicht nötig ist oder dort sogar Probleme auslöst. Dann musst du den entsprechenden Code in passende IFDEFs packen.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von Harry Stahl
Harry Stahl

Registriert seit: 2. Apr 2004
Ort: Bonn
1.424 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#8

AW: Form laden: Localizeloading in InitHeritedcomponent

  Alt 10. Jun 2018, 15:57
Super Uwe, ich bin beeindruckt.

Ich quälte mich gerade auch durch die FMX.Menus.pas, um weiteres Licht ins Dunkel zu bringen.
Aber mit Deinem Work-Around kann ich leben, der funktioniert hier super. Musste in anderen Units, welche das Hauptformular includierten noch einige

tm: TMenuItem;

durch

tm: FMX.Menus.TMenuItem;

ersetzen, aber das war's dann auch schon.

Vielen Dank, das erleichtert mir auch das weitere Testen, auf einem anderen (langsameren) Rechner hat sich die Startzeit des Programms schon auf 20 Sekunden aufaddiert, jetzt geht's dort wieder in insgesamt 4 Sek (incl. laden einer Maildatei mit 50.000 Maileinträgen).

Übrigens: Bei TMenubar tritt das Problem nicht auf. TMainMenu hat aber wohl auch noch andere Probleme, z.B. dass das OnClickEvent eines Hauptmenüeintrages der Menüzeile nicht ausgeführt wird.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 03:28 Uhr.
Powered by vBulletin® Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2018 by Daniel R. Wolf