AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Cross-Platform-Entwicklung Delphi Android: Reagieren auf DeletingItem im Listview

Android: Reagieren auf DeletingItem im Listview

Ein Thema von amigage · begonnen am 14. Jun 2018 · letzter Beitrag vom 8. Jul 2018
Antwort Antwort
amigage

Registriert seit: 11. Nov 2005
Ort: Leipzig
270 Beiträge
 
Delphi 11 Alexandria
 
#1

Android: Reagieren auf DeletingItem im Listview

  Alt 14. Jun 2018, 15:16
Hallo,

ich bin fast am Verzweifeln und wende mich daher wieder einmal euch.

Ich habe eine Android App mit einem TListView. Die Einträge kann man mit einem "Swipe" löschen.
Abgesehen davon, dass der "Delete" Button in der Liste hässlich aussieht (anderes Thema), bekomme ich es nicht hin, VOR dem tatsächlichen Löschen des Eintrags eine Abfrage einzublenden, um das Löschen zur Not abzubrechen.

Delphi-Quellcode:
procedure TMainDlg.LVDeletingItem(Sender: TObject; AIndex: Integer;
  var ACanDelete: Boolean);
begin
  TDialogService.PreferredMode := TDialogService.TPreferredMode.Platform;
  TDialogService.MessageDialog(txt_DeleteItem, System.UITypes.TMsgDlgType.mtConfirmation,
    [System.UITypes.TMsgDlgBtn.mbYes, System.UITypes.TMsgDlgBtn.mbNo],
    System.UITypes.TMsgDlgBtn.mbYes, 0,
    procedure(const AResult: TModalResult)
    var
      itemNo: integer;
      LI: TListViewItem;
    begin
      Case AResult of
          mrYes: begin
                   LI := MainDlg.LV.Items[AIndex];
                   itemNo := LI.Data['i'].AsInteger;
                   EntryList.Delete(itemNo);
                 end;
          mrNo: begin
                   ACanDelete := false;
                 end;
        End;
    end);
end;
Hier kommt die Fehlermeldung: E2555 Symbol 'ACanDelete' kann nicht erfasst werden

Also habe ich versucht, es anders zu übergeben.

Delphi-Quellcode:
procedure TMainDlg.LVDeletingItem(Sender: TObject; AIndex: Integer;
  var ACanDelete: Boolean);
var
  myCanDelete : Boolean;
begin
  myCanDelete := false;
  TDialogService.PreferredMode := TDialogService.TPreferredMode.Platform;
  TDialogService.MessageDialog(txt_DeleteItem, System.UITypes.TMsgDlgType.mtConfirmation,
    [System.UITypes.TMsgDlgBtn.mbYes, System.UITypes.TMsgDlgBtn.mbNo],
    System.UITypes.TMsgDlgBtn.mbYes, 0,
    procedure(const AResult: TModalResult)
    var
      itemNo: integer;
      LI: TListViewItem;
    begin
      Case AResult of
          mrYes: begin
                   myCanDelete := true;
                   LI := MainDlg.LV.Items[AIndex];
                   itemNo := LI.Data['i'].AsInteger;
                   EntryList.Delete(itemNo);
                 end;
          mrNo: begin
                   myCanDelete := false;
                 end;
        End;
    end);
   ACanDelete := myCanDelete;
end;
Hier ist aber das Problem, dass die Meldung zwar erscheint, aber der Eintrag schon vorher gelöscht wird.
Auch TDialogServiceSync kann unter Android nicht verwendet werden.

Habt ihr eine Idee, wie man es abfangen könnte oder hat jemand schon einen Code? Ich denke mal, das wird ja einige betreffen, die Listviews verwenden...
  Mit Zitat antworten Zitat
Schokohase
(Gast)

n/a Beiträge
 
#2

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 14. Jun 2018, 16:21
Wenn du da noch eingreifen willst, dann würde ich das so umsetzen:
Delphi-Quellcode:
procedure TMainDlg.LVDeletingItem(Sender: TObject; AIndex: Integer;
  var ACanDelete: Boolean);
var
  lv: TListView;
begin
  // erstmal ablehnen
  ACanDelete := false;
  lv := TListView(Sender);

  TDialogService.PreferredMode := TDialogService.TPreferredMode.Platform;
  TDialogService.MessageDialog(txt_DeleteItem, System.UITypes.TMsgDlgType.mtConfirmation,
    [System.UITypes.TMsgDlgBtn.mbYes, System.UITypes.TMsgDlgBtn.mbNo],
    System.UITypes.TMsgDlgBtn.mbYes, 0,
    procedure(const AResult: TModalResult)
    var
      li: TListViewItem;
      itemNo: integer;
    begin
      Case AResult of
          mrYes: begin
                   li := lv.Items[AINdex];
                   itemNo := li.Data['i'].AsInteger;
                   EntryList.Delete(itemNo);
                   // und dann manuell löschen
                   lv.Items.Delete(AIndex);
                 end;
        End;
    end);
end;

Geändert von Schokohase (14. Jun 2018 um 17:00 Uhr)
  Mit Zitat antworten Zitat
amigage

Registriert seit: 11. Nov 2005
Ort: Leipzig
270 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 14. Jun 2018, 16:55
Besten Dank für den Hinweis.

Natürlich! Abfangen und selbst entfernen.
Es funktioniert, jedoch lautet Anweisung korrekterweise lv.Items.Delete(AIndex);

Jetzt muss ich es nur noch hinbekommen, dass dann der hässliche "Entfernen"-Button auch wieder verschwindet.

Die Frage bleibt dann aber trotzdem: wozu gibt es das Event OnDeletingItem, wenn man das nicht so einfach mit ACanDelete steuern kann?
  Mit Zitat antworten Zitat
Schokohase
(Gast)

n/a Beiträge
 
#4

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 14. Jun 2018, 16:59
wozu gibt es das Event OnDeletingItem, wenn man das nicht so einfach mit ACanDelete steuern kann?
Häh? Kann man doch steuern und nur weil man das kann, kann man das machen was ich dir gezeigt habe.

Du willst aber noch den Benutzer per Dialog fragen, ob er wirlich löschen will. Dialoge werden auf den mobilen Plattformen asynchron ausgeführt (darum musst du die Callback-Methode schreiben) und darum eben so.

Geändert von Schokohase (14. Jun 2018 um 17:02 Uhr)
  Mit Zitat antworten Zitat
amigage

Registriert seit: 11. Nov 2005
Ort: Leipzig
270 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 7. Jul 2018, 18:02
Super, das funktioniert soweit. In dem Event habe ich die Abfrage implementiert und die entsprechenden auszuführenden Funktionen hinterlegt.
Jetzt soll der Eintrag auch auf eine andere Art und Weise gelöscht werden (per Longtap wird ein Menü eingeblendet).
ich möchte es mir einfach machen und auf diese Funktionen gleich wieder zugreifen, ohne sie neu zu hinterlegen.

Also dachte ich mir, ich rufe das Event auf: myListViewDeletingItem(myListView, myListView.ItemIndex, false);

Der Compiler meldet aber "E2033 Die Typen der tatsächlichen und formalen Var-Parameter müssen übereinstimmen".
Die stimmen doch meiner Erachtens überein, oder übersehe ich da etwas?

procedure TmyForm.myListViewDeletingItem(Sender: TObject; AIndex: Integer;var ACanDelete: Boolean);

ich stehe gerade auf dem Schlauch und würde mich über eine Hilfe freuen. Danke!
  Mit Zitat antworten Zitat
Benutzerbild von KodeZwerg
KodeZwerg

Registriert seit: 1. Feb 2018
3.685 Beiträge
 
Delphi 11 Alexandria
 
#6

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 7. Jul 2018, 18:42
Das Boolean braucht ein Empfänger. Also myListViewDeletingItem(myListView, myListView.ItemIndex, EinBooleanDummy); .
*ungewiss* vielleicht kann man den Kompiler überreden es zu akzeptieren wenn man das Ergebnis nicht benötigt
:myListViewDeletingItem(myListView, myListView.ItemIndex, Boolean(False)); .

edit
Vielleicht willst Du das Boolean als Input verwenden dann schreibe es so
:procedure TmyForm.myListViewDeletingItem(Sender: TObject; AIndex: Integer; const ACanDelete: Boolean = False); .

Ps: Auf diese Weise bräuchtest Du gar kein Boolean angeben solange es eh auf False stehen soll.
Beispiel: myListViewDeletingItem(myListView, myListView.ItemIndex);
Gruß vom KodeZwerg

Geändert von KodeZwerg ( 7. Jul 2018 um 19:19 Uhr)
  Mit Zitat antworten Zitat
amigage

Registriert seit: 11. Nov 2005
Ort: Leipzig
270 Beiträge
 
Delphi 11 Alexandria
 
#7

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 8. Jul 2018, 08:54
Ich danke Dir für Deine erneute Hilfe

myListViewDeletingItem(myListView, myListView.ItemIndex, EinBooleanDummy) funktioniert.

Das Boolean(False) funktioniert nicht und die Struktur der procedure ist vorgegeben.
  Mit Zitat antworten Zitat
Benutzerbild von KodeZwerg
KodeZwerg

Registriert seit: 1. Feb 2018
3.685 Beiträge
 
Delphi 11 Alexandria
 
#8

AW: Android: Reagieren auf DeletingItem im Listview

  Alt 8. Jul 2018, 14:49
Es freut mich das es nun funktioniert, Hauptsache Du hast auch Verstanden wieso es so lauten muss.
Gruß vom KodeZwerg
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 17:45 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz