AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Bildverarbeitung unter FMX und dann FMLinux ....

Ein Thema von bernhard_LA · begonnen am 8. Jul 2018 · letzter Beitrag vom 22. Jul 2018
Antwort Antwort
bernhard_LA

Registriert seit: 8. Jun 2009
Ort: Bayern
801 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#1

Bildverarbeitung unter FMX und dann FMLinux ....

  Alt 8. Jul 2018, 22:27
wie muss ich diese Funktion überarbeiten, damit die unter FMX und dann später auch unter FMLinux funktioniert ?
Was wird aus Bit.ScanLine am besten?



Delphi-Quellcode:
procedure SingleChannelImage(
  Bit : TBitMap;
  c : integer );
  type
    PixArray = Array [ 1 .. 3 ] of Byte;
  var
    p : ^PixArray;
    h, w : integer;

  begin

    Bit.PixelFormat := pf24bit;

    For h := 0 to Bit.height - 1 do
      begin
        p := Bit.Scanline[ h ];
        For w := 0 to Bit.width - 1 do
          begin

            case c of
              1 :
                begin
                  { B-Channel }
                  p^[ 2 ] := 0;
                  p^[ 3 ] := 0;
                end;
              2 :
                begin
                  { G-Channel }
                  p^[ 1 ] := 0;
                  p^[ 3 ] := 0;
                end;
              3 :
                begin
                  { R-Channel }
                  p^[ 2 ] := 0;
                  p^[ 1 ] := 0;
                end;
              else

            end;

            inc( p );
          end;
      end;
  end;
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
1.805 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#2

AW: Bildverarbeitung unter FMX und dann FMLinux ....

  Alt 9. Jul 2018, 08:28
Schaue mal das hier mit den Beispielen an:
http://docwiki.embarcadero.com/Libra...cs.TBitmap.Map

Unter FMX laufen die Zugriffe auf dieser Ebene über die Map- und Unmap-Methoden und dem TBitmapData-Record.
  Mit Zitat antworten Zitat
bernhard_LA

Registriert seit: 8. Jun 2009
Ort: Bayern
801 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#3

AW: Bildverarbeitung unter FMX und dann FMLinux ....

  Alt 12. Jul 2018, 08:40
kann ich ein Full code sample bekommen, speziell was muss man beachten wenn man FXM dann auch unter Linux verwenden will
  Mit Zitat antworten Zitat
bernhard_LA

Registriert seit: 8. Jun 2009
Ort: Bayern
801 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#4

AW: Bildverarbeitung unter FMX und dann FMLinux ....

  Alt 22. Jul 2018, 08:35
mit hilfe div. weiterer Post jetzt endlich am Ziel


Delphi-Quellcode:
procedure TForm2.SingleChannelImage(
  Bit : TBitmap;
  c : integer );
  var
    bitdata1 : TBitmapData;
    i : integer;
    j : integer;
    Color : TAlphaColor;
  begin
    if ( Bit.Map( TMapAccess.maReadWrite, bitdata1 ) )
    then
      try
        for i := 0 to Bit.width - 1 do
          for j := 0 to Bit.height - 1 do
            begin
              begin
                Color := PixelToAlphaColor( @PAlphaColorArray( bitdata1.Data )
                  [ j * ( bitdata1.Pitch div PixelFormatBytes[ Bit.PixelFormat ]
                  ) + 1 * i ], Bit.PixelFormat );

                case c of
                  1 :
                    begin
                      TAlphaColorRec( Color ).B := 0;
                      TAlphaColorRec( Color ).G := 0;
                    end;
                  2 :
                    begin
                      TAlphaColorRec( Color ).R := 0;
                      TAlphaColorRec( Color ).G := 0;
                    end;

                  3 :
                    begin
                      TAlphaColorRec( Color ).B := 0;
                      TAlphaColorRec( Color ).R := 0;
                    end;

                end;

                AlphaColorToPixel( Color, @PAlphaColorArray( bitdata1.Data )
                  [ j * ( bitdata1.Pitch div PixelFormatBytes[ Bit.PixelFormat ]
                  ) + 1 * i ], Bit.PixelFormat );

              end;
            end;
      finally
        Bit.Unmap( bitdata1 );
      end;
  end;

Geändert von bernhard_LA (22. Jul 2018 um 08:38 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:29 Uhr.
Powered by vBulletin® Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2018 by Daniel R. Wolf