AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Array-Funktionen

Ein Thema von wendelin · begonnen am 18. Jun 2021 · letzter Beitrag vom 19. Jun 2021
Antwort Antwort
wendelin

Registriert seit: 29. Dez 2010
Ort: Nürnberg
121 Beiträge
 
Delphi 7 Enterprise
 
#1

Array-Funktionen

  Alt 18. Jun 2021, 18:53
Hallo,

ich habe eine Frage.
Ihr kennt sicherlich die funktion MinIntValue(dyn.Array) oder MaxIntValue(dyn.Array).
Nun suche ich das Gegenstück ? dazu.
d.h. mir ist die kleinste (oder größte) Integerzahl in einem dyn. Array bekannt, aber
ich möchte den Index dieser Zahl bestimmen.
Bisher habe ich keine derartige Funktion bei D7 gefunden.
Natürlich kann man das auch in einer Schleife ala:
for i := 0 to n do if Array[i] = bekannteZahl then Index := i; Wendelin
Wolfgang
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#2

AW: Array-Funktionen

  Alt 18. Jun 2021, 20:36
Gibt halt nichts Anders/Besseres, drum kam noch niemand auf die Idee sowas Einfaches in eine Funktion zu packen.
Aber für String-Arrays gäbe es eine/zwei Funktion(en) ... MatchText/IndexText, MatchStr/IndexStr bzw. Delphi-Referenz durchsuchenAnsiMatchText/Delphi-Referenz durchsuchenAnsiIndexText usw.

Delphi-Referenz durchsuchenTArray.BinarySearch gäbe es noch/inzwischen, aber das funktioniert ausschließlich mit sortierten Arrays.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu (18. Jun 2021 um 23:18 Uhr)
  Mit Zitat antworten Zitat
Amateurprofi

Registriert seit: 17. Nov 2005
Ort: Hamburg
1.039 Beiträge
 
Delphi XE2 Professional
 
#3

AW: Array-Funktionen

  Alt 19. Jun 2021, 02:01
Hallo,

ich habe eine Frage.
Ihr kennt sicherlich die funktion MinIntValue(dyn.Array) oder MaxIntValue(dyn.Array).
Nun suche ich das Gegenstück ? dazu.
d.h. mir ist die kleinste (oder größte) Integerzahl in einem dyn. Array bekannt, aber
ich möchte den Index dieser Zahl bestimmen.
Bisher habe ich keine derartige Funktion bei D7 gefunden.
Natürlich kann man das auch in einer Schleife ala:
for i := 0 to n do if Array[i] = bekannteZahl then Index := i; Wendelin
Ich kann mir auch vorstellen, dass das nicht implementiert ist, weil die Resultate nicht immer eindeutig sind.
Nehmen wir an, ein Array enthielte die Werte 3, 2, 2, 4
Dann ist 2 wohl der kleinste Wert im Array.
Aber was ist der Index der kleinsten Zahl?
Dein obiges Beispiel würde 2 liefern also den Index der letzten 2 im Array, ich würde bei solch einer Funktion erwarten, dass der Index der ersten 2 geliefert wird.
Gruß, Klaus
Die Titanic wurde von Profis gebaut,
die Arche Noah von einem Amateur.
... Und dieser Beitrag vom Amateurprofi....
  Mit Zitat antworten Zitat
wendelin

Registriert seit: 29. Dez 2010
Ort: Nürnberg
121 Beiträge
 
Delphi 7 Enterprise
 
#4

AW: Array-Funktionen

  Alt 19. Jun 2021, 09:47
Danke Delphi-Freunde,
in meinem spez. Fall gibt es eindeutig nur EINE Zahl(einen Index).

Wendelin
Wolfgang
  Mit Zitat antworten Zitat
Amateurprofi

Registriert seit: 17. Nov 2005
Ort: Hamburg
1.039 Beiträge
 
Delphi XE2 Professional
 
#5

AW: Array-Funktionen

  Alt 19. Jun 2021, 13:53
@Wendelin:

Ich hab mal ein kleines Set von Funktionen zusammengestellt die den Index von bestimmten Werten in einem Array zurückgeben.

Erstes Vorkommen eines Wertes
Delphi-Quellcode:
// Gibt den Index des ersten Vorkommens von Value ab Start zurück
FUNCTION IndexOfValue(const Data:Array of Integer; Value,Start:Integer):Integer; overload;
begin
   if Start<Length(Data) then
      for Result:=Max(0,Start) to High(Data) do
         if Data[Result]=Value then Exit;
   Result:=-1;
end;
Delphi-Quellcode:
// Gibt den Index des ersten Vorkommens von Value in Data zurück
FUNCTION IndexOfValue(const Data:Array of Integer; Value:Integer):Integer; overload;
begin
   Result:=IndexOfValue(Data,Value,0);
end;
Letztes Vorkommen eines Wertes
Delphi-Quellcode:
// Gibt den Index des letzten Vorkommens von Value in Data vor oder an Start zurück
FUNCTION LastIndexOfValue(const Data:Array of Integer; Value,Start:Integer):Integer; overload;
begin
   if Start>=0 then
      for Result:=Min(High(Data),Start) downto 0 do
         if Data[Result]=Value then Exit;
   Result:=-1;
end;
Delphi-Quellcode:
// Gibt den Index des letzten Vorkommens von Value in Data zurück
FUNCTION LastIndexOfValue(const Data:Array of Integer; Value:Integer):Integer; overload;
begin
   Result:=LastIndexOfValue(Data,Value,High(Data));
end;
Erstes Vorkommen des kleinsten Wertes
Delphi-Quellcode:
// Gibt den Index des kleinsten Wertes in Data ab Start zurück
FUNCTION IndexOfMinValue(const Data:array of Integer; Start:Integer):Integer; overload;
begin
   Result:=IndexOfValue(Data,MinIntValue(Data),Start);
end;
Delphi-Quellcode:
// Gibt den Index des ersten Vorkommens des kleinsten Wertes in Data zurück
FUNCTION IndexOfMinValue(const Data:array of Integer):Integer; overload;
begin
   Result:=IndexOfMinValue(Data,0);
end;
Letztes Vorkommen des kleinsten Wertes
Delphi-Quellcode:
// Gibt den Index des letzten Vorkommens des kleinsten Wertes in Data an oder vor Start zurück
FUNCTION LastIndexOfMinValue(const Data:array of Integer; Start:Integer):Integer; overload;
begin
   Result:=LastIndexOfValue(Data,MinIntValue(Data),Start);
end;
Delphi-Quellcode:
// Gibt den Index des letzten Vorkommens des kleinsten Wertes in Data zurück
FUNCTION LastIndexOfMinValue(const Data:array of Integer):Integer; overload;
begin
   Result:=LastIndexOfMinValue(Data,High(Data));
end;
Erstes Vorkommen des größten Wertes
Delphi-Quellcode:
// Gibt den Index des größten Wertes in Data ab Start zurück
FUNCTION IndexOfMaxValue(const Data:array of Integer; Start:Integer):Integer; overload;
begin
   Result:=IndexOfValue(Data,MaxIntValue(Data),Start);
end;
Delphi-Quellcode:
// Gibt den Index des ersten Vorkommens des größten Wertes in Data zurück
FUNCTION IndexOfMaxValue(const Data:array of Integer):Integer; overload;
begin
   Result:=IndexOfMaxValue(Data,0);
end;
Letztes Vorkommen des größten Wertes
Delphi-Quellcode:
// Gibt den Index des letzten Vorkommens des größten Wertes in Data an oder vor Start zurück
FUNCTION LastIndexOfMaxValue(const Data:array of Integer; Start:Integer):Integer; overload;
begin
   Result:=LastIndexOfValue(Data,MaxIntValue(Data),Start);
end;
Delphi-Quellcode:
// Gibt den Index des letzten Vorkommens des größten Wertes in Data zurück
FUNCTION LastIndexOfMaxValue(const Data:array of Integer):Integer; overload;
begin
   Result:=LastIndexOfMaxValue(Data,High(Data));
end;
Hiermit kurz getestet
Delphi-Quellcode:
PROCEDURE TMain.Test;
FUNCTION TestFuncs(const Data:array of Integer):String;
var I:Integer;
begin
   Result:='Data = [';
   for I:=0 to High(Data) do
      Result:=Result+IntToStr(Data[I])+', ';
   Result[Length(Result)-1]:=']';
   Result[Length(Result)-1]:=#13;
   Result:=Result+
           IntToStr(IndexOfValue(Data,5,5))+' IndexOfValue(Data,5,5)'+#13+
           IntToStr(IndexOfValue(Data,5))+' IndexOfValue(Data,5)'+#13+
           IntToStr(LastIndexOfValue(Data,5,5))+' LastIndexOfValue(Data,5,5)'+#13+
           IntToStr(LastIndexOfValue(Data,5))+' LastIndexOfValue(Data,5)'+#13+
           IntToStr(IndexOfMinValue(Data,5))+' IndexOfMinValue(Data,5)'+#13+
           IntToStr(IndexOfMinValue(Data))+' IndexOfMinValue(Data)'+#13+
           IntToStr(LastIndexOfMinValue(Data,5))+' LastIndexOfMinValue(Data,5)'+#13+
           IntToStr(LastIndexOfMinValue(Data))+' LastIndexOfMinValue(Data)'+#13+
           IntToStr(IndexOfMaxValue(Data,5))+' IndexOfMaxValue(Data,5)'+#13+
           IntToStr(IndexOfMaxValue(Data))+' IndexOfMaxValue(Data)'+#13+
           IntToStr(LastIndexOfMaxValue(Data,5))+' LastIndexOfMaxValue(Data,5)'+#13+
           IntToStr(LastIndexOfMaxValue(Data))+' LastIndexOfMaxValue(Data)';
end;
begin
   ShowMessage(TestFuncs([4,6,5,3,6,7,8,5,2,3,5,1]));
end;
Gruß, Klaus
Die Titanic wurde von Profis gebaut,
die Arche Noah von einem Amateur.
... Und dieser Beitrag vom Amateurprofi....
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 06:20 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz