DLL mit Form

[Capa]

siehe oben das mit hide hat ich schonmal da wurde mein programm immer unsanft
per Taskmanager von mir geschlossen.
ich versuch mal etwas was mir gerade im kopf rumschwirrt.
und danke für den hinweis :/ wow lenkt mich wohl doch zu sehr ab ;)


Edit: Also bisher funzt es wie folgt, wenn ich die form starte dann zeigt er sie ohne fehler an
kann auch drauf zugreifen und die Form schliessen und wieder öffnen allerdings hab ich immernoch nen problem mit dem programmende quasi immernoch per taskmanager.

Delphi-Quellcode:

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caHide;
  FreeAndNil(Form2);
end;

[blauweiss]

im FormClose darfst Du nicht die Instanz selber zerstören

Delphi-Quellcode:

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caHide;
//  FreeAndNil(Form2);   <- hätte eigentlich hier schon krachen können
end;

dazu scheint es etwas hart, am Programmende eine ggfs. offene Form (noch dazu die in der DLL) einfach freizugeben, statt sie zu schließen.
Ich würde im Hauptprogramm dieses machen:

Delphi-Quellcode:

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := False;
  try
    HideForm2; // <-   anstatt FreeForm2
  finally
    CanClose := True;
  end;
end;

und auf den Garbage collector vertrauen.

Das setzt natürlich voraus, daß HideForm2 robust programmiert wird, z.B.

Delphi-Quellcode:

procedure HideForm2; stdcall;
begin
  if Assigned(Form2) then // <- hat bei Dir gefehlt
    Form2.Hide();
end;

Gruß,
blauweiss

[Capa]

mhh anderer Code selbes ergebnis kann die exe immernoch nur per taskmanager killen
bzw über die stop funktion in delphi.

Hier nochma der aktuelle Code nicht das sich doch noch nen anderer Fehler eingeschlichen hat den ich nicht
gesehen hab aber bei dem wenigen Code glaub ich das eher weniger.

DLL-File

Delphi-Quellcode:

library DLL1;

uses
  Sharemem,
  SysUtils,
  Classes,
  Forms,
  windows,
  DLLUnit1 in 'DLLUnit1.pas' {Form2};

{$R *.res}

procedure CreateForm(appHandle: THandle); stdcall;
begin
  if appHandle = 0 then apphandle := GetActiveWindow;
  Application.Handle := appHandle;
  try
    if Form2=nil then
      Form2 := TForm2.Create(Application);
    Form2.Show();
  except
    On E: Exception Do Application.HandleException(E);
  end;
  Application.Handle := 0;
end;

procedure HideForm; stdcall;
begin
  if Assigned(Form2) then
  begin
    Form2.Hide();
//    FreeAndNil(Form2);
  end;
end;

procedure Test(text1,text2,text3: string); stdcall;
begin
  Form2.Listbox1.Items.Add(text1);
  Form2.Listbox1.Items.Add(text2);
  Form2.Listbox1.Items.Add(text3);
end;

exports CreateForm,
          HideForm,
              Test;

begin
end.

DLL-Unit

Delphi-Quellcode:

unit DLLUnit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm2 = class(TForm)
    ListBox1: TListBox;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caHide;
end;

end.

Exe-Unit

Delphi-Quellcode:

unit Unit1;

interface

uses
  Sharemem, Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls,
  Forms, Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

procedure CreateForm2(appHandle: THandle); stdcall; external 'DLL1.dll' name 'CreateForm';
procedure HideForm2; stdcall; external 'DLL1.dll' name 'HideForm';
procedure Test(text1,text2,text3: string); stdcall; external 'DLL1.dll' name 'Test';


{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  CreateForm2(Application.Handle);
  Test('Need Help','Capa','DLL Form');
end;

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := False;
  try
    HideForm2;
  finally
    CanClose := True;
  end;
end;

end.

P.S.: Selbst wenn ich die Exe nur starte und dann wieder beende hab ich das problem
also auch wenn ich die Form2 nicht initialisiere.

[chaosben]

Mal ein bißchen OT: Das Auslagern kann man sich imho sparen, weil es mehr Ärger als Nutzen bringt. Letztendlich muss sowieso alles geladen werden. Wenn das dann aus verschiedenen Modulen geschieht ist es imho langsamer als aus einem Modul.
Also: Eine ordentliche Struktur in der Hauptanwendung und DLL's/BPL's nur wenns unbedingt nötig ist.

Und nun zurück zum Thema. :)

[shmia]

Zitat:

Zitat von chaosben (Beitrag 1085208)

Das Auslagern kann man sich imho sparen, weil es mehr Ärger als Nutzen bringt

Dem würde ich voll zustimmen und finde es auch nicht Offtopic.
Wenn man seine Anwendung in kleinere Teile (DLLs, BPLs) zerlegen möchte, kommt es drauf an, wie man die Schnitte legt.
Man kann "vertikal" oder "horizontal" schneiden.
Ein vertikaler Schnitt wäre z.B. wenn man Formulare in DLLs auslagert.
Ich nenne es "vertikal" weil von ganz oben (Benutzeroberfläche) durch die Mitte (Programmlogik) bis ganz unten (Datenbankzugriff, Low-Level-Funktionen) schneidet und an dieser Linie die Anwendung und die DLL auseinander reisst.

Bei einem horizontalen Schnitt würde man nur ganz bestimmte Features in eine DLL verpacken.
Das könnte z.B. eine Bibliothek zum Lösen von Gleichungssystemen sein oder zum Versenden von EMails über SMTP.
Auf jeden Fall enthält die DLL nur Code auf einer Abstraktionsebene (also NICHT User-Interface, Bussinesslogik und Datenzugriff zusammen).
Diese DLL greift nicht selbst auf Ini-Datei, Datenbanken oder ähnliches zu, sondern bekommt Alles von "Aussen", also von der Anwendung, übergeben.

Hier ein Bild, wie sich Microsft den Aufbau einer Anwendung vorstellt:
http://www.codeproject.com/KB/cs/Ins...chitecture.png
Man darf nicht senkrecht schneiden und dann den abgeschnittenen Teil in eine DLL auslagern!

[Capa]

das bild funzt nicht
ich denke mal du meinst http://www.codeproject.com/KB/cs/Ins...chitecture.png

[NickelM]

Jetzt mal ne Frage bzw. Vorschlag. Da du in der Dll sowieso die Forms eingebunden hast warum machst du das dan nicht so?

Delphi-Quellcode:

procedure CreateForm(app: TApplication); stdcall;
begin
  if app.Handle = 0 then app.handle := GetActiveWindow;
 try
   if Form2=nil then
   app.CreateForm(TForm2, Form2);
   Form2.Show();
  except
    On E: Exception Do app.HandleException(E);
  end;
end;

//Aufruf so:
CreateForm2(Application);

Dadurch bindest du die Form direkt in die Anwendung ein. Wenn du jetzt die Anwendung schliest müsste theoretisch (habs jetzt nicht getest, ist jetzt so ein Gedanke) die Application selbst das Form killen. Weil da du die Unit Forms in die DLL eingebunden hast, hat die dll einen eigene Application Klasse. Du übergibst den Handle bzw. änderst ihn, aber die Klasse hat nicht die gleichen Eigenschaften wie die andere.
In meinem Fall übergibst du die Adresse auf die Application, die du in der Anwendung hast, mit allen Eigenschaften. die Funktion CreateForm wird auch in der Anwendung intern beim erstellen eingesetzt.

P.S. Falls ich falsch liege lass ich mich auch gerne belehren, was WinAPI angeht, weil wirklich viel zutun hab ich damit nicht :-D

[blauweiss]

Hallo Capa,

Nochmals der Tip: Du mußt für Deinen Fall ShareMem als erste Unit in der USES-Klausel im EXE-Project verwenden. Schau Dir am Besten mal die Hilfe dazu an.

Gruß,
blauweiss

[Capa]

Zitat:

Zitat von blauweiss (Beitrag 1085265)

Hallo Capa,

Nochmals der Tip: Du mußt für Deinen Fall ShareMem als erste Unit in der USES-Klausel im EXE-Project verwenden. Schau Dir am Besten mal die Hilfe dazu an.

Gruß,
blauweiss

*hust* sorry hast recht habs in der unit eingebunden nicht in der Projectuses
und wie ich gerade feststelle wars sogar der grund warum der sich nicht richtig beendet hat.

Diese Aufgabe ist Quasi vorerst gelöst.

Danke an alle beteiligten für die Lösungsvorschläge.


Mfg Capa

[Capa]

irgendwie will das bei mir nie so funktionieren wie ich das will.
Hab das nun so gemacht das ich nur bestimmte Sachen exportiere in dem Fall nun
die MySQL Sachen.

Delphi-Quellcode:

library DLL2;

uses
  Sharemem, umysqlvio, uMysqlCT, uMysqlClient, uMysqlHelpers,
  SysUtils, Classes;

  {$I mysqlinc.inc}

type
  TMySqlLoginData = Record
    mysqladresse: ansistring;
    mysqldatenbank: ansistring;
    mysqlusername: ansistring;
    mysqlpasswort: ansistring;
    mysqlport: integer;
  End;

var  XMySQL: TMysqlClient;
    XResult: TMysqlResult;

{$R *.res}

function SendMysqlData(mydata: TMySqlLoginData): Boolean;
begin
  XMySQL := TMysqlClient.create;
  XMysql.Host := mydata.mysqladresse;
  XMysql.Db := mydata.mysqldatenbank;
  XMysql.user := mydata.mysqlusername;
  XMysql.password := mydata.mysqlpasswort;
  XMysql.port := mydata.mysqlport;
  XMysql.UnixSocket := '';
  XMysql.UseNamedPipe := false;
  XMysql.UseSSL := false;
  XMysql.Compress := false;
  XMysql.TrySockets := false;
  if (XMysql.Connect) then
    Result := True
  else
    Result := False;
end;

exports  SendMysqlData;

begin
end.

Aber selbst diese kleine Funktion macht mir Probleme mit ner Zugriffsverletzung.
Vom Aufbau her sollte doch da kein Problem liegen bin ich der Meinung.
Hab das bei Type definierte vorher schon mit string und shortstring versucht kam das selbe ergebnis.

Auch der Versuch die beiden Variablen in der Function zu deklarieren half nicht.

Mfg Capa