Strg+V im TEdit abfangen

[freak1985]

Okay dann muss ich es wohl doch über EN_UPDATE machen. Aber kann mir dsa nocheinmal jemand anders erklären. Hab das da oben nicht so verstanden!?


Danke


MfG

[Sprint]

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    OldWndProcEdit1: TWndMethod;
    procedure WndProcEdit1(var Message: TMessage);
  end;

Delphi-Quellcode:

uses
  Clipbrd;

Delphi-Quellcode:

{--------------------------------------------------------------------------------------------------}

procedure TForm1.WndProcEdit1(var Message: TMessage);
const
  S_MSG = 'Soll der Text "%s" in Edit1 eingefügt werden?';
begin
  if Message.Msg = WM_PASTE then
    if MessageDlg(Format(S_MSG, [Clipboard.AsText]), mtConfirmation, [mbYes, mbNo], 0) = mrNo then
      Exit;
  OldWndProcEdit1(Message);
end;

{--------------------------------------------------------------------------------------------------}

procedure TForm1.FormCreate(Sender: TObject);
begin
  OldWndProcEdit1 := Edit1.WindowProc;
  Edit1.WindowProc := WndProcEdit1;
end;

{--------------------------------------------------------------------------------------------------}

[Olli]

Gibt es denn beim TEdit keinen Eventhandler für WM_PASTE? ... der wäre doch exakt was gesucht wurde :gruebel: ... OnPaste oder so?

Danke Sprint, du sprichst mir aus der Seele. Einen Handler scheint es also nicht zu geben? Naja, dann halt die Fensterfunktion überschreiben ;)

[freak1985]

Danke :) Werde ich mal testen

EDIT @ Sprint:

Danke :) So habe ich mir das vorgestellt. Funzt einwandfrei :)