Wozu TNotifyEvent oder TEvent?

[Union]

Wenn Du auch einen Integer und nicht nur ein Objekt übergen möchtest, musst Du zuerst einen eigenen Eventtyp definieren, z.b.:

Delphi-Quellcode:

TDdtProgressStatus = (TPSStart, TPSProgress, TPSEnd);
TDdtProgressEvent = procedure(Sender : TObject; Status: TDdtProgressStatus; Value : integer) of object;

Dann in einem Objekt definieren:

Delphi-Quellcode:

property OnFileProgress : TDdtProgressEvent read FOnFileProgress write FOnFileProgress;

Und dann kannst Du es aufrufen:

Delphi-Quellcode:

   if Assigned(FOnFileProgress) then
      FOnFileProgress(Self, TPSStart, nLines);
   ...
   if Assigned(FOnFileProgress) then
      FOnFileProgress(Self, TPSProgress, 1);
   ...
   if Assigned(FOnFileProgress) then
      FOnFileProgress(Self, TPSEnd, nLines);

Wenn Du die Klasse dann benutzt, definierst Du eine entsprechende Prozedur:

Delphi-Quellcode:

procedure TfrmMain.FileProgressEvent(Sender: TObject;
  Status: TDdtProgressStatus; Value: integer);
begin
   case Status of
   TPSStart :
      begin
         // Meter-Anzeige aufbauen
         frmWarten.Show;
         frmWarten.btn.visible := false;
         frmWarten.pgb.min := 0;
         frmWarten.pgb.max := Value;
      end;
   TPSProgress :
      begin
         frmWarten.pgb.StepBy(Value);
      end;
   TPSEnd :
      begin
         frmWarten.pgb.Position := Value;
         frmWarten.btn.caption  := 'Fertig';
         frmWarten.btn.visible  := true;
         frmWarten.btn.setfocus;
      end;
   end;
end;

... und weist diese dem Event zu:

Delphi-Quellcode:

FileObject.OnFileProgress  := FileProgressEvent;

[Arnulf]

Danke für die Antworten.
Ich werde mich einfach mal hinsetzen und das mit einem tnotifyevent programmieren.
Gedacht war es schon so, daß man jegliche progress bars verwenden kann oder eben auch eine eigene und nicht unbedingt auf die originale von delphi angewiesen ist.

Die verwendung von tnotifyevent:

Zitat:

private
FOnProgressBarPosChange: TNotifyEvent;

procedure TMyVideoObject.doProgressBarPosChange;
begin
if Assigned(FOnProgressBarPosChange) then
FOnProgressBarPosChange(Self);
end;

hab ich zwar schon gesehen, aber den sinn hab ich einfach nicht verstanden.
was bringt dieses event?
es geht hier ja nur darum, daß der benutzer dieser klasse einem event eine prozedur zuweisen kann und die hald auch nicht benutzen muß wenn er nicht will.
Mehr macht das nicht - seh ich das jetzt richtig?

Arnulf

[dataspider]

Hi Arnulf,
das ist schon richtig. Das wichtigste ist aber, dass du über eine Zustandsänderung der Komponente zum richtigen Zeitpunkt informiert wirst (onBeforeConnect, onAfterConnect... oder onChange von TEdit).
Damit wird deine Methode von der Komponente eben ganau dann aufgerufen, wenn es notwendig ist.
Wäre es kein Event, müsstest du über einen Timer den Zustand kontinuierlich abfragen und merken, um zu wissen, ob sich etwas geändert hat.
Sehr oft kann man an solchen Stellen noch eingreifen (onCloseQuery des Forms).
Gruß, Frank