Procedure schreiben die bei Objekten Eigenschften setzt!

[Christian18]

Hi,

ist es nicht möglich wie ich es vor habe??? Was ich tun möchte ist im vorherrigen Beitrag!

MFG Christian18

[Sascha L]

Ich kann dir grade leider nicht einen Code zeigen, da das Update2 für Delphi06 gerade mein Delphi ruiniert :D

Du kannst doch aber z.B. folgendes machen:

Delphi-Quellcode:

(o as TLabel).Font.Styles

Wenn du unbedingt mit 1,2... für die einzelnen Styles arbeiten willst, würde ich ne Case-Anweisung verwenden. Ansonsten übergibt der Prozedure doch gleich die FontStyles. So ist es auch möglich dass du z.B. fsBold und fsItalic mit einem Aufruf einstellen kannst.

[r2c2]

Doch TControl hat ne Font-property(grad nochmal nachgeguckt).

Ergo:

Delphi-Quellcode:

procedure TProgramm.Objekt(o : TControl; w, h, l, t : Integer; AFontStyle: TFontStyle); 
begin 
  if w <> 0 then o.Width:=w; 
  if h <> 0 then o.Height:=h; 
  if l <> 0 then o.Left:=l; 
  if t <> 0 then o.Top:=t; 
  o.FontStyle := AFontStyle;
end;

mfg

Christian

[Christian18]

Hallo,

wenn ich bei mir o.FontStyle eingebe, dann kommt eine Fehlermeldung

Undefinierter Bezeichner 'FontStyle'

Ich habe kein FontStyle?!?!?

muss ich noch eine uses dazufügen??? ich habe Grphics hinzugefügt, da TFontStyle da drinn ist. was kann ich gegen den Fehler tun???

[Hawkeye219]

FontStyle ist keine Eigenschaft von TControl, es muß Font.Style heißen. Die Font-Eigenschaft ist aber in Deiner Routine nicht erreichbar, da sie als protected deklariert ist. Man könnte hier zwar einen "ClassCracker" einsetzen, aber das würde den Rahmen wohl sprengen. Abgesehen davon ist Font.Styles eine Menge, übergeben wird aber ein Mengenelement. Eine direkte Zuweisung wird also in keinem Fall funktionieren.

Gruß Hawkeye

[Sascha L]

Delphi-Quellcode:

procedure TForm1.ChangeObject(o : TControl; w, h, l, t : Integer; AFontStyle: TFontStyles);
begin
  if w > -1 then o.Width:=w;
  if h > -1 then o.Height:=h;
  if l > -1 then o.Left:=l;
  if t > -1 then o.Top:=t;
  (o as TLabel).Font.Style := AFontStyle;
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  ChangeObject(Label1,100,50,-1,-1,[fsBold,fsItalic]);
end;

Oder:

Delphi-Quellcode:

procedure TForm1.ChangeObject(o : TControl; w, h, l, t : Integer; AFontStyle: TFontStyles);
begin
  with o do begin
    Width:=w;
    Height:=h;
    Left:=l;
    Top:=t;
  end;
  (o as TLabel).Font.Style := AFontStyle;
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  ChangeObject(Label1,100,50,Label1.Left,Label1.Top,[fsBold,fsItalic]);
end;

[dataspider]

Hi,

am sichersten sollte es über RTTI gehen:

Delphi-Quellcode:

Uses
  TypInfo
...
procedure SetControlParams(AControl: TControl; AFontStyle: TFontStyles; w:
    Integer = -1; h: Integer = -1; l: Integer = -1; t: Integer = -1);
Var
  AFont: TFont;
begin
  if w > -1 then AControl.Width:=w;
  if h > -1 then AControl.Height:=h;
  if l > -1 then AControl.Left:=l;
  if t > -1 then AControl.Top:=t;
  if IsPublishedProp(AControl, 'Font') then
  begin
    AFont := TFont(GetObjectProp(AControl, 'Font'));
    AFont.Style := AFontStyle;
  end;
end;