formatierter progress string

[stephan007]

irgendwie doch, weil ich das was hinten steht, für die einheit brauche (also für den progress string).

also muss ich aus 1 MB (oder 1MB) den int 1 rausziehen und MB als string speichern, dass ich

xxx MB / yyy MB machen kann.
also ich brauch beide infos. deshalb auch meine anmerkung, dass ich parsen muss.
also alles nehmen, was kein buchstabe ist (ist eine zahl) und dann den rest als einheit (also position x bis ende).

[Hawkeye219]

Hallo Stephan,

du kannst das Parsen auch an Val delegieren. Für ganzzahlige Werte sieht das dann so aus:

Delphi-Quellcode:

function Split (s: string;  var aValue: Integer;  var aTail: string): Boolean;  overload;
var
  ErrPos : Integer;
begin
  Val (s, aValue, ErrPos);
  if (ErrPos > 0) then
    aTail := TrimLeft(Copy(s, ErrPos, MaxInt))
  else
    aTail := '';
  Result := (aTail <> '');
end;

Bei Realwerten wird es etwas aufwendiger. Die Val-Prozedur verarbeitet nur Dezimalpunkte und hat zudem einen Implementierungsfehler: falls hinter der Zahl weitere Zeichen stehen, wird der Dezimaltrenner nicht berücksichtigt.

Delphi-Quellcode:

function Split (s: string;  var aValue: Double;  var aTail: string): Boolean;  overload;
var
  ErrPos : Integer;
begin
  Val (s, aValue, ErrPos);
  aTail := '';
  if (ErrPos > 0) then
    begin
      if (ErrPos = Pos(DecimalSeparator, s)) then
        s[ErrPos] := '.';
      Val (s, aValue, ErrPos);
      if (ErrPos > 0) then
        begin
          aTail := TrimLeft(Copy(s, ErrPos, MaxInt));
          Val (Copy(s, 1, ErrPos - 1), aValue, ErrPos);
        end;
    end;
  Result := (aTail <> '');
end;

Die Anwendung:

Delphi-Quellcode:

var
  s : string;
  IntValue : Integer;
  RealValue : Double;
  Dimension : string;
begin
  s := '123 MB';
  Split(s, IntValue, Dimension);
  ShowMessage (Format('Value=%d'#13'Dimension="%s"', [IntValue, Dimension]));

  s := '1,44 MB';
  Split(s, RealValue, Dimension);
  ShowMessage (Format('Value=%g'#13'Dimension="%s"', [RealValue, Dimension]));
end;

Gruß Hawkeye

[stephan007]

habe ich dann da sowohl 123 und MB wie in deinem beispiel oder nur die zahl?

denn ich muss mir wie gesagt in einem integer die zahl merken und in einem string die einheit.
aber ich werde deine lösung mal ausprobieren, dann sehe ich es eh auch. danke jedenfalls :???:

[stephan007]

ja macht es, super, genau das was ich gesucht habe und geht sogar ohne parsen, wie schön. :lol: