Google Maps über COM (Component Object Model)

[swaters]

Just had time to try your explanation out.

Works wonderfully.

Thank-you again Thom.

Really enjoying my dabbling now. A lot less frustration. Thanks again.

[HJay]

Wenn ich mit dem folgenden Code ein Overlay-Rechteck erzeuge, dann hat dieses Rechtecke ein weißes Karomuster drübergelegt (feine weiße Linien senkrecht und waagerecht im Abstand von 5 cm oder so), das optisch immer gleich breit ist, egal welche Zoomstufe man wählt. Ist das ein Bug von GoogleMaps oder mache ich noch was falsch mit den Parametern?

Code:

procedure TGoogleMap.CreateTile;
  var Rectangle : TRectangle;
      RectOptions: TRectangleOptions;
begin
  with Script(WebBrowser) do begin
    Rectangle := New(Google.Maps.Rectangle);

    RectOptions:=TRectangleOptions.Create;
    with RectOptions do begin
      StrokeColor   := clBlack;
      StrokeOpacity := 0.8;
      StrokeWeight  := 1;
      FillColor     := clRed;
      FillOpacity   := 0.35;
      Map           := Maps[0];
      Bounds        := Maps[0].GetBounds;
    end;

    Rectangle.SetOptions(RectOptions);
  end;
end;

Noch eine Ergänzungsfrage: Sollte ich RectOptions mit Free wieder freigeben oder ist das egal?

[Thom]

Hi swaters,

:thumb:

Hallo HJay,

das liegt am API/dem IE. Die Karte besteht aus Kacheln der Größe 256x256 Pixel (sollte etwa dem 5x5 cm Raster auf Deinem Bildschirm entsprechen). Diese Bilder werden in DIV-Containern abgelegt. Unter Umständen gibt es dabei den von Dir erwähnten Pixelfehler. Dieser tritt aber in der Regel nur bei älteren IE-Versionen auf. Hast Du Dein Programm in der Registry "freigeschaltet"?

Das Optionsobjekt kannst Du freigeben - mußt Du aber nicht. Momentan kommt es einfach nur darauf an, wie oft Du ein neues Rechteck erstellst: Bei 10 Stück spielt der Speicherverbrauch kaum eine Rolle, bei 10000 aber schon. In diesem Fall solltest Du nicht mehr benötigte Objekte in Deinem Programmcode freigeben.

[HJay]

Ich habe das Konzept mit den New()-Befehlen noch nicht ganz verstanden. Häufen sich dadurch nicht jede Menge Objekte an, die man eigentlich freigeben müsste?

Ich kann ein Rectangle wieder entfernen, indem ich seine Eigenschaft Map auf nil setze. Dann kann ich es aber erneut sichtbar machen, indem ich wieder eine Map zuweise. Wie aber lösche ich ein Rectangle endgültig und gebe die Ressourcen frei?

In der folgenden Routine erzeuge ich nur zum Ausprobieren nach dem Event drag_end kleine Rechtecke in den Ecken des neuen sichtbaren Bereichs. Muss ich mich um die mit New() erzeugten Objekte noch irgendwie kümmern? Belasten die TLatLng und TLatLngBounds nach Ende der Routine weiterhin die Ressourcen?

Und umgekehrt, kann ich mir das von function CreateTile: TRectangle zurückgegebene Rechteck in einer TObjectList merken und später weiter verwenden, z.B. um Farbe oder Bounds anzupassen?

Darf ich die Objekte mit Rectangle.Free freigeben und fertig? Wenn ich das TLatLngBounds-Object nur temporär benötige, dann müsste ich also eher ALatLngBounds := New(...) zuweisen und dann CreateTile(ALatLngBounds) aufrufen und dann ALatLngBounds.Free aufrufen, um sauber zu bleiben?

Der Aufruf RectOptions.Bounds := ABounds kopiert die Werte, oder? Dafür muss es das ursprünglich mit New erzeugte und der Funktion übergebene TLatLngBounds-Object nicht dauerhaft geben, oder?

Ich werde nämlich relativ viele Rechtecke und Punkte berechnen müssen und möchte schon von vornhereins auber bleiben.

Ich werde noch nicht schlau daraus, was jetzt klassische Objekte sind und was Variablen.

Code:

function TGoogleMap.CreateTile(ABounds: TLatLngBounds): TRectangle;
  var Rectangle : TRectangle;
      RectOptions: TRectangleOptions;
begin
  with Script(WebBrowser) do begin
    Rectangle := New(Google.Maps.Rectangle);

    RectOptions := TRectangleOptions.Create;
    with RectOptions do begin
      StrokeColor   := clBlack;
      StrokeOpacity := 0.8;
      StrokeWeight  := 1;
      Clickable     := False;
      FillColor     := clRed;
      FillOpacity   := Random;
      Map           := Maps[0];
      Bounds        := ABounds;
    end;

    Rectangle.SetOptions(RectOptions);
    Result := Rectangle;
  end;
end;

procedure TGoogleMap.MapDragEnd(Sender: TObject);
  var ALatLng : TLatLng;
      BLatLng : TLatLng;
begin
  with Script(WebBrowser) do begin
    ALatLng := Maps[0].Bounds.GetSouthWest;
    BLatLng := New(Google.Maps.LatLng(ALatLng.Lat + 0.003, ALatLng.Lng + 0.003));
    CreateTile(New(Google.Maps.LatLngBounds(ALatLng, BLatLng)));

    BLatLng := Maps[0].Bounds.GetNorthEast;
    ALatLng := New(Google.Maps.LatLng(BLatLng.Lat - 0.003, BLatLng.Lng - 0.003));
    CreateTile(New(Google.Maps.LatLngBounds(ALatLng, BLatLng)));
  end;
end;

[HJay]

Zitat:

Zitat von Thom (Beitrag 1196282)

Unter Umständen gibt es dabei den von Dir erwähnten Pixelfehler. Dieser tritt aber in der Regel nur bei älteren IE-Versionen auf. Hast Du Dein Programm in der Registry "freigeschaltet"?

Ich habe Windows 7 mit IE9 und das Programm ist in der Registry freigeschaltet. Na ja, schade, aber nicht so schlimm.

Google gibt etliche Treffer in bezug auf DOCTYPE-Deklarationen, die nötig sind. Das wird doch aber sicherlich von Dir schon gemacht, oder?

[Thom]

Jaaaaa, die Speicherverwaltung. Das ist ein abendfüllendes Thema. :)

Prinzipiell arbeiten alle Objekte des Frameworks als "Wrapper" oder "Adapter" für bestehende oder neu zu erstellende JavaScript-Objekte. (siehe Grafik). Die JavaScript-Objekte werden über ihre COM-Interfaces angesprochen, die vom Delphi-Wrapper-Objekt gespeichert werden. Solange das Delphi-Objekt also noch existiert, wird auch nicht die Interface-Referenz auf das JavaScript-Objekt freigegeben (Referenz-Zählung) und damit kann auch die JavaScript-Engine des Internet Explorers das (JavaScript-)Objekt nicht freigeben.

Damit möglichst wenig/nichts verloren geht, werden alle vom Framework erstellten Wrapper-Objekte zentral verwaltet und spätestens beim Beenden des Programmes freigegeben.
Unterscheiden muß man dabei die eigentlichen Karten-(Wrapper-)Objekte wie TMap, TRectangle, TMarker usw. und die "Hilfs"-Objekte wie zum Beispiel TMapOptions oder TRectangleOptions. Die Karten-Objekte werden beim Aufruf der entsprechenden Methoden erstellt (Google.Maps.Map, Google.Maps.Rectangle usw.) und anschließend vom Script-Objekt verwaltet (Script.Maps[...], Script.Rectangles[...] usw.).

In JavaScript werden neue Objekte mit der Anweisung "new" erstellt:

Code:

var latLng = new google.maps.latLng(10,20);
[...]

Damit ist auch ersichtlich, daß hier ein neues Objekt angelegt wird. Delphi bietet so etwas nicht, so daß das neue Objekt einfach mit

Delphi-Quellcode:

var LatLng: TLatLng;
  [...]
  LatLng:=Google.Maps.LatLng(10,20);
  [...]

erstellt wird. Viele (Delphi-)Programmierer halten das aber für eine unsaubere Programmierung: Es wird aufgrund des Syntax nicht deutlich, daß an dieser Stelle ein neues Objekt entsteht, wem es "gehört" und wer für dessen Freigabe zuständig ist. Deshalb wurde in der Version 2 des Frameworks die New-Funktion eingeführt, die vom programmtechnischen Standpunkt eigentlich vollkommen überflüssig ist:

Delphi-Quellcode:

function New(Value: Txxx): Txxx;
begin
  Result:=Value;
end;

Sie kann also ohne Probleme weggelassen werden und dient lediglich der besseren Lesbarkeit des Quelltextes:

Delphi-Quellcode:

  Map:=Google.Maps.Map;
  //hat die selbe Funktion wie
  Map:=New(Google.Maps.Map);

Das wird sich in der Version 3 des Frameworks radikal ändern: Die Maps-Methoden liefern dann nur noch eine Objekt-Klasse und erst die New-Funktion erstellt das eigentliche (Wrapper-)Objekt. Damit wird dann die Verwendung der New-Funktion obligatorisch.
Zusätzlich wird es auch für alle "Hilfs"-Objekte (wie TRectangleOptions) Konstruktor-Methoden im entsprechenden Namespace geben:

Delphi-Quellcode:

  RectangleOptions:=New(Google.Maps.RectangleOptions);
  [...]

Die direkte Erstellung über

Delphi-Quellcode:

  RectangleOptions:=TRectangleOptions.Create;
  [...]

wird dann nicht mehr möglich sein, da die entsprechenden Konstruktor-Methoden nicht mehr public sind.

Was auf den ersten Blick wie eine Bevormundung des Programmierers aussieht, hat aber mehrere Gründe. Zum einen zählt dazu die bessere Lesbarkeit und die einheitliche Strukturierung des Quelltextes. Zum anderen gibt es den technischen Aspekt, wenn mehrere Browser-Komponenten verwendet werden: Jedes Objekt muß nämlich im entsprechenden Browser-Kontext erstellt werden und das geht nur, wenn dem neu zu erstellenden Objekt das entsprechende Script-Objekt übergeben wird.
Momentan muß das so geschehen:

Delphi-Quellcode:

  RectangleOptions:=TRectangleOptions.Create(Script(WebBrowser1));
  [...]

Das sieht nicht nur bescheiden aus, sondern ist auch im Gegensatz zum neuen Syntax wesentlich komplizierter:

Delphi-Quellcode:

  RectangleOptions:=New(Google.Maps.RectangleOptions);
  [...]

Da das Objekt Maps "weiß", in welchem Kontext es existiert, kann demzufolge auch das Objekt RectangleOptions korrekt erstellt werden.

Obwohl - wie schon erwähnt - alle Objekte automatisch freigegeben werden (alle Karten-Objekte zum Beispiel auch bei einem Refresh mit der Taste F5) ist es mitunter sinnvoll, sie manuell im Quelltext freizugeben. Das betrifft allerdings in der Regel nur die "Hilfsobjekte" (TxxxOptions).

Trotzdem würde ich Dir empfehlen, momentan keine "Hilfsobjekte" manuell freizugeben, da die neue Frameworkversion nach außen hin ausschließlich mit Interfaces arbeitet und damit eine explizite Freigabe überflüssig wird. (Falls jetzt jemand von den Delphi-Profis kommt und sagt "Interfaces werden nicht freigegeben" - dooooooch, auch das wird gehen. Korrekterweise wird natürlich nicht das Interface freigegeben, sondern das dahinterliegende Objekt.)

Wird allerdings ein Rechteck nicht mehr benötigt, kann es selbstverständlich mit Free in den (digitalen) Mülleimer befördert werden. Es meldet sich dann automatisch bei allen internen Listen ab.

Delphi-Quellcode:

var
  Rectangle: IRectangle;
  RectangleOptions: IRectangleOptions;
begin
  [...]
  RectangleOptions:=New(Google.Maps.RectangleOptions);
  RectangleOptions.xxx;
  [...]  
  Rectangle:=New(Google.Maps.Rectangle(RectangleOptions));
  [...]
end; //<- hier wird RectangleOptions automatisch freigegeben, Rectangle bleibt selbstverständlich erhalten

Das Speichermanagement-Problem wird sich also mit der Umstellung auf die kommende Version quasi von selbst erledigen. Um darauf gerüstet zu sein, sollte man keine harten Typumwandlungen mehr vornehmen, sondern jetzt schon den as-Operator verwenden:

Delphi-Quellcode:

  //schlecht:
  TRectangle(Sender).xxx;
  //besser:
  (Sender as TRectangle).xxx;

Damit ist dann die Umstellung schnell erledigt:

Delphi-Quellcode:

  //geht nicht:
  IRectangle(Sender).xxx;
  //geht:
  (Sender as IRectangle).xxx;

[HJay]

Wie kann man den Text eines GoogleMaps-Controls ändern?

Derzeit lautet der Text zum Beispiel "Text" in Fettdruck und ich möchte je nach Bool-Zustand den Text entweder in normal oder in fett ausgeben.

Derzeit ändert sich beim Click folgendes:
+ vorher: weiße Box mit Rahmen und dem Text "Text"
+ nachher: keine Box mehr, nur noch der Text "XXX"

Wie kann man die weiße Box erhalten und einfach nur '<b>Text</b>' durch 'Text' ohne Fettdruck ersetzen?

Wahrscheinlich greife ich auf das falsche InnerHTML-Objekt zu.

Vielen Dank im voraus!

Code:

procedure TGoogleMap.InitMap(Sender: TObject);
  var
    MyOptions         : TMapOptions;
    MyMap             : TMap;
    AControlDiv       : TNode;
    AControl          : TJScriptObject;
begin
  with Script(WebBrowser) do begin
    MyOptions := TMapOptions.Create(Script(WebBrowser));
    with MyOptions do begin
      Zoom := 12;
      Center := New(Google.Maps.LatLng(53.250249,9.835209));
      MapTypeID := Google.Maps.MapTypeID.Roadmap;
    end;
    MyMap := New(Google.Maps.Map(MyOptions));

    MyMap.OnZoomChanged := MapZoomChanged;
    MyMap.OnDragEnd     := MapDragEnd;

    { add button control }
    AControlDiv := Document.CreateDivNode;
    AControl    := TJScriptObject.Create;
    InitControl(AControlDiv);
    MyMap.Controls[Google.Maps.ControlPosition.TopLeft].Push(AControlDiv);
  end;

  if Assigned(Callback) then Callback(Sender);
end;

procedure TGoogleMap.InitControl(AControlDiv: TNode);
  var AControlUI, AControlText: TNode;
begin
  with Script(WebBrowser) do begin
    AControlDiv.Style.Padding := '5px';
    AControlUI := Document.CreateDivNode;
    with AControlUI do
    begin
      with Style do
      begin
        BackgroundColor :=clWhite;
        BorderStyle     :='solid';
        BorderWidth     :='1px';
        Cursor          :='pointer';
        TextAlign       :='center';
      end;
      Title:='a hint to pop up';
    end;
    AControlDiv.AppendChild(AControlUI);

    AControlText := Document.CreateDivNode;
    with AControlText do begin
      with Style do begin
        FontFamily   := 'Arial,sans-serif';
        FontSize     := '12px';
        PaddingLeft  := '4px';
        PaddingRight := '4px';
      end;
      InnerHTML := '<b>Text</b>';
    end;
    AControlUI.AppendChild(AControlText);

    Google.Maps.Event.AddDomListener(AControlUI, 'click', NewFunction(ControlClick));
  end;
end;

procedure TGoogleMap.ControlClick;
begin
  with Script(Webbrowser) do Maps[0].Controls[Google.Maps.ControlPosition.TopLeft].Items[0].InnerHTML := 'XXX';
end;

[swaters]

Thom,
I would like to get the Result for a request as a xml. Is it possible?
My idea is to edit my series of roots and then create one gpx file and then load it to my gps and hopefully be talked through my journey by my iphone.

Thanks.

[Peter.Stadler]

Hallo Thom,

Wie kann man im Delphiprogramm mit Deinem Framework und mit GoogleMaps auf einen Marker clicken und dadurch z. B. ein Programm starten, das ein Bild oder eine Bilder-Kollektion anzeigt?

mfg Peter

[Peter.Stadler]

Hallo Thom,

Habe gerade das EventSimple Projekt studiert. Im Prinzip macht es das, was ich brauche. Aber...
Wenn mehr als ein Marker vorhanden ist, wie bekommt man den Bezug zum richtigen Marker. Bei mir sollt jeder
Marker bei jedem OnClick Event etwas Anderes auslösen.

mfg Peter