Korrekt Fehler bei Zugriff auf Registry abfangen

[wolle72]

Hi,

um in die Registry zu schreiben habe ich das hier gefunden:

Delphi-Quellcode:

begin
    Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True);
    Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"');
    Reg.CloseKey;
  finally
    Reg.Free;
  end;
  end;

Klappt auch prima. Nur wenn ich (unter Vista) keine Admin-Rechte habe dann hängt sich das Programm auf. Wenn ich aber das "finally" durch ein "except" ersetze klappt alles prima. Dann wird zwar bei den fehlenden Rechten nix gemacht, aber es hängt sich auch nix auf.

Seht ihr ein Problem dabei wenn ich ein "except" verwende ?

Viele Grüssle
Wolle

[sirius]

Ja, weil, wenn alles klappt wird Reg.free nicht aufgerufen.
Du kannst aber um den ganzen Code nocht ein try Except herumlegen, wenn du magst und in dem Except dann entsprechend darauf reagieren. Zum Beispiel, den User informieren,....

[Bernhard Geyer]

Eigentlich nein. Wüßte auch bei TRegistry nicht wie es anders gehen sollte.

Und dein "Problem" ist ab Windows NT vorhanden. Dort wird der Registry-Zugriff per Rechtevergabe geregelt.

[argonix]

Ja. Wenn du finally durch except ersetzt wird das Registryobjekt nur im Falle eines Fehlers gelöscht.
Versuche es mal so:

Delphi-Quellcode:

begin 
    Reg := TRegistry.Create;
//try 
  try 
    Reg.RootKey := HKEY_LOCAL_MACHINE; 
    Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True); 
    Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"'); 
    Reg.CloseKey;
except
end; 
 // finally 
    Reg.Free; 
 // end; 
  end;

So müsste das OK sein.

[edit] Sirius war schneller! [/edit]

[Bernhard Geyer]

Zitat:

Zitat von sirius

Ja, weil, wenn alles klappt wird Reg.free nicht aufgerufen.

Lest euch mal etwas in der Online-Hilfe ein. Der Code im Finally-Zweig wird immer abgearbeitet!
Das Konstrukt mit Ressourcenfreigabe im finally ist korrekt!

[semo]

wie wäre es wenn du das problem an der wurzel packst anstatt mögliche folgefehler zu bekämpfen:

Zitat:

Nur wenn ich (unter Vista) keine Admin-Rechte habe dann hängt sich das Programm auf

also gilt es die aktuellen rechte zu ermitteln und dann zu überlegen wie man weiter vorgeht...

[sirius]

Zitat:

Zitat von Bernhard Geyer

Lest euch mal etwas in der Online-Hilfe ein. Der Code im Finally-Zweig wird immer abgearbeitet!
Das Konstrukt mit Ressourcenfreigabe im finally ist korrekt!

Wenn du schon so schlau und überheblich daherkommst:
Les dir bitte mal die Frage durch!

Zitat:

Zitat von wolle72

Wenn ich aber das "finally" durch ein "except" ersetze

[wolle72]

Wenn ich das richtig verstanden habe passen die Ideen von "Sirius" und "argonix" bestens. Denn sie scheinen genau das zu tun was ich wollte und auch die Ressourcenfreigabe scheint zu erfolgen.

Natürlich hat "M. Hassmann" absolut recht. Nur war mir das zuviel für mein Anliegen, da der Code um das zu prüfen IMHO halb so gross ist wie die ganze EXE bisher an sich.

Danke @all

Wolle

[Bernhard Geyer]

Zitat:

Zitat von sirius

Zitat:

Zitat von Bernhard Geyer

Lest euch mal etwas in der Online-Hilfe ein. Der Code im Finally-Zweig wird immer abgearbeitet!
Das Konstrukt mit Ressourcenfreigabe im finally ist korrekt!

Wenn du schon so schlau und überheblich daherkommst:
Les dir bitte mal die Frage durch!

Zitat:

Zitat von wolle72

Wenn ich aber das "finally" durch ein "except" ersetze

:oops: Sorry.

Aber ein try ... finally sollte nicht zum hänger führen.
Kannst du den Code mit Debug-DCU's mal durchdebuggen wenn du keine Registry-Rechte hast wo genau die Anwendung hängen bleibt.

[wolle72]

Zitat:

Zitat von Bernhard Geyer

Aber ein try ... finally sollte nicht zum hänger führen.

Das dachte ich eigentlich auch.

Zitat:

Zitat von Bernhard Geyer

Kannst du den Code mit Debug-DCU's mal durchdebuggen.

Wenn ich herausbekomme wie das geht, dann kann ich das machen. Bin Neuling bei Delphi ;)

[Christian Seehase]

Moin Wolle,

was an dem Code

Delphi-Quellcode:

begin
  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True);
    Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"');
    Reg.CloseKey;
  finally
    Reg.Free;
  end;
end;

jeden Fall noch verbesserungswürdig ist:
OpenKey ist eine Funktion, die einem den Erfolg durch ihr Ergebnis mitteilt.
Soll heissen: Wenn OpenKey fehlgeschlagen ist, machen die Ausführung von WriteString und CloseKey keinen Sinn.

Delphi-Quellcode:

begin
  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True) then begin
      try
        Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"');
      finally
        Reg.CloseKey;
      end;
    end;
  finally
    Reg.Free;
  end;
end;

Der weitere Try/finally-Block (er kann auch das begin/end ersetzen) sichert dann noch das schliessen des Keys ab, falls WriteString fehlschlägt.

[Bernhard Geyer]

Kann es nicht auch sein das einfach nur die durchschlagende Exeption das Problem ist und deshalb anderer Code nicht oder nicht korrekt ausgeführt wird.

Am besten den Code von Chris nehmen und noch ein try ... exept drüber legen um zu verhindern das der restliche Ablauf im Programm gestört wird.

[wolle72]

Hi Chris,

ich hab das jetzt mal so gemacht:

Zitat:

Zitat von Christian Seehase

Delphi-Quellcode:

begin
  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True) then begin
      try
        Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"');
      finally
        Reg.CloseKey;
      end;
    end;
  finally
    Reg.Free;
  end;
end;

weil es mir logisch und sinnvoll erscheint. Aber leider kommt die ursprüngliche Fehlermeldung, was bei

Delphi-Quellcode:

begin
    Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True);
    Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"');
    Reg.CloseKey;
  except
  end;
    Reg.Free;
  end;

nicht der Fall ist.

[teebee]

Die Exception wird wohl durch das WriteString ausgelöst, und da fängst Du ja auch nichts ab. Das müsstest Du noch in ein extra Try...Except einpacken.

Gruß, teebee

[Luckie]

Delphi-Quellcode:

begin 
  Reg := TRegistry.Create; 
  try 
    Reg.RootKey := HKEY_LOCAL_MACHINE; 
    if Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True) then
    begin 
      try
        Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"'); 
        Reg.CloseKey;
      except
        Reg.CloseKey;
        raise Exception.Create(SyserrorMessage(GetLastError)); 
    else
       raise Exception.Create(SyserrorMessage(GetLastError)); 
    end; 
  finally 
    Reg.Free; 
  end; 
end;

So würde ich es machen, glaube ich.

[DeddyH]

Hallo Luckie, da steige ich nicht durch. Wozu gehört denn das else? Und wo ist das end des try-except-Blocks?

[teebee]

Ich würde es so machen, dass ich alles in eine Funktion packe, die mir als Rückgabewert nur ok oder nicht zurückgibt. Der Aufrufer kann dann entscheiden, was er mit dem Ergebnis anfängt. Darüber, ob ein leerer Except-Abschnitt guter Stil ist oder nicht, kann man sicher diskutieren (wenn man will...)

Delphi-Quellcode:

Function SchreibeIrgendetwasInRegistry: Boolean;
Var Reg: TRegistry;
Begin
  Result := False;
  Reg := TRegistry.Create;
  Try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    If Reg.OpenKey('Software\Microsoft\Windows\CurrentVersion\Run', True) Then
    Begin
      Try
        Try
         Reg.WriteString('TempCleaner','"' + ParamStr(0) + '" ' + ParamStr(1) + ' "' + ParamStr(2) + '"');
         Result := True; // hierhin kommen wir nur, wenn alles OK war
        Except
        End;
      Finally
        Reg.CloseKey;
      End;
    End;
  Finally
    Reg.Free;
  End;
End;

[wolle72]

@teebee

Das scheint soweit prima zu tun :-D Ich hab's jetzt zwar nicht als Funktion integriert, aber datt dürft ja keinen Unterschied machen.

Danke !
Viele Grüsse Wolle

[Luckie]

Zitat:

Zitat von DeddyH

Hallo Luckie, da steige ich nicht durch. Wozu gehört denn das else? Und wo ist das end des try-except-Blocks?

Jupp, kann sein, dass da die Blöcke nicht ganz passen, weil ich es hier im Beitragseditor getippt habe. Aber das Prinzip sollte klar sein. Das else gehört zu dem if Reg.OpneKey(...).