Doppelte Einträge in 5 ComboBoxen herausfinden ?

[HolgerCW]

Hallo zusammen,

ich habe 5 ComboBoxen in denen man überall das selbe auswählen kann.

Wie kann ich nun am besten Abfragen, ob in mindestens zwei ComboBoxen, das selbe ausgewählt wurde.

Das Ergebnis soll nämlich sein, das in jeder ComboBox entweder nichts oder unterschiedliche Werte gegenüber den anderen ComboBoxen ausgewählt werden.

Gruss

Holger

[mkinzler]

wenn die Reihenfolge auch identisch ist, einfach die Idizes vergleichen

[HolgerCW]

Die ist identisch,

wie würdest Du den Vergleich machen, da man ja jede ComboBox gegen jede andere Vergleichen müsste ?

Gruss

Holger

[Aurelius]

Eine schleife nutzen(in der immer eine comboBox gewählt ist) und dann mit Findcomponent die anderen comboboxen finden und mit der gewählten vergleichen (auch in einer Schleife).

[HolgerCW]

Hast Du da vielleicht mal ein kleines Codebeispiel ?

Gruss

Holger

[Aurelius]

Nein, leider nicht. Aber bestimmt findet man hier in der DP was zum Thema FindComponent

[mkinzler]

Wenn du die ComboBoxen kennst brauchst du sie ja nicht mit .FindComponent suchen. Den Index des ausgewählten Eintrags kannst du per .ItemIndex ermitteln.

[Die Muhkuh]

Hi,

wenn Du z.B. den Text einer ComboBox abfragen willst, könntest Du es z.B. so machen:

Delphi-Quellcode:

var
  I: Integer;
  J: Integer;
  cbb_comp1, cbb_comp2: TComboBox;
begin
  for I := 0 to Self.ComponentCount - 1 do
  begin
    if Self.Components[I] is TComboBox then
    begin
      cbb_comp1 := (Self.Components[I] as TComboBox);

      for J := 0 to Self.ComponentCount - 1 do
      begin
        if Self.Components[J] is TComboBox then
        begin
          cbb_comp2 := (Self.Components[J] as TComboBox);

          if cbb_comp1 <> cbb_comp2 then
          begin
            if cbb_comp1.Text = cbb_comp2.Text then
            begin
              ShowMessage(cbb_comp1.Name + ' und ' + cbb_comp2.Name + 
                ' sind gleich');
            end;
          end;
        end;
      end;
    end;
  end;
end;

[MaBuSE]

Zitat:

Zitat von HolgerCW

Die ist identisch,
wie würdest Du den Vergleich machen, da man ja jede ComboBox gegen jede andere Vergleichen müsste ?

Eine einfache Lösung auf die Schnelle ist folgende:

(Natürlich kann man die Comboboxen auch mit FindComponent suchen, aber das hier ist ja nur ein einfaches Beispiel.
Das Füllen der Comboboxen ist nur zu Testzwecken drin. 5 Comboboxen und ein Button auf das Form und dann folgenden Quelltext einfügen.)

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ComboBox1: TComboBox;
    ComboBox2: TComboBox;
    ComboBox3: TComboBox;
    ComboBox4: TComboBox;
    ComboBox5: TComboBox;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  a : Array [1..5] of TComboBox;
  sl: TStringList;
  i, j: integer;
  ok : Boolean;
begin
  // Dem Array die ComboBoxen zuweisen
  a[1] := ComboBox1;
  a[2] := ComboBox2;
  a[3] := ComboBox3;
  a[4] := ComboBox4;
  a[5] := ComboBox5;

  // nur wenn ComboBox Listen leer sind
  if a[1].Items.Count = 0 then
  begin
    // Eine Liste für alle Comboboxen erstellen
    sl := TStringList.Create;
    try
      sl.Add('Eins');
      sl.Add('Zwei');
      sl.Add('Drei');
      sl.Add('Vier');
      sl.Add('Fünf');

      // Liste allen Comboboxen zuweisen
      for i := 1 to 5 do
      begin
        a[i].Items.Assign(sl);
      end;
    finally
      sl.Free;
    end;
  end;

  // ok ist True wenn alle Inhalte unterschiedlich sind
  ok := True;

  // Comboboxen miteinander vergleichen
  for i := 1 to 5 do
  begin
    if a[i].ItemIndex > -1 then
    begin
      for j := i + 1 to 5 do
      begin
        ok := ok and (a[i].ItemIndex <> a[j].ItemIndex);
      end;
    end;
  end;

  // ok ausgeben
  if ok then Caption := 'ok' else Caption := 'not ok';
end;

end.

[HolgerCW]

Super danke,

habe das jetz mit FindComponent gelöst:

Delphi-Quellcode:

var
 I, T: Integer;
 CB1, CB2: TComboBox;
begin

 For I := 1 to 5 do
 begin

  For T := 1 to 5 do
  begin

   CB1 := TComboBox(Form_Sigma_Auftrag.FindComponent('CB_Auftragstyp_' + IntToStr(I)));
   CB2 := TComboBox(Form_Sigma_Auftrag.FindComponent('CB_Auftragstyp_' + IntToStr(T)));

   If (CB1.Text = CB2.Text) AND (I <> T) AND (CB1.Text <> '') AND (CB2.Text <> '')  then
   begin

    Application.MessageBox(PChar('Der Auftragstyp ' + CB1.Text + ' ist doppelt vorhanden.'),'Kritischer Fehler',MB_OK or MB_ICONSTOP);
    exit;

   end;

  end;

 end;

Gruss

Holger

[MaBuSE]

Zitat:

Zitat von Die Muhkuh

wenn Du z.B. den Text einer ComboBox abfragen willst, könntest Du es z.B. so machen:

Ok Du warst schneller :-)
Aber was macht Du wenn er 7 Comboboxen auf dem Form hat, aber nur 5 Testen will?
In dem Fall ist das mit dem direkten Zuweisen einfacher. ;-)

Mann kann das auch in eine Funktion packen so was wie:

Delphi-Quellcode:

...
function CheckComboBoxes(const a: array of TComboBox): Boolean;
var i, j: Integer;
begin
  Result := True;
  for i := 0 to High(a) do
    if a[i].ItemIndex > -1 then
      for j := i + 1 to High(a) do
      begin
        Result := Result and (a[i].ItemIndex <> a[j].ItemIndex);
      end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  if CheckComboBoxes([ComboBox1, ComboBox2, ComboBox3])
    then Caption := 'OK'
    else Caption := 'NOT OK';
end;
...

Damit ist man flexibel, da mann beliebig viele Comboboxen angeben kann.
Ich hoffe das hilft Dir weiter ;-)

[Die Muhkuh]

Hi MaBuSe,

da hast Du natürlich recht. Wenn ich jetzt Deine Lösung mit dem Array sehe, ist es imho die beste Lösung. ;-)

[HolgerCW]

Astrein.

Vielen dank für all die Lösungen.

Gruss

Holger

[MaBuSE]

Zitat:

Zitat von HolgerCW

Delphi-Quellcode:

...
 For I := 1 to 5 do
 begin
  For T := 1 to 5 do
  begin
...

Du macht unnötig viele Vergleiche.

i = 1 und t = 2 gibt immer das selbe Ergebnis wie i = 2 und t = 1


Ich habe meine Funktion von ItemIndex auf Text Vergleich umgestellt, da es Dir wohl sympatischer ist ;-)

(Durch das [i]Result := Result and (a.Text <> a[j].Text); wird übrigens bei Result := False kein Vergleich mehr durchgeführt, da der Compiler das wegoptimiert.)

Delphi-Quellcode:

...
function CheckComboBoxes(const a: array of TComboBox): Boolean;
var i, j: Integer;
begin
  Result := True;
  for i := 0 to High(a) do
    if a[i].Text <> '' then
      for j := i + 1 to High(a) do
      begin
        Result := Result and (a[i].Text <> a[j].Text);
      end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  if CheckComboBoxes([ComboBox1, ComboBox2, ComboBox3])
    then Caption := 'OK'
    else Caption := 'Ein Auftragstyp ist doppelt vorhanden';
end;
...

[Die Muhkuh]

Hi,

man könnte das ganze jetzt noch weitgehend "verbessern" und den Index der ComboBoxen zurückgeben, in denen das gleiche ausgewählt ist. ;-)

[HolgerCW]

Super,

danke werde es umsetzen.

Gruss

Holger