FensterText per ProcessID bekommen?

[sk0r]

Hi,

kurze und schnelle Frage: WIe kann ich per WinAPI den
Text des Fensters einer Anwendung bekommen deren ProcessID
ich habe? Ich finde bei MSDN leider keine API.

Danke im Vorraus für Hilfe

MfG: sk0r

[DGL-luke]

von der pid solltest du irgendwie zum hauptfenster kommen, und das handle des hauptfensters kann in GetWindowText(Len) packen.

[Wotan89]

http://msdn2.microsoft.com/en-us/library/ms633520(VS.85).aspx

[sk0r]

GetWindowText() habe ich schon ausprobiert. MEin Ziel ist es,
dass eine injizierte DLL den Fenstertext des Zielprogrammes zu bekommen.

Code:

procedure TForm1.FormCreate(Sender: TObject);
var
  myBuf: array[0..250] of Char;
begin
  setlasterror(ERROR_SUCCESS);
  GetWindowText(0, myBuf, sizeof(myBuf));
  showmessage(myBuf);
  showmessage(syserrormessage(getlasterror));
end;

Die Eigene Anwendung hat doch immer die Nummer 0, oder?

[SirThornberry]

nein, auch die eigene Anwendung hat nicht die 0

[sk0r]

Also GetWindowText kann nicht einfach so funktionieren, da es ja
selbst ein Handle als Parameter benötigt. Aber wie komme ich da drann? :/

[DGL-luke]

ähm, getcurrentprocess oder so ähnlich sollte dir die procid geben... und dann weiter wie in meinem ersten post ^^

[sk0r]

schon klar, aber wie komme ich denn an das fenster handle?^^

[DGL-luke]

aus der google-suche entnommen:

Zitat:

Enumerate all windows (EnumWindows()), get process ID for each one (GetWindowThreadProcessId()). Compare it with process ID you've got and if the same you found your window.

[Olli]

Die meisten Prozeße werden mehrere Fenster haben. Schlimmer noch, dank der Tatsache, daß es sowas wie ein "Hauptfenster" nicht gibt (ein Prozeß kann da auch mehrere mit dem entsprechenden Fensterstil haben), mußt du wohl, wie schon erwähnt durch alle Fenster gehen und ermitteln ob das gewünschte dabei ist. Da wird wohl nur eine Kombination aus Text, Klasse und Stil (o.ä.) einen Erfolg bringen. Wenn du nur den Text ermittelst, kann das schiefgehen.

[bitsetter]

Hi,

mit EnumThreadWindows müsste es IMHO auch gehen, die Fenster in der Liste müsstest du eventuell nochmal filtern.
Mal schnell zusammengetippt:

Delphi-Quellcode:

uses TLHelp32, Contnrs;

type
  TWndItem = class(TObject)
    Wnd: HWND;
end;

function EnumThreadWndProc(Wnd: HWND; WndList: TObjectList): BOOL; stdcall;
var
  WndItem: TWndItem;
begin
  WndItem:= TWndItem.Create;
  WndItem.Wnd:= Wnd;
  WndList.Add(WndItem);
  Result:= true;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  WndList: TObjectList;
  Thread32: TThreadEntry32;
  hThreadSnap: THandle;
  ProcId: DWord;
  i: integer;
  myBuf: array[0..250] of Char;
begin
  WndList:= TObjectList.Create;
  try
    ProcId := ...;//GetCurrentProcessId();
    hThreadSnap := CreateToolHelp32Snapshot(TH32CS_SNAPTHREAD, ProcId);
    if (hThreadSnap > 0) and (hThreadSnap <> INVALID_HANDLE_VALUE) then
      try
        ZeroMemory(@Thread32, SizeOf(TThreadEntry32));
        Thread32.dwSize := SizeOf(TThreadEntry32);
        if Thread32First(hThreadSnap, Thread32) then
          repeat
            if ProcId = Thread32.th32OwnerProcessID then
              EnumThreadWindows(Thread32.th32ThreadID, @EnumThreadWndProc, DWord(WndList));
          until not Thread32Next(hThreadSnap, Thread32);
      finally
        CloseHandle(hThreadSnap);
      end;

    for i:= 0 to Pred(WndList.Count) do
    begin
      if Windows.IsWindowVisible(TWndItem(WndList.Items[i]).Wnd) then
      begin
        GetWindowText(TWndItem(WndList.Items[i]).Wnd, myBuf, sizeof(myBuf));
        ListBox1.Items.Add(myBuf);
      end;
    end;

  finally
    WndList.Free;
  end;
end;

[Luckie]

EnumThreadWindows muss dann aber auch für alle Threads des Prozesses ausgeführt werden!

[bitsetter]

Dass wird doch in der Schleife gemacht oder nicht?
In den meisten Fällen wird es jedenfalls ausreichen.

[mschaefer]

oder nicht 'EnumThreadWndProc' müßte mehrfach aufgerufen werden...