Ordner prüfen ob er leer ist

[SaFu]

Hi

gibt es eine Möglichkeit zu prüfen ob ein Ordner lee ist oder nicht

z.b.

Delphi-Quellcode:

if Directory(C:\test) = Empty then
showmessage ('leer');

Gruß Sascha

[SirThornberry]

mit FindFirst und FindNext schauen ob etwas im ordner gefunden wird :)

[Aurelius]

da bräuchte man doch nur per FindFirst() zu gucken ob du was findest...

//Da war Sir Thornberry ein bisschen schneller :D

[SirThornberry]

Aber Vorsicht - FindFirst alleine geht schief weil in jedem Ordner "." und ".." gefunden wird.

[Aurelius]

Nicht gewusst :thumb:

[SaFu]

so ähnlich

Delphi-Quellcode:

if FindFirst(Form1.ServerPfad + 'Bilder',faAnyFile, SR) = 0 then

[Klaus01]

Zitat:

Zitat von fuknersascha

so ähnlich

Delphi-Quellcode:

if FindFirst(Form1.ServerPfad + 'Bilder',faAnyFile, SR) = 0 then

Ich würde die Suche etwas spezifizieren.

Delphi-Quellcode:

if FindFirst(Form1.ServerPfad + 'Bilder\*.jpg',faAnyFile, SR) = 0 then

Denn bei Deiner Abfrage werden auch die . und .. Verzeichnisse mit ausgewertet.
Wie der Sir schon gesagt hat.

Grüße
Klaus

[taaktaak]

Hmm, schon richtig,
aber bei Angabe eines Extends wird nicht allgemeingültig geprüft, ob das Verzeichnis leer ist. In diesem Fall wird lediglich geprüft, ob sich Dateien mit der spezifizierten Endung im Verzeichnis befinden.

[Klaus01]

Zitat:

Zitat von taaktaak

Hmm, schon richtig,
aber bei Angabe eines Extends wird nicht allgemeingültig geprüft, ob das Verzeichnis leer ist. In diesem Fall wird lediglich geprüft, ob sich Dateien mit der spezifizierten Endung im Verzeichnis befinden.

Hallo Ralph,

das ist schon richtig was Du schreibst.
Ich ging nur davon aus, dass sich im Ordner Bilder auch nur jpg-Bilder befinden.

Grüße
Klaus

[SaFu]

Ja mein problem ist ja noch das ich auf drei Formate prüfen muss (jpg,gif und bmp) also fühge ich es einfach mit einem OR an oder?

einfacher wäre es natürlich ob es kommplett leer ist.

[taaktaak]

Mit OR die Strings verketten? Nee, wie sollte das funktionieren?

[Klaus01]

Hallo Sascha,

habe noch diesen Code gefunden.
Dort wird auf *.* geprüft.

Grüße
Klaus

[taaktaak]

Das ist dort ja nahezu genial gelöst!

[SaFu]

Also ich kann machen was ich will ich bekomm immer nur ein false rause

Delphi-Quellcode:

directory:= (Form1.ServerPfad + 'DokumentenurRTF');
isEmpty := IsDirectoryEmpty(directory) ;

ShowMessage(BoolToStr(isEmpty,true)) ;

function TForm5.IsDirectoryEmpty(const directory: string): boolean;
var
  searchRec :TSearchRec;
begin
  try
   result := (FindFirst(directory+'\*.*', faAnyFile, searchRec) = 0) AND
             (FindNext(searchRec) = 0) AND
             (FindNext(searchRec) <> 0) ;
  finally
    FindClose(searchRec) ;
  end;
end;

mach ich was falsch

[SirThornberry]

autsch. Die Lösung gefällt mir überhaupt nicht. Aber das ist geschmacksache. Am besten weißt du die Ergebnisse erstmal auf temporäre Variablen zu dann kannst du debuggen warum du nicht das gewünschte Ergebnis bekommst.

[SaFu]

Das ergebnis ist doch auf eine Variable zugewiesen

Delphi-Quellcode:

isEmpty : boolean;

oder verstehe ich das falsch

[taaktaak]

Moin, Moin SirThornberry!
Was gefällt dir an der Lösung nicht (abgesehen davon, dass sie keine korrekten Ergebnisse liefert) - Subdirectories werden in der Originalform leider auch als Files erkannt! Aber sonst ist sie doch optinal kurz: FindFirst findet ".", das erste FindNext findet "..", das zweite FindNext enstscheidet dann (leider falsch)

[SirThornberry]

mir gefällt an der Lösung zum Beispiel nicht das FindClose auch aufgerufen wird wenn FindFirst fehlschlägt. Das ist zwar erlaubt aber überflüssig. Der Sinn von Try-Finally bleibt mir an der Stelle auch Schleierhaft. Es ist nirgends Code der eine Exception erzeugen könnte.

[Die Muhkuh]

Hi,

ich werfe mal diese Funktion in den Raum:

Delphi-Quellcode:

function IsDirectoryEmpty(Directory: String): Boolean;
var
  SR: TSearchRec;
begin
  Result := false;

  if FindFirst(Directory, faAnyFile, SR) = 0 then
  begin
    repeat
       Result := (SR.Name <> '.') and (SR.Name <> '..');
    until Result;

    FindClose(SR);
  end;
end;

[taaktaak]

Ja, das sind nachvollziehbare Argumente :hi:

[DeddyH]

@Manuel: Fehlt da nicht ein FindNext?

[taaktaak]

@Muhkuh: Aber auch deine Funktion erkennt Directories als Files - oder??

[SaFu]

jetzt bin total verwirrt bei mir funktioniert so gut wie keine lösung richtig

[DeddyH]

Zitat:

Zitat von taaktaak

@Muhkuh: Aber auch deine Funktion erkennt Directories als Files - oder??

Was wäre denn da so schlimm daran? Ein Verzeichnis, das Unterverzeichnisse enthält, ist eben auch nicht leer.

[taaktaak]

Wieso schlimm, kommt natürlich auf die Aufgabenstellung an :mrgreen:

[bluesbear]

Jetzt kam ich ins grübeln, wie ich das eigentlich mache. Ganz tief unten in der Code-Kiste fand ich die Kanone, mit der ich auf den Spatz schieße:

Delphi-Quellcode:

procedure GetListOfFiles(FileList: TStrings; Source, FileMask: string;
    Attributes, IgnoreAttributes: Integer; Recurse: Boolean);
var SearchDir: string;
    SearchRec: TSearchRec;
    Res : Integer;
    DirList : TStringList;
    i : Integer;
begin
  DirList := TStringList.Create;
  try
    SearchDir := AddBackSlashL(Source);
    Res := SysUtils.FindFirst(SearchDir + FileMask, Attributes, SearchRec);
    while (Res = 0) and (SearchRec.Name > '') do begin
      if (SearchRec.Name <> '.') and (SearchRec.Name <> '..') and
         ((Attributes = faAnyFile) or ((SearchRec.Attr and Attributes) <> 0))  and
         ((IgnoreAttributes = 0) or ((SearchRec.Attr and IgnoreAttributes) = 0)) then begin
        FileList.Add(SearchDir + SearchRec.Name);
      end;
      Res := FindNext(SearchRec);
    end;
    if Recurse and ((Attributes and faDirectory) = 0) then begin   // Unterordner durchsuchen
      GetListOfFiles(DirList, Source, '*.*', faDirectory, 0, True);
      for i:=0 to Pred(DirList.Count) do begin
        GetListOfFiles(FileList, DirList[i], FileMask, Attributes, 0, True);
      end;
    end;
  finally
    SysUtils.FindClose(SearchRec);
    DirList.Free;
  end;
end;

function IsDirEmpty(const Dir: string): Boolean;
var SL : TStringList;
begin
  SL := TStringList.Create;
  try
    GetListOfFiles(SL, Dir, '*.*', faAnyFile - faDirectory, 0, False);
    Result := SL.Count = 0;
  finally
    SL.Free;
  end;
end;

Nu, der Spatz ist garantiert tot! :mrgreen:

[DeddyH]

Noch' n Gedicht :mrgreen:

Delphi-Quellcode:

function IsFolderEmpty(const Foldername: string): Boolean;
var Rec: TSearchRec;
begin
  Result := false;
  if FindFirst(IncludeTrailingPathDelimiter(Foldername) + '*.*',faAnyFile,Rec) = 0 then
    begin
      repeat
        Result := (Rec.Name = '.') or (Rec.Name = '..');
      until (FindNext(Rec) <> 0) or not Result;
      FindClose(Rec);
    end;
end;

[Die Muhkuh]

Zitat:

Zitat von DeddyH

@Manuel: Fehlt da nicht ein FindNext?

:oops: Asche auf mein Haupt.

[SaFu]

Ok Danke funktioniert so

gruss sascha

[Christian Seehase]

Zitat:

Zitat von DeddyH

Noch' n Gedicht :mrgreen:

Delphi-Quellcode:

function IsFolderEmpty(const Foldername: string): Boolean;
var Rec: TSearchRec;
begin
  Result := false;
  if FindFirst(IncludeTrailingPathDelimiter(Foldername) + '*.*',faAnyFile,Rec) = 0 then
    begin
      repeat
        Result := (Rec.Name = '.') or (Rec.Name = '..');
      until (FindNext(Rec) <> 0) or not Result;
      FindClose(Rec);
    end;
end;

Ich hätte dazu noch eine Idee ;-)

Delphi-Quellcode:

function IsDirectoryEmtpy(const AsFolder : string) : Boolean;

var
  sr : TSearchRec;

begin
  Result := FindFirst(IncludeTrailingPathDelimiter(AsFolder)+'*.*',faAnyFile,sr) = 0;
  if Result then begin
    try
      Result := (FindNext(sr) = 0) and (FindNext(sr) <> 0);
    finally
      FindClose(sr);
    end;
  end;
end;

[himitsu]

Zitat:

Zitat von Christian Seehase

Delphi-Quellcode:

Result := (FindNext(sr) = 0) and (FindNext(sr) <> 0);

teste dieses z.B. mal an einem Rootverzeichnis wie "C:\" :twisted:

[marabu]

Moin,

nicht Delphi, aber Windows bringt die gesuchte Funktion bereits mit:

Delphi-Quellcode:

const
  shlwapi = 'shlwapi.dll';

function PathIsDirectoryEmpty(pszPath: PAnsiChar): BOOL; stdcall;
    external shlwapi name 'PathIsDirectoryEmptyA';

procedure TDemoForm.ButtonClick(Sender: TObject);
var
  isEmpty: Boolean;
begin
  isEmpty := PathIsDirectoryEmpty(PChar(Edit.Text));
  ShowMessage(BoolToStr(isEmpty, True));
end;

Da auch nicht existierende Verzeichnisse als "nicht leer" ausgewiesen werden, wird man wohl in der Regel zusätzlich SysUtils.DirectoryExists() einsetzen.

Grüße vom marabu

[SaFu]

Also die Lösung vom Klaus01 funktioniert bis jetzt ohne Probleme, gut ich muss dazu sagen das ich dieses noch nicht groß getestet habe aber im groben funzt es.

Ich bin natürlich für verbesserungen offen