TreeView mit Anzahl der Datensätze im Text

[DevStar]

Hallo,

habe einen TreeView erstellt für meine Datenbank.

Jetzt möchte ich gerne die Anzahl der Datensätze im Text anzeigen lassen.


-- Kunden (74)
-- Aufträge (25)

Wie kann ich das machen?

Hat da jemand einen Tip?

Gruß DevStar

[mkinzler]

Einfach den text der Node dementsprechend erweitern. Erstellst du diese manuell oder hast verwendest du ein TDBTreeView

[omata]

Hier mal ein Schnellschuss...

Delphi-Quellcode:

function addChildCount(Node:TTreeNode):integer;
begin
  Result:=0;
  if assigned(Node) then begin
    repeat
      if Node.HasChildren then
        Node.Text:=Node.Text + ' (' + inttostr(addChildCount(Node.getFirstChild)) + ')';
      inc(Result);
      Node:=Node.getNextSibling;
    until not assigned(Node);
  end;
end;

Aufruf:

Delphi-Quellcode:

addChildCount(TreeView.Items.GetFirstNode);

[DevStar]

Hallo, vielen lieben dank erstmal.

Es ist kein dbTreeView.

Habe es selber erstellt zur Laufzeit.

Funktioniert soweit ganz gut. Nur kann ich meine Datensätze nicht mehr auswählen, da ich für den SELECT-Befehl den Node.Text abgreife:

Delphi-Quellcode:

Node := TreeView1.Selected;
sSQL_Table := 'SELECT * FROM VIEW_KUNDEN ';

sSQL_Bedinung := 'WHERE KOSTENBEZEICHNUNG = ''' + Node.Parent.Text + ''' ' +
                 'AND KASSENNAME = ''' + Node.Text + ''' ' +
                 'ORDER BY NUMMER';

sSQL := sSQL_Table + sSQL_Bedinung;

Ich müsste also eine Funktion finden die dien Klammerwert wieder entfernt. "(xx)"
Das geht aber nicht, weil ich ja nicht weiß wieviel Zeichen xx haben wird.
Sonst müsste das doch mit Pos und Delete gehen??

[mkinzler]

Dafür würde ich den Tag nehmen

[DevStar]

Zitat:

Zitat von mkinzler

Dafür würde ich den Tag nehmen

Äh..und wie? Weiß nicht genau was Du meinst.

[mkinzler]

Ich würde den PK-Wert in der Eigenschaft Tag des Knotens ablegen

[omata]

Hier noch ein anderer Vorschlag...

Delphi-Quellcode:

function DeleteCount(Text:string):string;
var Posi:integer;
begin
  Result:=Text;
  repeat
    Posi:=pos(' (', Text);
    if Posi > 0 then
      delete(Text, 1, Posi);
  until Posi = 0;
  delete(Result, length(Result) - length(Text), length(Result));
end;

[mkinzler]

Wobei ich eine Bezeichnung niemals als Schlüsselkriterium verwenden würde.

[DevStar]

Zitat:

Zitat von mkinzler

Wobei ich eine Bezeichnung niemals als Schlüsselkriterium verwenden würde.

Schon klar, aber das läßt sich mit einem selbsterstellten dbTreeView schlecht darstellen.

Zu Omata's Funktion:

Diese liefert mir leider nur die ersten beiden Zeichen des Textes.

Edit: Muss nochmal nerven. Gibt es eine Möglichkeit den Klammerwert in einer anderen Farbe dazustellen? So wie in IBExpert.

[omata]

Das sollte so eigentlich gehen...

Delphi-Quellcode:

function DeleteCount(Text:string):string;
var Posi:integer;
begin
  Result:=Text;
  repeat
    Posi:=pos(' (', Text);
    if Posi > 0 then
      delete(Text, 1, Posi);
  until Posi = 0;
  delete(Result, length(Result) - length(Text), length(Result));
end;

function addChildCount(Node:TTreeNode):integer;
begin
  Result:=0;
  if assigned(Node) then begin
    repeat
      if Node.HasChildren then
        Node.Text:=DeleteCount(Node.Text) + ' (' + inttostr(addChildCount(Node.getFirstChild)) + ')';
      inc(Result);
      Node:=Node.getNextSibling;
    until not assigned(Node);
  end;
end;

Aufruf:

Delphi-Quellcode:

addChildCount(TreeView.Items.GetFirstNode);

[DevStar]

Zitat:

Zitat von omata

Das sollte so eigentlich gehen...

Ja jetzt geht es. Hast Du was geändert an der function oder hab ich nur falsch abgetippt.

Super.Danke. Ihr seit die besten.

Jetzt muss ich den Klammerwert nur noch in blau darstellen und ich bin glücklich.

Danke nochmal.

[omata]

Hier mal ein Vorschlag...

Delphi-Quellcode:

TForm = class(TForm)
:
private
  { Private-Deklarationen }
  FBitmap:TBitmap;
:
:
procedure TForm.FormCreate(Sender: TObject);
begin
  FBitmap:=TBitmap.Create;
end;

procedure TForm.FormDestroy(Sender: TObject);
begin
  FBitmap.free;
end;

procedure TForm.TreeViewAdvancedCustomDrawItem(Sender: TCustomTreeView;
  Node: TTreeNode; State: TCustomDrawState; Stage: TCustomDrawStage;
  var PaintImages, DefaultDraw: Boolean);
var Rect:TRect;
    Text, Zahl:string;
begin
  Rect:=Node.DisplayRect(true);
  FBitmap.Height:=Rect.Bottom - Rect.Top;
  FBitmap.Width:=Rect.Right - Rect.Left;
  Text:=DeleteCount(Node.Text);
  Zahl:=Node.Text;
  delete(Zahl, 1, length(Text));
  if cdsFocused in State then begin
    FBitmap.Canvas.Font.Color:=clWhite;
    FBitmap.Canvas.Brush.Color:=clActiveCaption;
  end
  else begin
    FBitmap.Canvas.Font.Color:=clBlack;
    FBitmap.Canvas.Brush.Color:=clWhite;
  end;
  FBitmap.Canvas.FillRect(FBitmap.Canvas.ClipRect);
  FBitmap.Canvas.TextOut(2, 1, Text);
  FBitmap.Canvas.Font.Color:=clBlue;
  FBitmap.Canvas.TextOut(FBitmap.Canvas.TextWidth(Text)+8, 1, Zahl);
  Sender.Canvas.Draw(Rect.Left, Rect.Top, FBitmap);
end;

[DevStar]

Zitat:

Zitat von omata

Hier mal ein Vorschlag...

Hast Du auch mal ein Beispiel wie ich diese Procedure aufrugen kann?

Das klappt leider nicht:

Delphi-Quellcode:

TreeViewAdvancedCustomDrawItem (TreeView1, TreeView1.Selected, cdsDefault, true, true);

[omata]

Doppelklick im Objektinspektor auf der Ereignisseite vom TreeView. Dort gibt es das Ereignis.

[DevStar]

Zitat:

Zitat von omata

Doppelklick im Objektinspektor auf der Ereignisseite vom TreeView. Dort gibt es das Ereignis.

OK, tut sich aber nichts. Die Procedure wird ausgeführt, sehe aber jetzt keine Änderung im Tree.

[omata]

Hier mal ein Beispiel.

[DevStar]

Zitat:

Zitat von omata

Hier mal ein Beispiel.

Klasse. Fehler gefunden. Funktioniert bestens.

D A N K E !!!!