Cursor in Editfeld setzen

[Kiaro]

Hi ihr!

Hab ne wohl recht einfache Frage, bin nur nich selber drauf gekommen bisher.
Wie kann ich wenn ich auf einen Button klicke dabei ein Editfeld so anwählen, dass der Cursor drin sitzt und ich munter drauf los schreiben kann?

form1.edit1.?? oder doch anders? :gruebel:

mfg Kiaro

[Vjay]

Delphi-Quellcode:

ActiveControl:= Edit1;

[notam]

Oder

Delphi-Quellcode:

edit1.SetFocus;

Gruß Manuel

[gekmihesg]

am besten:

Delphi-Quellcode:

edit1.setfocus();
edit1.selectionstart:=length(edit1.text);

[naudoc]

Hallo,
ich lasse dieses Thema wieder auferstehen, weil die von euch angegebenen Codes bei mir nicht funktionieren...
Bei procedure OnFormCreate geht es, nicht jedoch bei folgender:

Delphi-Quellcode:

procedure TForm1.TabbedNotebook1Change(Sender: TObject; NewTab: Integer;
  var AllowChange: Boolean);
begin
if tabbednotebook1.ActivePage='Rechnen' then begin edit1.SetFocus(); ActiveControl:= Edit1; end; 

if tabbednotebook1.activepage='Graphen zeichnen' then begin edit4.SetFocus(); ActiveControl:= Edit4; end; 

end;

Ich habe auch beide angegebenen Codes einzeln versucht...

Danke

mfG

[luka]

oder

Delphi-Quellcode:

procedure TForm1.FormShow(Sender: TObject);
begin
   Edit1.SetFocus;
   Edit1.SelectAll;
end;

[marabu]

Guten Morgen,

das Ereignis OnChange() wird beim TabbedNoteBook vor dem eigentlichen Seitenwechsel ausgelöst, deshalb kann der Focus nicht sofort auf das neue Control gesetzt werden:

Delphi-Quellcode:

procedure TDemoForm.TabbedNotebookChange(Sender: TObject; NewTab: Integer;
  var AllowChange: Boolean);
begin
  case NewTab of
    0: PostMessage(Edit1.Handle, WM_SETFOCUS, 0, 0);
    1: PostMessage(Edit2.Handle, WM_SETFOCUS, 0, 0);
  end;
end;

Der moderne Nachfolger von TTabbedNoteBook ist TPageControl.

Grüße vom marabu

[naudoc]

Hi,

danke für die Erklärung und den Tip...

bei ersten mal wechseln funktioniert es auch, aber danach nur noch wenn ich auf Rechnen(also 0) drücke, und das edit4 in Graphen zeichnen ist blockiert.

Woran könnte das liegen?

mfG

[marabu]

Hallo,

in meiner Clean Room Umgebung tritt dieses Phänomen nicht auf. Ich vermute, dass dein sonstiger Code das Fehlverhalten produziert.

Freundliche Grüße

[naudoc]

Ich hab jetzt ein neues Projekt nur mit nem TabbedNOtebook und 2 Edits gemacht, und da gehts auch nicht...
welche Version von Delphi hast du denn? Ich habe Delphi7...

Hast du noch andere Vermutungen?

mfG

[marabu]

Hallo,

du hast Recht. Es gibt Probleme, wenn man einfach nur die Fokusierung auf Windows-Ebene durchführt. Da kein Ereignis nach dem Seitenwechsel ausgelöst wird, führe ich eine Custom Message ein:

Delphi-Quellcode:

const
  UM_SETFOCUS = WM_USER;

type
  TDemoForm = class(TForm)
    TabbedNotebook: TTabbedNotebook;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Edit4: TEdit;
    procedure TabbedNotebookChange(Sender: TObject; NewTab: Integer;
      var AllowChange: Boolean);
  private
    procedure UMSetFocus(var Msg: TMessage); message UM_SETFOCUS;
  end;

var
  DemoForm: TDemoForm;

implementation

{$R *.dfm}

procedure TDemoForm.UMSetFocus(var Msg: TMessage);
begin
  TWinControl(Msg.LParam).SetFocus;
end;

procedure TDemoForm.TabbedNotebookChange(Sender: TObject; NewTab: Integer;
  var AllowChange: Boolean);
begin
  case NewTab of
    0: PostMessage(Handle, UM_SETFOCUS, 0, Integer(Edit1));
    1: PostMessage(Handle, UM_SETFOCUS, 0, Integer(Edit3));
  end;
end;

Freundliche Grüße

[naudoc]

Hi,

funktionieren tut es jetzt :hello: :hello: :thumb: :thumb:

Aber warum genau... :wiejetzt: :gruebel: ?? Kannst du mir das knapp und verständlich erklären?

[marabu]

Hallo,

wir können ein Fenster (Edit1 o.ä.) erst fokusieren, wenn es auch sichtbar ist. Da wir kein Ereignis haben, welches NACH einem Seitenwechsel im TabbedNoteBook ausgelöst wird, müssten wir eigentlich öfter mal nachschauen, ob es inzwischen soweit ist.

Ich habe mich von folgender Überlegung leiten lassen: Die Ausführung des Codes für das Ereignis OnChange() ist Teil des eigentlichen Seitenwechsels und das Programm bekommt die Kontrolle erst zurück, wenn der Seitenwechsel vollständig abgeschlossen ist. Wenn ich eine Nachricht in die Warteschlange einstelle, so wird sie also erst ausgeführt, wenn das fragliche Edit-Fenster bereits sichtbar ist. Meine Nachricht wird automatisch zum richtigen Zeitpunkt ausgeführt und kann die VCL-Methode SetFocus() verwenden, so dass Nebenwirkungen ausgeschlossen sind.

Freundliche Grüße

[naudoc]

Das Prinzip verstehe ich jetzt, nur den Code nicht, naja, hauptsache, ich versteh die Theorie, für die Praxis müsste ich zu viele Befehle lernen... :coder2:

;)

Danke!

Max