Panel mit Label dynamisch erzeugen

[hans ditter]

Hallo liebe DP,
ich bin's nochmal, diesmal mit 'ner anderen Frage...

Ich schreibe gerade an einem Kontoprogramm, wo man seine Ausgaben und Einnahmen eintrage kann, seinen Kontostand etc. sieht. Ich möchte nun in der unteren Hälfte der Form ein Bereich machen, in dem Panels angezeigt werden, auf denen wiederum versch. Labels angezeigt werden.
Allerdings müssen die Panels ja während der Laufzeit erzeugt werden.
Wie ich EIN Panel dynamisch erzeuge, ist mir klar, aber wie ich ein Panel, auf dem noch mehrere Labels sind, während der Laufzeit erzeuge, weiß ich nicht.
Ach ja, dass ist vlt noch wichtig: Die Panels sollen logischerweise alle gleich aussehen, also soll immer das gleiche Panel mit anderem Namen eingefügt werden.

LG, hans ditter

[mkinzler]

-Erzeugung des Panels
-Erzeugung der Labels mit Panel als Owner + Parent

[himitsu]

Zitat:

Zitat von mkinzler (Beitrag 1038174)

-Erzeugung des Panels
-Erzeugung der Labels mit Panel als Owner + Parent

oder du schaust dir mal Frames an (also statt des Panel ein Frame)

oder man erstellt sich eine neue Komponente (von TPanel abgeleitet, welches in seinem Constructor die Labels erstellt

oder
oder
oder

[mkinzler]

-Oder den gleichen und tauscht nur die Inhalte aus
-PageControl mit ausgeblendeten Tabs
...

[hans ditter]

wozu würdet ihr mir denn raten? Ich bin noch relativ neu bei Delphi.
(persöhnlich würde ich ja gerne mal ausprobieren, eine neue Komponente zu erstellen... aber das stell ich mir schwierig vor)

[DeddyH]

Obwohl ich selbst noch nie damit gearbeitet habe denke ich, Frames dürften das Einfachste sein.

[stahli]

Hallo Hans,

soooo schwierig ist es eigentlich nicht, eine Komponente zu erstellen.
Ich habe selbst als erstes ein rotes Panel erstellt und war ganz stolz :-)

Ich glaube nur, mit dem Turbo Delphi kannst Du keine eigenen Komponenten in die Palette aufnehmen. Du könntest aber zur Laufzeit problemlos DEINE Komponente erzeugen, die dann gleich Labels o.ä. beinhaltet.

Mein Tipp: Versuche erst mal ein farbiges Panel (ein Tutorial wird sich finden), dann hast Du schon mal das Prinzip fertig. Dann die Farbe wieder weg und statt dessen ein paar Labels drauf...

Wirst sehen, das macht Spaß :-)

[hans ditter]

@ stahli Hm, ich will ja keinem zu nahe treten und korrigiere mich, falls ich falsch liege, aber kann man ein Panel nicht mit den Standardfarben über die Caption Color färben?

Auf jeden Fall erstmal ein großen Dank an alle, werd mal die versch. Ideen durchprobieren.

Liebe Grüße, hans ditter

[stahli]

Hallo,

nein, das macht doch nichts ;-)

Es ist schon ein Unterschied, ob man eine Eigenschaft eines Objekts ändert oder ob man ein eigenes Objekt ableitet.

Du würdest dann eben zur Laufzeit: NewPanel := TMyRedPanel.Create(Self)
schreiben.

Und das wäre eben ein NEUES und EIGENES Objekt, abgeleitet eben von TPanel.
Den Constructor des Objekts würde man dann in der Form überschreiben:

Delphi-Quellcode:

  TMyRedPanel = class(TPanel)
  private
  protected
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
  end;

...

constructor TMyRedPanel.Create(AOwner: TComponent);
begin
  inherited;
  Color := clRed;
end;

destructor TMyRedPanel.Destroy;
begin
  inherited;
end;

Und schon hast Du eine eigene Komponente mit "neuen" Eigenschaften. Zumindest wird das Prinzip schon mal erkennbar.
Normalerweise kann man nun die neue Komponente registrieren und in die Komponentenpalette aufnehmen - das dürfte aber mit Deiner Delphi-Version nicht gehen, denke ich.

Im nächsten Schritt kannst Du dann die Farbe (war ja nur zum testen) wieder entfernen und Deine Labels einbinden:

Delphi-Quellcode:

  TMyPanel = class(TPanel)
  private
  protected
  public
    Label1: TLabel;
    Label2: TLabel;
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
  end;

...

constructor TMyPanel.Create(AOwner: TComponent);
begin
  inherited;
  Label1 := TLabel.Create(Self);
  Label1.Parent := Self;
  Label1.Align := alTop;
  Label2 := TLabel.Create(Self);
  Label2.Parent := Self;
  Label2.Align := alBottom;
end;

destructor TMyPanel.Destroy;
begin
  inherited;
end;

Der neuen Komponente kann man dann natürlich auch noch wunderbar Eigenschaften und Methoden zuweisen.
So könnte man z.B. den Zugriff zu den Labels von außen verhindern und dafür bestimmte Eigenschaften zur Verfügung stellen, z.B. CaptionTop und CaptionBottom.
Dann kann der Benutzer direkt diese Eigenschaften (ggf. sogar im Objektinspektor) setzen.

Also es lohnt sich durchaus, sich das mal etwas anzuschauen...

[Chemiker]

Hallo hans ditter,

was man auch benutzen kann ist ein Komponenten-Template.
Damit es relativ einfach eine neue Komponente zu erschaffen ohne viel Quelltext. Jedenfalls siehe ich das bei Standard-Komponenten die nicht allzu viele Sondereigenschaften haben einer neuen abgeleiteten Komponente vor.

Allerdings ist mir nicht bekannt ob das bei den Turbos auch geht, bei dem BDS 2006 ist es dabei.

Bis bald Chemiker

[Hansa]

Zitat:

Zitat von hans ditter (Beitrag 1038171)

Allerdings müssen die Panels ja während der Laufzeit erzeugt werden.
Wie ich EIN Panel dynamisch erzeuge, ist mir klar, aber wie ich ein Panel, auf dem noch mehrere Labels sind, während der Laufzeit erzeuge, weiß ich nicht.

Ist doch kein grosses Problem :

Delphi-Quellcode:

procedure TForm2.btn1Click(Sender: TObject);
var i,x,y : Integer;
    NewPanel : TPanel;
begin
   x := 0;
   y := 0;
  for i := 0 TO 9 do begin
    NewPanel := TPanel.Create (Self);
    NewPanel.Name := 'art' + IntToStr(i);
    NewPanel.Color := clYellow;
    NewPanel.Caption := IntToStr(i);
    if (i > 0) then begin
      if (i mod 5) <> 0 then begin
        x := x + 60;
      end
      else begin
        x := 0;
        y := y + 60;
      end;
    end;
    NewPanel.Left := x;
    NewPanel.Top := y;
    NewPanel.Width := 60;
    NewPanel.Height := 60;
    NewPanel.OnMouseDown := MouseDown;
    NewPanel.Parent := Form2;
    NewPanel.Show;
  end;
end;

Das wären die Panele. Jedes braucht jetzt noch ein Label ? Dann noch das hier hintendran hängen.

Delphi-Quellcode:

    NewLabel.Caption := **;
    NewLabel.Font.Style := [fsBold];
    NewLabel.Parent := NewPanel;

[hans ditter]

Hi alle zusammen. Ich hatte heute erstmal mit dem Frame angefangen, aber Stahli hat bei mir das Feuer wieder entfacht... :D :feuerchen:

Ich hab allerdings schon ein paar Fragen, die, hoffe ich, nicht alzu blöd sind.

Zitat:

constructor Create(AOwner: TComponent); override;

Warum ist der Owner TComponent?

Zitat:

inherited;

was besagt dies? inherited = vererbt... :glaskugel:
und zu inherited hab ich noch eine Frage: ich hab im INet ein Tut gefunden und der schreibt beim Constructor

Zitat:

inherited Create(AOwner)

und beim Destructor

Zitat:

inherited Destroy

... ist das egal, wie ich das schreibe oder ist da ein Unterschied?

[mkinzler]

Zitat:

Warum ist der Owner TComponent?

In dieser Klasse sind die notwendigen Eigenschaften/Funktionalitäten implementiert

Zitat:

Zitat:

inherited;

was besagt dies? inherited = vererbt... :glaskugel:

Es soll eine Methode der Superklasse aufgerufen werden. Wird keine angegeben, wird die Methode mit selben Namen und selber Signatur genommen.

Zitat:

und zu inherited hab ich noch eine Frage: ich hab im INet ein Tut gefunden und der schreibt beim Constructor

Zitat:

inherited Create(AOwner)

und beim Destructor

Zitat:

inherited Destroy

... ist das egal, wie ich das schreibe oder ist da ein Unterschied?

[/QUOTE]
Hier wird explizit gesagt das das geerbte Create mit dem Parameter AOwner genommen werden soll. Destroy hat keine Parameter.

[himitsu]

Inherited besagt, daß man eine Funktion/Procedur aus der Elternklasse aufrufen will.
- Beim Constructor und Destruktor muß/sollte man dieses machen, damit auch die Felder der Elternklassen initialisiert und freigegeben werden.
- Und in diesem Fall ist es doch so, daß hier gleichnamige Funktionen vorliegen (einmal das Create in deiner Klasse und dann das/die Create in den Klassenvorfahren)
und irgendwie muß man dem Compiler ja mittteilen, welche Version man aufrufen möchte ... standardmäßig wird ja immer die letzte Version (also die in deiner eigenen Klasse Deklarierte) verwendet/aufgerufen ... und mit Inherited davor dann die aus dem Vorfahren.

Wenn praktisch irgendwelche Funktionen in deiner Klasse überschrieben/verdeckt wurden, dann kannst du so die "originalen" Funktionen im Vorfahren aufrufen:

Delphi-Quellcode:

inherited Procedurname(Parameter, Parameter2, ...);
inherited Procedurname(Parameter);
inherited Procedurname;
// genauso bei Constructor und Destructor

Result := inherited Funktionsname(Parameter, Parameter2, ...);
Result := inherited Funktionsname(Parameter);
Result := inherited Funktionsname;

Wenn sich aber der Name und der Parametersatz des aufzurufenen Funktion mit der der aufrufenen Funktion gleichen, dann kann man auch "alles" weglassen und nur Inherited angeben.

Delphi-Quellcode:

inherited;  // genauso bei Constructor und Destructor

Result := inherited;

Wenn also dein eigener Constructor genauso aufgebaut ist, wie einer eines Vorfahren, dann reicht ein einfaches Inherited ... also solange du nicht eigene Parameter hinzugefügt hast.

[hans ditter]

Hier mal der gesamte Code von meiner Komponente, aber irgendwie funktioniert die nicht so, wie ich will.
1.) Bei der Funktion

Code:

Str(ini.ReadFloat [I]etc.[/I]

sagt Delphi, dass der linken Seite nix zuzuordnen ist...
2.)Dann sagt Delphi auch noch in mehreren Fällen, dass auf die Funktion "Brush" hier nicht zugegriffen werden kann. Ich wollte aber das Panel rot bzw. grün färben lassen, wie mach ich das dann, wenn nicht so?

Hoffe irgendwer kann mir nochmal helfen... LG, hans ditter

Delphi-Quellcode:

unit Panel1;

interface

uses
  SysUtils, Classes, Controls, ExtCtrls, StdCtrls, Graphics, IniFiles;

type
  TLabeledPanel = class(TPanel)
  private
    FLabelDatum: TLabel;
    FLabelKurzbeschreibung: TLabel;
    FLabelKategorie: TLabel;
    FLabelBetrag: TLabel;
    FLabelESign: TLabel;
    FImage: TImage;
    { Private-Deklarationen }
  protected
    { Protected-Deklarationen }
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    procedure Fuellen(ID: string);
    { Public-Deklarationen }
  published
    { Published-Deklarationen }
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TLabeledPanel]);
end;

constructor TLabeledPanel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);

  //alle Labels erstellen und Eigenschaften der Labels einstellen

  FLabelDatum:=TLabel.Create(Self);
    FLabelDatum.Parent:=Self;
    FLabelDatum.Width:=56;
    FLabelDatum.Left:=128;
    FLabelDatum.Top:=5;
    FLabelDatum.Caption:='';
  FLabelKurzbeschreibung:=TLabel.Create(Self);
    FLabelKurzbeschreibung.Parent:=Self;
    FLabelKurzbeschreibung.Width:=180;
    FLabelKurzbeschreibung.Top:=24;
    FLabelKurzbeschreibung.Left:=4;
    FLabelKurzbeschreibung.Caption:='';
  FLabelKategorie:=TLabel.Create(Self);
    FLabelKategorie.Parent:=Self;
    FLabelKategorie.Width:=180;
    FLabelKategorie.Top:=43;
    FLabelKategorie.Left:=4;
    FLabelKategorie.Caption:='';
  FLabelBetrag:=TLabel.Create(Self);
    FLabelBetrag.Parent:=Self;
    FLabelBetrag.Width:=60;
    FLabelBetrag.Top:=62;
    FLabelBetrag.Left:=124;
    FLabelBetrag.Caption:='';
  FLabelESign:=TLabel.Create(Self);
    FLabelESign.Parent:=Self;
    FLabelESign.Top:=62;
    FLabelESign.Left:=186;
  FImage:=TImage.Create(Self);
    FImage.Parent:=Self;
    FImage.Left:=5;
    FImage.Top:=62;
end;

destructor TLabeledPanel.Destroy;
begin

  //alle Labels wieder freigeben

  FLabelDatum.Free;
  FLabelKurzbeschreibung.Free;
  FLabelKategorie.Free;
  FLabelBetrag.Free;
  FImage.Free;
  inherited Destroy;
end;

procedure TLabeledPanel.Fuellen(ID: String);
var ini: TIniFile;
begin
  ini:=TIniFile.Create(ExtractFilePath(ParamStr(0)) + 'kontoinfo.ini');
  (*Die Labels befüllen; Werte werden aus der Ini 'kontoinfo.ini' mittels dem übergebenen
    Wert in 'ID'*)
  try
    FLabelDatum.Caption:=DateToStr(ini.ReadDate('ID',ID,0));
    FLabelKurzbeschreibung.Caption:=ini.ReadString('Kurzbeschreibung',ID,'0');
    FLabelKategorie.Caption:=ini.ReadString('Kategorie',ID,'0');
    Str(ini.ReadFloat('Betrag',ID,0):9:2,FLabelBetrag.Caption);
      if ini.ReadInteger('Art',ID,-1) = 0 then
        TLabeledPanel.Brush.Color:=cllime
      else
        TLabeledPanel.Brush.Color:=clred
  finally
    ini.Free;
  end;
end;

end.

[DeddyH]

Versuch es mal so (ungetestet):

Delphi-Quellcode:

procedure TLabeledPanel.Fuellen(ID: String);
var ini: TIniFile;
    s: string; 
begin
  ini:=TIniFile.Create(ExtractFilePath(ParamStr(0)) + 'kontoinfo.ini');
  (*Die Labels befüllen; Werte werden aus der Ini 'kontoinfo.ini' mittels dem übergebenen
    Wert in 'ID'*)
  try
    FLabelDatum.Caption:=DateToStr(ini.ReadDate('ID',ID,0));
    FLabelKurzbeschreibung.Caption:=ini.ReadString('Kurzbeschreibung',ID,'0');
    FLabelKategorie.Caption:=ini.ReadString('Kategorie',ID,'0');
    Str(ini.ReadFloat('Betrag',ID,0):9:2,s);  //Das letzte ist ein Var-Parameter
    FLabelBetrag.Caption := s;
    if ini.ReadInteger('Art',ID,-1) = 0 then
      Canvas.Brush.Color:=cllime              //Setzen der Farbe der Zeichenfläche
    else
      Canvas.Brush.Color:=clred;
    Invalidate;  //neu zeichnen lassen
  finally
    ini.Free;
  end;
end;

[hans ditter]

hallo DeddyH...
danke für deinen Vorschlag, ich hab ihn gleich mal probiert, was du vorgeschlagen hast. Aber weder in der Unit meiner Komponente noch während der Laufzeit funktioniert das. Ich hatte auch nochmal versucht, wenn die Komponente createt wird, sie einzufärben, hat aber leider auch nicht geklappt.

Hat noch jmd eine Idee?

[DeddyH]

Na dann einfach mal Color setzen (ohne Brush oder Canvas).

Delphi-Quellcode:

if ini.ReadInteger('Art',ID,-1) = 0 then
  Color:=cllime //Setzen der Farbe
else
  Color:=clred;

[Hawkeye219]

Hallo,

beim Panel sollte man den Wert der Eigenschaft ParentBackground noch auf False abändern.

Gruß Hawkeye

[DeddyH]

Richtig, da war sowas, ich kam nur nicht mehr drauf :mrgreen:

[hans ditter]

@ DeddyH nur Color setzten hat geholfen und dafür brauchte ich auch...
@ Hawkeye ... nicht ParentBackground auf false setzten...

Trotzdem vielen Dank an euch beide :D

[hans ditter]

nun war es in dieser Frage ja seit einiger Zeit wieder ruhig... jetzt hab ich aber mal wieder ein Frage.
Wie ich (glaube bzw. hoffe ich ;)) schonmal erwähnte, schreibe ich gerade an einem Kontoprogramm. Dabei sollen nun mehrer Konten möglich sein. Dafür möchte ich eine Art Tableiste am oberen Rand anbringen, mit der man dann das Konto auswählen kann.
Allerdings hat Delphi soooo eine große Auswahl und ich so wenig Ahnung von Tableisten, dass ich mal einen Rat brauche, welche ich am besten nehmen sollte und wie ich die jetzt am Besten nachträglich in das Projekt einbinde, denn das Anzeigen eines Kontos steht schon... jetzt soll halt nur noch ausgewählt werden, welche Information da angezeigt werden, und dass mittels der Tableiste.

Hoffe ihr versteht mein Problem, freue mich schon auf die vielen hilfreichen Antworten!

hans ditter

[DeddyH]

Kannst Du den Begriff "Tableiste" ein wenig präzisieren? Meinst Du ein Control mit mehreren Reitern? Dann schau Dir doch einmal TPageControl näher an.

[hans ditter]

ja, genau, sowas in der Art suche ich, allerdings muss ich das in ein fertiges Projekt einfach einfügen können. Kann ich da die Komponenten dann einfach raufkopieren oder wie sähe das dann aus?
Vor allem hab ich die Befürchtung, dass dann diese Panels, die während der Laufezeit createt werden, nicht mehr dahin kommen, wo sie hinsollen. Ich vermute, dass ich da dann den Code umschreiben muss... und, naja, das wollte ich wenn möglich verhindern.

[DeddyH]

IIRC liegen die Komponenten ja bereits auf einem Panel. Dieses Panel musst Du dann einfach auf das TabSheet setzen (Parent-Eigenschaft). Allerdings würde ich Dir dringend empfehlen, bei soviel dynamisch erzeugten Controls FastMM einzuschalten, da man gerne einmal einen Fehler bei der Freigabe von Ressourcen macht (aus eigener Erfahrung).

[himitsu]

bezüglich Speicherleck und dynamisch erzeugten Komponenten:
http://www.delphipraxis.net/153654-s...ml#post1041239

FastMM muß sowas nicht unbedingt mitbekommen.

[DeddyH]

Aber schaden kann es trotzdem nicht, oder?

[himitsu]

Zitat:

Zitat von DeddyH (Beitrag 1041452)

Aber schaden kann es trotzdem nicht, oder?

nee, das nicht ... wollte damit nur ausdrücken, daß FastMM keine eierlegende Wollmilchsau ist ... es kann nicht alles finden (aber Einiges).

[DeddyH]

Wenn ich Millionen Instanzen einer Klasse erzeuge und mir damit den Speicher vollhaue, kann FastMM auch nichts mehr machen, klar. Aber wenn ich mir z.B. eine Listenklasse definiere, die Objekte verwaltet, die wiederum selbst Unterobjekte erzeugen, bin ich froh, wenn FastMM mir meldet, ob der ganze Kladderadatsch auch wieder sauber entsorgt wird bzw. in welchen Fällen eben nicht. Darauf wollte ich eigentlich hinaus.

[himitsu]

Es müssen keine Millionen sein.

Probier es einfach mal aus ... egal welchen Button du drückst und danach die (Haupt)Form schließt, die 100 Forms der Schleife werden niemals gemeldet.

Delphi-Quellcode:

procedure TForm5.Button1Click(Sender: TObject);
var i: Integer;
begin
  System.ReportMemoryLeaksOnShutdown := True;
  for i := 1 to 100 do TForm5.Create(Self);
end;

procedure TForm5.Button2Click(Sender: TObject);
var i: Integer;
begin
  System.ReportMemoryLeaksOnShutdown := True;
  for i := 1 to 100 do TForm5.Create(Self);
  TForm5.Create(nil);
end;

[DeddyH]

Die sollten ja auch vom Owner freigegeben werden, oder hab ich was übersehen?

[himitsu]

Zitat:

Zitat von DeddyH (Beitrag 1041466)

Die sollten ja auch vom Owner freigegeben werden, oder hab ich was übersehen?

Jupp, aber dennoch ist es, wärend der Existenz des Owners, bzw. wärend das Programm läuft, ein "Speicherleck", auch wenn es dann "zu spät" gschlossen wird.
Und genau das ist auch der Grund, warum FastMM dieses niemals mitbekommt.
z.B. in einen Timer ist sowas nicht sehr optimal untergebracht.

[DeddyH]

Immerhin werden die ja noch beseitigt (wenn auch spät). Mir geht es darum, aufzuspüren, welche Objekte auch nach Programmende noch im Speicher kleben, weil ich irgendwo eine Freigabe übersehen habe.

[mkinzler]

Das kann man umgehen, wenn man den richtigen Owner setzt.

[DeddyH]

Ich rede jetzt nicht unbedingt von Komponenten, meine Klassen haben ja nicht zwangsgerade einen Owner.

[mkinzler]

Hier geht es aber um welche :zwinker:.
Sonst würde man ja eher eine besitzende Obejktliste verwenden

[DeddyH]

OK, wir schweifen langsam ab. Ich wollte ja nur mal FastMM in den Raum werfen :zwinker:

[himitsu]

@

Zitat:

Zitat von DeddyH (Beitrag 1041471)

Mir geht es darum, aufzuspüren, welche Objekte auch nach Programmende noch im Speicher kleben, weil ich irgendwo eine Freigabe übersehen habe.

Wozu? Windows räumt dann doch eh alles auf. :zwinker:

Für mich ist es egal wann ein "Speicherleck" existiert, denn es können Beide arge Probleme bereiten.

Und abgesehn davon könntest du deinen Klassen doch einen Owner mitgeben ... [sarkasmus] dann brauchst'e dich niewieder um Speicherlecks zu sorgen und diese selber abschaffen [/sarkasmus].

[hans ditter]

also, erstmal vielen Dank, dass mit der Parenteigenschaft probier ich mal aus.
Ich hätte aber gleich nochmal eine Frage. Das Programm braucht zwei Forms. Also einmal zeigt es dein Kontostand, und einmal deine Arbeitstzeit(ganz einfach gesagt). Beides soll sozusagen als Hauptfenster erscheinen. Da ich nichts gefunden hab, wie man die Hauptform eines Projekts ändern kann, dachte ich mir, ich mach die Hauptform (Form1) einfach unsichtbar und zeige dann die 2. Form an. Wenn ich jetzt aber zurück auf Form1 gehen möchte, soll ja Form2 geschlossen werden.
Und hier kommt mein Problem: Ich möchte dem Nutzer aber auch die Möglichkeit lassen, das Programm mit der x-Taste in Form2 zu beenden.
Da hab ich jetzt einfach vollgendes geschrieben:

Delphi-Quellcode:

procedure TForm2.Close;
begin
Form1.Visible;
Form1.Close;
end;

Allerdings wird Form2 ja auch geschlossen, wenn man die Ansicht wieder auf Form1 setzt. In diesem Fall wird Form2 geschlossen, und damit auch zwangsweise Form1.
Wie kann ich das umgehen? Also wie unterscheide ich, ob jemand auf Ansicht wechseln klickt oder auf das Kreuz oben?

Vielen Dank für die große Hilfe,
hans ditter

P.S.: Übrigens, die OT-Diskussion war sehr interessant :zwinker:, da muss ich nämlich wirklich nochmal nachprüfen... :D

[DeddyH]

Zitat:

Zitat von hans ditter (Beitrag 1042110)

Da ich nichts gefunden hab, wie man die Hauptform eines Projekts ändern kann, ...

Einfach in den Projektoptionen oder direkt im Projektquelltext das gewünschte Formular an die erste Stelle der Erstellungsreihenfolge setzen.