Komponenten auf dem Panel durchlaufen???

[romber]

Hallo!

Ich habe auf einem TPanel mehrere CheckBoxen, jedem ist ein Tag > 0 zugewiesen. Nun muss ich Tags von gecheckten Boxen auslesen. Wie kann ich in einer Schleife alle CheckBoxen durchlaufen, ohne dass ich nach und nach den Wert jeder CheckBox auslese???

Danke!

[Hansa]

Wie soll denn das gehen ? Das hier :

Zitat:

Zitat von romber (Beitrag 1049090)

Wie kann ich in einer Schleife alle CheckBoxen durchlaufen, ohne dass ich nach und nach den Wert jeder CheckBox auslese???

:shock: Das wird wohl nur so gehen :

Delphi-Quellcode:

Pseudo-Code :
for i := 0 to ComponentCount do begin
  if CheckBox.IsChecked then
    TueWas;
...
end;

[haentschman]

Hallo...

FindComponent dürfte hier dein Freund sein :hi:

[romber]

Zitat:

Zitat von haentschman (Beitrag 1049094)

FindComponent[/OH][/B] dürfte hier dein Freund sein :hi:

Bei FindComponent muss ich doch auch jede Komponente mit dem namen suchen. Genau so könnte ich doch auch auf jede Komponente einzeln zugereifen und Status abfragen, oder?

[haentschman]

nun ja, mit FindComponent findes du nur die CheckBoxen z.B.
Mit Components hast du alle Komponenten. ComponentCount ist die Summe aller Komponenten. Wenn die Checkboxen durchnummeriert sind kannst du das ganze in einer Schleife ablaufen lassen. Siehe Beispiele: Beispiele ganz unten

[Uwe Raabe]

Delphi-Quellcode:

procedure TForm51.Button1Click(Sender: TObject);
var
  chk: TCheckBox;
  I: Integer;
begin
  for I := 0 to Panel1.ControlCount - 1 do begin
    if Panel1.Controls[I] is TCheckBox then begin
      chk := TCheckBox(Panel1.Controls[I]);
      if chk.Checked then begin
        TueWasMit(chk.Tag);
      end;
    end;
  end;
end;

[haentschman]

... auch ne Variante 8-)

[Hansa]

Glaube, Haentschman hat sich etwas vertan. Mit FindComponent kriegt man ja nur EIN Steuerelement. Je nachdem, was auf dem Panel alles drauf ist, dann nützt das wohl nicht viel ? :shock:

Habe allerdings noch was vergessen :

Delphi-Quellcode:

Pseudo-Code :
for i := 0 to ComponentCount do begin
  if Control IS TCheckBox then   // <--------------------------------
    if CheckBox.IsChecked then
      TueWas;
...
end;

Jetzt lese aber auch mal selber in der Hilfe nach den gelieferten Stichworten. 8-) Mir fällt aber noch gerade auf, dass mein Vorschlag so auch nicht so einfach geht, es sei denn die Checkboxen sind nur auf dem Panel und sonstwo auf der Form sind keine. Ah, roter Kasten. Ja, so wie Uwe Raabe das gemacht hat. So müsste das doch gehen. Dann müsste man aber wohl den Checkboxen explizit sagen, dass das Panel Parent ist ? :gruebel: Es ist immer dasselbe. Bei näherem Hinsehen ist doch alles komplizierter, als anfangs gedacht. :mrgreen:

[Satty67]

Er könnte auch allen CheckBoxen das gleiche Click-Ereignis zuweisen und darin ein TrueFalse-Array pflegen. Listen-Index = Tag

Die Liste kann er dann als property publizieren, falls das ganze in einem Dialog für ein MainForm abläuft.

[Uwe Raabe]

Achtung - quer gedacht: Mann kann auch jeder CheckBox eine Action zuweisen, die alle in derselben ActionList liegen. Dann iteriert man durch die ActionList und das war's.

Hat nebenbei noch den Vorteil, daß man die Checked-Property im OnUpdate-Event aktualisieren kann.

Die Actions können übrigens alle die gleichen Event-Handler haben, da man ja immer noch das Tag zur Unterscheidung hat.

Kommt natürlich alles auf die Anwendung an...

[haentschman]

Zitat:

Glaube, Haentschman hat sich etwas vertan. Mit FindComponent kriegt man ja nur EIN Steuerelement

...nicht ganz. Wenn deine Checkboxen nummeriert sind kannst du das in einer Schleife ablaufen lassen. Wobei ich aber die Variante von Uwe im Nachhinein bevorzugen würde (Control as TCheckbox) und über den Index blättern.

...in diesem Sinne :hi:

[romber]

Vielen Dank an alle! :cheers: Das mit dem ControlCount ist genau das, was ich suchte!!!

[Hansa]

@romber : langsam. Lese das hier mal noch durch.

@haentschman :
Ach so meinst Du das. Na klar, habe ich letztens auch so ähnlich gemacht. Muss wohl doch noch im Quelltext wühlen. :mrgreen: Noch ein paar Denkanstösse aus der Praxis :

Zuerst mal die "Haentschman-Methode" :

Delphi-Quellcode:

for i := 1 to 15 do
  TEdit (FindComponent ('lblIntEdit'+IntToStr(i))).Text := '';
...
for i := 1 to 15 do begin
  lblKomp := TEdit (FindComponent ('lblIntEdit'+IntToStr(i))).Text;
  gesamt := gesamt + StrToInt (lblKomp) * GeldTyp [i];

Zum Verständnis : das stammt jetzt aus einem Geldzähl-Programmteil. Die Leute verzählen sich immer und sollen deshalb lediglich die Anzahl an Münzen/Scheinen eingeben. Das wird dann alles zusammengerechnet. Es gibt eben genau 15 Sorten. Deshalb passt da for-Schleife und FindComponent gut. Wie Haaentschman vorschlägt, sind die Edits da durchnummeriert. Das ist aber nicht mal so wichtig. Wichtiger ist der Prefix "lblIntEdit". Ich könnte da ruhig noch mehr Edits haben, die mit der Geldzählung gar nichts zu tun haben. Solange ich darauf achte, dass die nicht auch mit lblIntEdit anfangen, dann läuft alles wie gewünscht. Ich will damit sagen, dass der Name an sich wichtiger ist, als die Nummerierung. Durch geschickte Namenswahl kann man leicht alles so eingrenzen, wie gewünscht. Das wäre jetzt eine Sache ohne IS / AS.

Hier soll nur gewissen Panelen ein OnClick zugewiesen werden :

Delphi-Quellcode:

case Key of
  13 : begin
         c := FindComponent (pnlName);
         if (c is TMenuPanel) then
           (c as MenuPanel).OnClick (self); // Bei Return Click simulieren
       end;

Geht in dem Fall einfacher, weil TMenuPanel eigene Komponente ist. Die "normalen" Panele bleiben von dem Verhalten unberührt, weil das IS die ausschliesst. Weiterer Vorteil : mit den paar Zeilen ist sichergestellt, dass alle TMenuPanele gleich behandelt werden.

Dann noch das :

Delphi-Quellcode:

for i := 0 to ComponentCount - 1 do begin
  c := Components [i];
  if c is TMenuPanel then
    CompNames.AddObject((c as TMenuPanel).Caption, c);
end;
CompNames.Sort;

Das ist ungefähr das, was ich anfangs meinte. Da gehe ich jetzt wirklich alle Controls der Form durch. Was ist da jetzt der Sinn ? Es gibt da Menüpunkte als Panele. Die kann man direkt anklicken. Es geht um eine Touchscreen-Application. Nun gibts aber Leute, die wollen lieber die Maus benutzen zusammen mit Pulldown-Menu. Auf der Form steht nun in den Panelen : 1 Menüpunkt 1 2 Menüpunkt 2 so in der Richtung. Da hängt noch eine Stringliste hintendran. Und diese wird sortiert. Mit Hilfe der sortierten Liste baue ich dann per Programm das Menu auf. Und genau in der Reihenfolge der Panele auf dem Screen stehen sie auch als Menüpunkt zur Verfügung. Was wäre das eine Arbeit gewesen, ca. 100-300 solcher Panele auch als Menüpunkt auf diversen Forms zu haben (per Menüdesigner). Ausserdem gilt so ja automatisch : Panel weg, Menüeintrag weg, immer alles schön synchron.

Mir fällt gerade ein : auch für einfachere Fälle eignet sich das mit der Stringliste. Muss ja nicht sortiert sein, aber wenn etwas nur mit einer Gruppe an Edits, Panelen, Labels etc. gemacht werden muss, dann einfach die entsprechenden Namen in die Stringliste packen. Dann käme wieder FindComponent im Spiel und damit eben die Stringliste durchgehen.

[romber]

@Hansa

Interessant. Danke!!!
Ich bin gerade dabei, alle mögliche Varianten zu probieren. Aber auf meinen Panel sind wirklich nur die CheckBox-Elemente drauf, deren Status ich auch abfragen möchte. Das heisst, ich brauche doch gar nicht erst sicher gehen, dass ein CheckBox ein bestimmtes Namenszusatz hat. Ich muss nur jedes Element auf dem Panel als CheckBox identifizieren und Status abfragen.

[Hansa]

Zitat:

Zitat von romber (Beitrag 1049153)

Das heisst, ich brauche doch gar nicht erst sicher gehen, dass ein CheckBox ein bestimmtes Namenszusatz hat. Ich muss nur jedes Element auf dem Panel als CheckBox identifizieren und Status abfragen.

So isset, mit is. Der längere Beitrag bezog sich auch eher auf ähnliche Fragen, quasi als Zusammenstellung. Nicht direkt auf Deine Frage. Oder zum verlinken, falls ähnliche Frage wieder auftaucht. Es kommen ja sowieso immer dieselben. :mrgreen: Weiter gehts : ComponentCount bezieht sich auf die Form. Also alles, was da drauf ist läuft da mit. Mit is lässt sich das jetzt zwar auf die Checkboxen eingrenzen, aber wehe es gibt noch welche ausserhalb des Panels. Eventuell könnte man da aber dann die Sache mit den Namen neu aufrollen. 8-) Und bei mehreren Panels, tja, dann müsste man sich die Sache von Uwe Raabe genauer ansehen bzw. testen.

[DeddyH]

FindComponent innerhalb von Schleifen ist allerdings ein ziemlicher Performance-Killer, da diese Funktion intern bereits über die Controls iteriert. Von daher ist die Variante von Uwe Raabe vorzuziehen.

[Hawkeye219]

Hallo,

wer häufiger über bestimmte Controls in einem Container iterieren muss, der kann über den Einsatz eines Enumerators (Delphi 2005+) nachdenken. Die Schnittstelle der Klasse könnte dabei so aussehen:

Delphi-Quellcode:

type
  TControlsEnumerator = class
  public
    constructor Create (const aContainer: TWinControl);
    destructor Destroy; override;
    function GetEnumerator: TControlsEnumerator; inline;
    function withClass (const aClassFilter: TControlClass): TControlsEnumerator; inline;
    function named (const aNameFilter: string): TControlsEnumerator; inline;
    function recursive: TControlsEnumerator; inline;
    function sortedByName: TControlsEnumerator; inline;
    function MoveNext: Boolean;
    function GetCurrent: TControl; inline;
    property Current: TControl read GetCurrent;
  end;

function ContainedControls (const aContainer: TWinControl): TControlsEnumerator;

Bei Verwendung des Enumerators erhält man in der Anwendung einen relativ lesbaren Quelltext:

Delphi-Quellcode:

procedure TDemoForm.TestButtonClick (Sender: TObject);
var
  C: TControl;
begin
  for C in ContainedControls(Panel1).withClass(TCheckBox) do
    if TCheckBox(C).Checked then
      Memo.Lines.Add (IntToStr(C.Tag));

  for C in ContainedControls(Self).recursive.sortedByName do
    Memo.Lines.Add (C.Name);

  for C in ContainedControls(Panel1).withClass(TCheckBox).named('*box*') do
    TCheckBox(C).Checked := not TCheckBox(C).Checked;
end;

Die angehängte Unit verwendet die VCL-Unit Masks, welche bis einschließlich Delphi 2010 einige Fehler enthält. Zur Unterstützung von Stringvergleichen mit Wildcards gibt es aber auch in der DP Alternativen.

Gruß Hawkeye