USB-Stick - Seriennummer/Produktname auslesen

[Rabe]

Hi all,

ich lasse mir gerade ein Muster eines USB-Stick mit eigener Seriennummer / Produktname anfertigen.

Wie kann ich mit D2010 diese Werte auslesen?
Das scheint nicht trivial zu sein, denn meine bisherigen Fundstellen enden meist im "...dann weiss ich es auch nicht"

Viele Grüße
Rabe

[Assarbad]

Zitat:

Zitat von Rabe (Beitrag 1063556)

Wie kann ich mit D2010 diese Werte auslesen?
Das scheint nicht trivial zu sein, denn meine bisherigen Fundstellen enden meist im "...dann weiss ich es auch nicht"

Sind die Werte denn auch im "elektronischen" Teil des Sticks verfügbar?

Der Configuration Manager (CM) dürfte die Funktionen bieten, vermutlich zusammen mit der Setup API. Aber ein wenig genauer mußt du schon werden wenn du eine qualifizierte Antwort haben willst :zwinker:

[Rabe]

Zitat:

Zitat von Assarbad (Beitrag 1063557)

Sind die Werte denn auch im "elektronischen" Teil des Sticks verfügbar?

Was immer Du damit meinst... Ist mir nicht klar.

Zitat:

Zitat von Assarbad (Beitrag 1063557)

Aber ein wenig genauer mußt du schon werden wenn du eine qualifizierte Antwort haben willst :zwinker:

Naja - wenn Du die Website gesehen hast, weisst Du genau soviel wie ich. Wie so oft - Rest ist Forschung.

Rabe

[shmia]

Also ich würde es mit der API-Funktion GetVolumeInformation versuchen.
http://www.delphi-library.de/topic_N...ln_9434,0.html

[Assarbad]

Zitat:

Zitat von Rabe (Beitrag 1063558)

Was immer Du damit meinst... Ist mir nicht klar.

Eine aufgedruckte Seriennummer ließe sich schlecht auslesen.

Zitat:

Zitat von Rabe (Beitrag 1063558)

Naja - wenn Du die Website gesehen hast, weisst Du genau soviel wie ich. Wie so oft - Rest ist Forschung.

Für diesen Fall mußt du die Geräte im Prinzip listen und dann das mit deinem Gerätenamen selber ermitteln. Aber deine Beschreibung (und zugegebenermaßen die auf der verlinkten Seite) ist etwas vage.

Ganz generell wirst du mit den SetupDi*-Funktionen schon ein ganzes Stück weiter kommen. Melde mich nochmal, wenn keiner schneller ist.

@shmia: GetVolumeInformation ist für den Namen usw. von Partitionen. Er will es für das Gerät soweit ich es verstehe.

[RWarnecke]

Hi,

wenn Du den Stick hast, dann probiere mal mein SystemInfo aus. Das liest einige Werte von einem USB-Stick aus. Wenn das die Werte sind, die Du brauchst kann ich Dir dazu ein paar Links und vielleicht noch ein bisschen Beispielsourcecode geben.

[Assarbad]

Zitat:

Zitat von RWarnecke (Beitrag 1063568)

SystemInfo

URL ist inkorrekt ;)

[himitsu]

Ich vermute mal, daß die da enthaltenen Codes die gewünschte Seriennummer nicht auslesen/anzeigen,
aber vielleicht klappt's ja dennoch.

http://www.delphipraxis.net/72979-kl...-auslesen.html

(wenn's klapp, und sobald ich meine Platte wieder bei mir hab, kann ich dann gern mal die Codes raussuchen)

[Assarbad]

Ich glaube ich belasse es bei theoretischen Einlassungen. Habe soeben versucht mit Delphi 2009 ein kleines (konsolenbasiertes) Beispielprojekt zu erstellen und es crasht bevor es die erste Codezeile (im Debugger) erreicht im Release-Mode. :roll:

Im Debug-Mode crasht "nur" die IDE. Ach wie ist es doch schön mit ausgereifter Technologie zu arbeiten ...

Danke auch nochmals Codegear/Embarcadero! :evil:

Ich merke gerade was ich doch vermißt habe wenn ich immer in MS Visual Studio gearbeitet habe.

Nachtrag: lt. Update-Prüfung sind auch keine Aktualisierungen verfügbar. Wenig überraschend wenn man deren Produktpolitik bedenkt. :kotz:

[Assarbad]

OK, also die Exception im Programm habe ich jetzt mit IDA gefunden, da leider die RS-IDE absolut nicht dazu taugte.

Habe das auch erstmal behoben, aber das erklärt wohl kaum den Crash der IDE bzw. des Debuggers. :wall:

Gleich noch ein paar Fehler in JWA gefunden und behoben.

[Assarbad]

Ein Weg scheint darin zu bestehen direkt in HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Enum\U SB nachzugucken.

WMI ginge auch noch.

Aber ich habe mich für den schon beschriebenen Weg entschieden:

Delphi-Quellcode:

program usbkey;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Windows,
  SetupApi,
  Cfg,
  CfgMgr32;

// From WDK/DDK (ntddstor.h, winioctl.h)
const GUID_DEVINTERFACE_DISK: TGUID = '{53F56307-B6BF-11D0-94F2-00A0C91EFB8B}';

const props : array[0..12] of DWORD = (
  SPDRP_CLASS,
  SPDRP_CLASSGUID,
  SPDRP_DEVICEDESC,
  SPDRP_DRIVER,
  SPDRP_ENUMERATOR_NAME,
  SPDRP_FRIENDLYNAME,
  SPDRP_LOCATION_INFORMATION,
  SPDRP_MFG,
  SPDRP_PHYSICAL_DEVICE_OBJECT_NAME,
  SPDRP_SECURITY_SDS,
  SPDRP_SERVICE,
  SPDRP_UI_NUMBER_DESC_FORMAT,
  SPDRP_UI_NUMBER
  );

function GetDeviceRegProperty(hDevInfo: THandle; const spdevid : TSPDevInfoData; dwProperty: DWORD): String;
var
  dwTemp, dwRequired : DWORD;
begin
  case dwProperty of
  // REG_DWORD
  SPDRP_ADDRESS,
  SPDRP_BUSNUMBER,
  SPDRP_CAPABILITIES,
  SPDRP_CHARACTERISTICS,
  SPDRP_CONFIGFLAGS,
  SPDRP_DEVTYPE,
  SPDRP_INSTALL_STATE,
  SPDRP_UI_NUMBER:
  begin
    if(SetupDiGetDeviceRegistryProperty(hDevInfo, spdevid, dwProperty, PDWORD(nil)^, @dwTemp, sizeof(dwTemp), dwRequired)) then
    begin
      Result := Format('%u (0x%8.8X)', [dwTemp, dwTemp]);
      exit;
    end;
  end;
  // REG_SZ
  SPDRP_CLASS,
  SPDRP_CLASSGUID,
  SPDRP_DEVICEDESC,
  SPDRP_DRIVER,
  SPDRP_ENUMERATOR_NAME,
  SPDRP_FRIENDLYNAME,
  SPDRP_LOCATION_INFORMATION,
  SPDRP_MFG,
  SPDRP_PHYSICAL_DEVICE_OBJECT_NAME,
  SPDRP_SECURITY_SDS,
  SPDRP_SERVICE,
  SPDRP_UI_NUMBER_DESC_FORMAT:
  begin
    // We expect this call to fail
    if(not SetupDiGetDeviceRegistryProperty(hDevInfo, spdevid, dwProperty, PDWORD(nil)^, nil, 0, dwRequired)) then
    begin
      if(ERROR_INSUFFICIENT_BUFFER = GetLastError()) then
      begin
        SetLength(Result, (dwRequired + 1) div sizeof(Char));
        if(SetupDiGetDeviceRegistryProperty(hDevInfo, spdevid, dwProperty, PDWORD(nil)^, PByte(@Result[1]), dwRequired, dwRequired)) then
        begin
          // Result now contains the property string
          exit;
        end;
      end;
    end;
  end
  else
    Result := Format('<unsupported property %u>', [dwProperty]);
    exit;
  end;
  if(ERROR_INVALID_DATA = GetLastError()) then
    Result := ''
  else
    Result := Format('<Win32 error: %u>', [GetLastError()]);
end;

procedure GetDetailedData(hDevInfo : THandle ; dwIdx : DWORD; const spdevid : TSPDevInfoData);
var
  cmret : CONFIGRET;
  ulStatus, ulProblem : DWORD;
  str : String;
  i: Integer;
begin
  cmret := CM_Get_DevNode_Status(ulStatus, ulProblem, spdevid.DevInst, 0);
  // Something went wrong
  if(CR_SUCCESS <> cmret) then
  begin
    // Aaah, it's just that the device isn't plugged in (or otherwise present)
    if(CR_NO_SUCH_DEVNODE <> cmret) then // shut up about non-present devices
      WriteLn('CM_Get_DevNode_Status returned error: ', cmret);
    exit;
  end;
  if(DN_STARTED = (DN_STARTED and ulStatus)) then
  begin
    WriteLn(dwIdx, ' started:');
    for i := Low(props) to High(props) do
    begin
      str := GetDeviceRegProperty(hDevInfo, spdevid, props[i]);
      if(str <> '') then
        WriteLn(Format('%8.8X', [props[i]]), ': ', str);
    end;
  end
end;

procedure ListUsbDisks();
var
  hDevInfo : THandle;
  iErr : Integer;
  spdevid: TSPDevInfoData;
  dwIdx: DWORD;
begin
  hDevInfo := SetupDiGetClassDevs(@GUID_DEVINTERFACE_DISK, nil, 0, DIGCF_DEVICEINTERFACE);
  if(INVALID_HANDLE_VALUE <> hDevInfo) then
  try
    dwIdx := 0;
    iErr := ERROR_SUCCESS;
    repeat
      spdevid.cbSize := sizeof(spdevid);
      if(not SetupDiEnumDeviceInfo(hDevInfo, dwIdx, spdevid)) then
      begin
        iErr := GetLastError();
        if(ERROR_NO_MORE_ITEMS <> iErr) then
        begin
          WriteLn('Error from SetupDiEnumDeviceInterfaces: ', iErr);
          break;
        end;
      end;
      GetDetailedData(hDevInfo, dwIdx, spdevid);
      Inc(dwIdx);
    until (iErr = ERROR_NO_MORE_ITEMS);
  finally
    if(not SetupDiDestroyDeviceInfoList(hDevInfo)) then
      WriteLn('Could not destroy device list: ', GetLastError());
  end
  else
    WriteLn('Could not retrieve list for devices of GUID_DEVINTERFACE_DISK class: ', GetLastError());
end;

begin
  try
    ListUsbDisks();
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.

Download: https://assarbad.net/stuff/!export/usbkey.rar bzw. http://assarbad.net/stuff/!export/usbkey.rar (D2009-Projekt)

Ein paar Details fehlen noch, aber damit haste zumindest erstmal den Anfang.

NB: SetupDiGetDriverInfoDetail oder SetupDiGetDeviceProperty (nur Vista und höher) kannst du vermutlich dann zusätzlich anstrengen wenn es noch mehr Daten sein sollen.

[RWarnecke]

Zitat:

Zitat von Assarbad (Beitrag 1063570)

Zitat:

Zitat von RWarnecke (Beitrag 1063568)

SystemInfo

URL ist inkorrekt ;)

Upps, da ist mir ein kleiner Fehler unterlaufen. :oops: Hier nochmal die richtige Adresse zu SystemInfo.

[papajong]

Ein anderer Weg wäre WMI:

Namespaces root\CIMV2
Class Win32DiskDrive
Property PNPDeviceID

dazu gibt es ein nettes Tool:
http://theroadtodelphi.wordpress.com...-code-creator/

[Rabe]

Vielen Dank für die vielen Tipps.

Der Dienstleister hat mitgeteilt, dass der Stick heute raus ist. Am WE werde ich mich also mal daran setzen und die Varianten testen. Ergebnis wird in jedem Fall hier eingetragen.

Viele Grüße
Rabe

[Assarbad]

Guck auch mal hier: http://scp.assarbad.net/dsource/index.htm ( speziell http://scp.assarbad.net/dsource/testusb.rar ).