Too stupid to execute and wait

[QuickAndDirty]

Hallo,
ich bin zu doof einen Prozess zu aus der Anwendung zu startetn und zu warten bis er beendet ist.
Ich nutze eine modifizierte Version aus der Code lib von EexecAndWait um den Prozess auf zu rufen...aber es ging auch vor den Modifizierungen nicht habe die eingebaut um herauszufinden was da passiert...bzw. um das Ergebniss zu verbessern...erfolglos!

Das verhalten ist wie folgt...
der Prozessstartet und hängt dann! Er wird von WaitforSingleObject scheinbar blockiert. Weiter als bis zum Splahscreen kommt er nicht. Erst wenn ich den startenden prozess beende läuft der gestartetet Prozess durch. Das ist nicht das Verhalten was ich mir wünsche.
Hier der Code zum starten und warten.

Das Programm heißt SFX.exe

Delphi-Quellcode:

function ExecAndWait(Filename, Params: string; WindowState: word = SW_SHOWNORMAL): boolean;
var
  ShExecInfo: SHELLEXECUTEINFO;
  r : Cardinal;
  const
  SEE_MASK_NOASYNC= $100;
begin
  Result := false;
  if Filename = '' then
    exit;
  if not FileExists(FileName) then
  Begin
    ShowMessage('Datei nicht existent!');
    Exit;
  End;
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := application.MainFormHandle; //GetForegroundWindow;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOA);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  Result := ShellExecuteEx(@ShExecInfo);

  try
    if Result then
      r := WaitForSingleObject(ShExecInfo.hProcess, INFINITE)
    else
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
                   #13#10'System Fehler: ' + SysErrorMessage(GetLastError));
  finally
    CloseHandle(ShExecInfo.hProcess);
  end;
end;

Der Funktionsaufruf

Delphi-Quellcode:

ExecAndWait(inspath+'\SETUP.EXE','');

Das aufgerufene Programm ist ein Setup.exe ^^
sieht so aus.

Delphi-Quellcode:

program Setup;

uses
  dialogs,
  SysUtils,
  Forms, fmainf;

{$R *.RES}

begin
  SplashForm := TSplashForm.Create(Application);
  SplashForm.Show;
  SplashForm.Update;
  Application.ProcessMessages;
  Application.Title := 'Setup';
  Application.HelpFile := 'SETUP.chm';//A.R.DB
//Hier würde ein Showmessage noch angezeigt
  Application.CreateForm(TFmainf, Fmainf); // Er kommt nur bis hierhin....dann wartet er auf das ende der sfx.exe....total dämlich
//Hier würde ein Showmessage nicht mehr angezeigt 
  SplashForm.Hide;
  SplashForm.Free;
  Application.Run;
end.

[Luckie]

Der Code ist ja grausam. Willst du uns irgendwie quälen? Der Ressourcenschutzblock sitzt an der falschen Stelle, bei der Fehlerbehandlung hast du mehrfach doppelten Code und mit einem case wäre das ganze wesentlich übersichtlicher.

[QuickAndDirty]

Ich habe die ExecuteAndWait einfach übernommen und dann so lange vergewaltigt bis sie mir sagt warums sie nicht funktioniert....das ist nicht als bleibender Code gedacht....

try finaly kann nicht wo anders hin so weit ich das sehe.

könntest du dennoch was zum thema sagen?

[ChrisE]

Hallo QAD,

ich denke mal du nutzt Delphi > 2007. Wenn das der Fall ist dann solltest du darauf achten, dass du WideString und AnsiString nicht vermischst :-)

Gruß, Chris

[Edit]siehe

Delphi-Quellcode:

ShExecInfoA.lpVerb := 'open';

[/Edit]
[Edit2]
und das ist auch komisch:

Delphi-Quellcode:

ShExecInfoA.lpFile := PChar(AnsiString(Filename));
ShExecInfoA.lpParameters := PChar(AnsiString(Params));
ShExecInfoA.lpDirectory := PChar(AnsiString(ExtractFileDir(Filename)));

Ein WideString z.b FileName wird zu nem AnsiString gecastet und dann wird doch wieder nen PChar draus gemacht und einer Struktur übergeben die Ansi als Index trägt :gruebel:
[/Edit2]

[sirius]

Zitat:

Zitat von QuickAndDirty (Beitrag 1115709)

Hallo,
ich bin zu doof einen Prozess zu aus der Anwendung zu startetn und zu warten bis er beendet ist.

Was heißt denn für dich "warten"? Was soll denn dein eigener Prozess in der Zwischenzeit tun?

Zitat:

der Prozessstartet und hängt dann! Er wird von WaitforSingleObject scheinbar blockiert.

Genau (its not a bug its a feature)! Deswegen heißt die Funktione ja auch ExecuteAndWait

Also, es sieht so aus, als ob alles so geschieht, wie es vom Autor gedacht war. Nur die Frage ist jetzt: Was willst du?

[himitsu]

Zitat:

Delphi-Quellcode:

else if GetLastError = ERROR_FILE_NOT_FOUND then
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
                   #13#10'System Fehler: ERROR_FILE_NOT_FOUND')
    else if GetLastError = ERROR_PATH_NOT_FOUND then
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
               #13#10'System Fehler: ERROR_PATH_NOT_FOUND')
    else if GetLastError = ERROR_DDE_FAIL then
...

Kennst du schon SysErrorMessage oder RaiseLastOSError?

PS: Bei einem dir unbekannten Fehler oder bei neuen Fehler in neueren Windowsen, wird bei dir niemals ein Fehler angezeigt. :shock:


Abgesehn davon ist es bei solchen "Funktionen" nicht schöön, wenn Fehler mit ShowMessage und Co. angezeigt werden,
denn was wäre, wenn ich in meinem Programm solche Fehler über abfangen möchte, ohne daß etwas angezeigt wird? (z.B. ein externes Try-Except, was bei ShowMessage aber nicht geht)

Zitat:

WaitForSingleObject

Schau dir mal Delay in der DP-CodeLib an, damit kann man in der aktiven Methode warten und die restliche GUI läuft dennoch weiter.
Oder man lagert das aktuelle ExecAndWait in einen Thread aus, da bleibt dann nur der Thread "hängen" und der GUI-Thread kann problemlos weiterarbeiten.

[QuickAndDirty]

@Luckie:
Als Goody extra für dich Case of reingebaut...

Ist tatsächlich augenfreundlicher...funktioniert aber auch nicht besser. :(

[QuickAndDirty]

Zitat:

Zitat von himitsu (Beitrag 1115720)

Zitat:

Delphi-Quellcode:

else if GetLastError = ERROR_FILE_NOT_FOUND then
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
                   #13#10'System Fehler: ERROR_FILE_NOT_FOUND')
    else if GetLastError = ERROR_PATH_NOT_FOUND then
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
               #13#10'System Fehler: ERROR_PATH_NOT_FOUND')
    else if GetLastError = ERROR_DDE_FAIL then
...

Kennst du schon SysErrorMessage oder RaiseLastOSError?

PS: Bei einem dir unbekannten Fehler oder bei neuen Fehler in neueren Windowsen, wird bei dir niemals ein Fehler angezeigt. :shock:


Abgesehn davon ist es bei solchen "Funktionen" nicht schöön, wenn Fehler mit ShowMessage und Co. angezeigt werden,
denn was wäre, wenn ich in meinem Programm solche Fehler über abfangen möchte, ohne daß etwas angezeigt wird? (z.B. ein externes Try-Except, was bei ShowMessage aber nicht geht)

Himitsu die Showmessages sind nur zum debuggen ^^

du hast also auch keine Idee warum es nicht geht ja?

[himitsu]

Auch mit SysErrorMessage und Co. kann man debuggen. :roll:

Und siehe mein Edit im letzen Post.

wie schon jemand sagte:
- bei ShExecInfoA, SHELLEXECUTEINFOA und ShellExecuteExA das A weg
- WideString zu String
- die AnsiString-Casts raus

Wer sagt, daß das ForegroundWindow zu deinem Prozess gehört? ... Keiner, also kannst du da doch nicht einfach was dranhängen.

[QuickAndDirty]

Zitat:

Zitat von ChrisE (Beitrag 1115715)

Hallo QAD,

ich denke mal du nutzt Delphi > 2007.

ja 2007.

Zitat:

Zitat von ChrisE (Beitrag 1115715)

Wenn das der Fall ist dann solltest du darauf achten, dass du WideString und AnsiString nicht vermischst :-)

Gruß, Chris

Ok, danke. Habe das korrigiert...
Scheint das problem aber nicht zu beheben kann das sein?

Zitat:

Zitat von ChrisE (Beitrag 1115715)

[Edit]siehe

Delphi-Quellcode:

ShExecInfoA.lpVerb := 'open';

[/Edit]

was ist damit?

[QuickAndDirty]

Zitat:

Zitat von himitsu (Beitrag 1115724)

Auch mit SysErrorMessage und Co. kann man debuggen. :roll:

Und siehe mein Edit im letzen Post.

wie schon jemand sagte:
- bei ShExecInfoA, SHELLEXECUTEINFOA und ShellExecuteExA das A weg
- WideString zu String
- die AnsiString-Casts raus

Wer sagt, daß das ForegroundWindow zu deinem Prozess gehört? ... Keiner, also kannst du da doch nicht einfach was dranhängen.

Ok. wie gesagt habe es kopiert weil ich mal schnell was brauchte... und mit Kommandline programmen ging es auch.

Ich bin in sachen Windows API relativ unbeleckt! Und hoffte eigentlich was fertiges zu finden was einfach einen Prozess startet und wartet bis er fertig ist! Der code hat mit Kommandlinetools auch super hingehauen.
(gsecexe, Isql.exe)

[QuickAndDirty]

Zitat:

Zitat von sirius (Beitrag 1115719)

Zitat:

Zitat von QuickAndDirty (Beitrag 1115709)

Hallo,
ich bin zu doof einen Prozess zu aus der Anwendung zu startetn und zu warten bis er beendet ist.

Was heißt denn für dich "warten"? Was soll denn dein eigener Prozess in der Zwischenzeit tun?

Na nichts? gucken wann er weiter machen darf, er muss nicht mal auf User input reagieren können ...wäre aber schön.

Zitat:

Zitat von sirius (Beitrag 1115719)

Zitat:

der Prozessstartet und hängt dann! Er wird von WaitforSingleObject scheinbar blockiert.

Genau (its not a bug its a feature)! Deswegen heißt die Funktione ja auch ExecuteAndWait

Also, es sieht so aus, als ob alles so geschieht, wie es vom Autor gedacht war. Nur die Frage ist jetzt: Was willst du?

sfx.exe startet Setup.exe und setup.exe hängt dann im splashscreen und sfx.exe hängt im Waitforsingleobject. (Ein deadlock)
Ich will das NUR sfx.exe im Waitforsingleobject hängt aber nicht setup.exe im splashscreen.

[QuickAndDirty]

Änderungen eingebaut...wie zu erwarten selbes problem...
änderungen im startpost veröffentlicht.


WaitForSingleObject wartet bis das Prozesshandle ungültig wird oder?

Wieso hängt der überwachte Prozess wenn er überwacht wird?

[Luckie]

Funktioniert wunderbar:

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: Widestring; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFOW;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := GetForegroundWindow;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOW);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PWideChar(Filename);
  ShExecInfo.lpParameters := PWideChar(Params);
  ShExecInfo.lpDirectory := PWideChar(WideString(ExtractFileDir(Filename)));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteExW(@ShExecInfo) then
  begin
    WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '');
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
  ShowMessage('Fertig');
end;

[ChrisE]

Zitat:

Zitat von QuickAndDirty (Beitrag 1115726)

Zitat:

Zitat von ChrisE (Beitrag 1115715)

Hallo QAD,

ich denke mal du nutzt Delphi > 2007.

ja 2007.

Also = 2007 nicht größer --> bei Deiner Entwicklungsumgebung ist AnsiString = String und PChar = PAnsiChar -> somit ein Schönheitsfehler im Code.

Zitat:

Zitat von QuickAndDirty (Beitrag 1115726)

Zitat:

Zitat von ChrisE (Beitrag 1115715)

Wenn das der Fall ist dann solltest du darauf achten, dass du WideString und AnsiString nicht vermischst :-)

Gruß, Chris

Ok, danke. Habe das korrigiert...
Scheint das problem aber nicht zu beheben kann das sein?

OK - siehe oben

Zitat:

Zitat von QuickAndDirty (Beitrag 1115726)

Zitat:

Zitat von ChrisE (Beitrag 1115715)

[Edit]siehe

Delphi-Quellcode:

ShExecInfoA.lpVerb := 'open';

[/Edit]

was ist damit?

Hättest du größer 2007 wäre String = WideString. Das gilt auch für Stringkonstanten wie

Delphi-Quellcode:

'open'

. Diesen WideString würdest du an eine Struktur übergeben die für AnsiString gedacht ist. Das wäre ein potenzieller Fehler.

Warum dein aufgerufenes Programm trotzdem hängt weiß ich nicht. Das ist komisch.

Funktioniert der Code mit notepad - bzw. einem Programm dass du nicht selber geschrieben hast? (siehe Luckie)

Gruß, Chris

[QuickAndDirty]

Zitat:

Zitat von Luckie (Beitrag 1115732)

Funktioniert wunderbar:

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: Widestring; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFOW;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := GetForegroundWindow;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOW);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PWideChar(Filename);
  ShExecInfo.lpParameters := PWideChar(Params);
  ShExecInfo.lpDirectory := PWideChar(WideString(ExtractFileDir(Filename)));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteExW(@ShExecInfo) then
  begin
    WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '');
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
  ShowMessage('Fertig');
end;

Ja mit notepad funktioniert es wunderbar,
mit isql.exe geht es und mit gsec.exe geht es auch

Aber mit meiner setup.exe ist nach dem Splashscreen Schluss.
Warum?

[QuickAndDirty]

Zitat:

Zitat von ChrisE (Beitrag 1115733)

Warum dein aufgerufenes Programm trotzdem hängt weiß ich nicht. Das ist komisch.

sehe ich auch so...

Zitat:

Zitat von ChrisE (Beitrag 1115733)

Funktioniert der Code mit notepad - bzw. einem Programm dass du nicht selber geschrieben hast? (siehe Luckie)

Gruß, Chris

ja mit ISQL.exe, gsec.exe, notepad.exe....

hat jemand ne idee warum er bei setup.exe nur bis zum splashscreen kommt??

[ChrisE]

Zitat:

Zitat von Luckie (Beitrag 1115732)

Funktioniert wunderbar:

Hmm, du mischst aber auch WideString und AnsiString bzw. gibst es nicht explizit an.

Delphi-Quellcode:

  ShExecInfo.lpVerb := 'open';

Ich würde es so versuchen (Deine Sourcen angepasst):

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: string; AHWnd: HWND; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFO;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := AHWnd;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFO);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteExW(@ShExecInfo) then
  begin
    WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '', Self.Handle);
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
  ShowMessage('Fertig');
end;

Zitat:

Zitat von QuickAndDirty (Beitrag 1115734)

Aber mit meiner setup.exe ist nach dem Splashscreen Schluss.
Warum?

Nutzt du Windows Vista / 7? Dann starte sfx.exe mal mit Adminrechten oder benenne setup.exe um in meinprogramm.exe und probier es nochmal.

Gruß, Chris

[Luckie]

Wo mische ich? Ich habe nur Delphi 7 hier, deshalb habe ich ausdrücklich WideStrings benutzt.

[QuickAndDirty]

Zitat:

Zitat von ChrisE (Beitrag 1115736)

Zitat:

Zitat von Luckie (Beitrag 1115732)

Funktioniert wunderbar:

Hmm, du mischst aber auch WideString und AnsiString bzw. gibst es nicht explizit an.

Delphi-Quellcode:

  ShExecInfo.lpVerb := 'open';

Ich würde es so versuchen (Deine Sourcen angepasst):

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: string; AHWnd: HWND; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFO;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := AHWnd;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFO);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteExW(@ShExecInfo) then
  begin
    WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '', Self.Handle);
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
  ShowMessage('Fertig');
end;

Zitat:

Zitat von QuickAndDirty (Beitrag 1115734)

Aber mit meiner setup.exe ist nach dem Splashscreen Schluss.
Warum?

Nutzt du Windows Vista / 7? Dann starte sfx.exe mal mit Adminrechten oder benenne setup.exe um in meinprogramm.exe und probier es nochmal.

Gruß, Chris

Ich nutze 2000, xp, und 7
über all das selbe Verhalten nur das es bei Windows 7 erst mit Adminrechten überhaupt in den Splashscreen kommt.

Ich testete dioe letzen paar minuten hier auf einer Windows 2000 virtuellen maschiene...

[QuickAndDirty]

Zitat:

Zitat von Luckie (Beitrag 1115737)

Wo mische ich? Ich habe nur Delphi 7 hier, deshalb habe ich ausdrücklich WideStrings benutzt.

die windows api ist nicht so einfach mit delphi...
also mit delphi 2007 wäre es ok nur String zu benutzen? weil das schon Widechar ist?


mir wird ungut...

[himitsu]

Zitat:

Zitat von ChrisE (Beitrag 1115736)

Das gilt auch für Stringkonstanten wie 'open' . Diesen WideString würdest du an eine Struktur übergeben die für AnsiString gedacht ist. Das wäre ein potenzieller Fehler.

Nicht ganz.
Stringkonstanten haben erstmal keinen Typ.
Übergibt man sie nun an einen AnsiString- oder PAnsiChar-Parameter, wird dafür eine AnsiString-Konstante eingebunden.
Würde man diesen an WideString-, UnicodeString- oder PWideChar-Parameter oder eben eine Variable übergeben, dann wird dafür eine Unicode-Konstante eingebunden.
Werden beide Parameter/Variablen verwendet, werden zwei Konstanten eingebunden (Ansi und Unicode).

Zitat:

Zitat von QuickAndDirty (Beitrag 1115740)

also mit delphi 2007 wäre es ok nur String zu benutzen? weil das schon Widechar ist?

Nein.

Bis D2007 waren String, Char und PChar auf AnsiString, AnsiChar und PAnsiChar gemapt wurden,
wärend dieses seit D2009 auf UnicodeString (nicht WideString), WideChar und PWideChar zeigt.

[QuickAndDirty]

kann es ein problem sein das GDI+ in der Setup.exe genutzt wird?

msdn sagt:http://msdn.microsoft.com/en-us/library/aa450988.aspx
A thread that uses a wait function with no time-out interval may cause the system to become deadlocked. For example, the Dynamic Data Exchange (DDE) protocol and the COM function CoInitialize both indirectly create windows that can cause a deadlock. Therefore, if you have a thread that creates windows, use MsgWaitForMultipleObjects or MsgWaitForMultipleObjectsEx, rather than WaitForSingleObject.
[/QUOTE]

ist das nicht ein bisschen...extrem krass...

[ChrisE]

Zitat:

Zitat von himitsu (Beitrag 1115741)

Zitat:

Zitat von ChrisE (Beitrag 1115736)

Das gilt auch für Stringkonstanten wie 'open' . Diesen WideString würdest du an eine Struktur übergeben die für AnsiString gedacht ist. Das wäre ein potenzieller Fehler.

Nicht ganz.
Stringkonstanten haben erstmal keinen Typ.
Übergibt man sie nun an einen AnsiString- oder PAnsiChar-Parameter, wird dafür eine AnsiString-Konstante eingebunden.
Würde man diesen an WideString-, UnicodeString- oder PWideChar-Parameter oder eben eine Variable übergeben, dann wird dafür eine Unicode-Konstante eingebunden.
Werden beide Parameter/Variablen verwendet, werden zwei Konstanten eingebunden (Ansi und Unicode)

Cool, wieder was dazu gelernt - THX :thumb:

Zitat:

Zitat von Luckie (Beitrag 1115737)

Wo mische ich? Ich habe nur Delphi 7 hier, deshalb habe ich ausdrücklich WideStrings benutzt.

Damit ahst du nicht mehr gemischt - sorry :-(

Aber meine Codeanpassung hatte auch nicht eine Fehler :-) Ich habe ShellExecuteExW aufgerufen anstatt ShellExecuteEx.

Ich denke nur, dass man auf explizite WideString bzw. AnsiString-Verwendung verzichten sollte wo es geht. Dann funktioniert der Quelltext unter 2007 und >=2009 :-)

Gruß, Chris

[QuickAndDirty]

ja...schön...
der code funktionierte ja ....
in jedem der bisherigen zustände...

nur produziert er eben nen deadlock in einem fall

[ChrisE]

Zitat:

Zitat von QuickAndDirty (Beitrag 1115747)

nur produziert er eben nen deadlock in einem fall

Hast du das Probiert?

Zitat:

Zitat von ChrisE (Beitrag 1115736)

Nutzt du Windows Vista / 7? Dann starte sfx.exe mal mit Adminrechten oder benenne setup.exe um in meinprogramm.exe und probier es nochmal.

Gruß, Chris

[QuickAndDirty]

PROBLEM GELÖST

Delphi-Quellcode:

function ExecAndWait(Filename, Params: string; WindowState: word = SW_SHOWNORMAL): boolean;
var
  ShExecInfo: SHELLEXECUTEINFO;
  r : Cardinal;
  const
  SEE_MASK_NOASYNC= $100;
begin
  Result := false;
  if Filename = '' then
    exit;
  if not FileExists(FileName) then
  Begin
    ShowMessage('Datei nicht existent!');
    Exit;
  End;
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := application.MainFormHandle; //GetForegroundWindow;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOA);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  Result := ShellExecuteEx(@ShExecInfo);


  try
    if Result then
    begin
      repeat
        R := MsgWaitForMultipleObjects(1, ShExecInfo.hProcess, False, INFINITE,QS_ALLINPUT);
        if r <> WAIT_OBJECT_0 then
          Application.ProcessMessages;
      until r = WAIT_OBJECT_0;
    end
    else
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
                   #13#10'System Fehler: ' + SysErrorMessage(GetLastError));
  finally
    CloseHandle(ShExecInfo.hProcess);
  end;
end;

WaitForSingleObject produziert scheinbar wie vorgesehen einen deadlock wenn der aufgerufen prozess ein neues Fenster erzeugt.
Und die msdn hatte recht...(seltsam) mit MsgWaitForMultipleObjects geht es dann trotzdem.

Delphi-Quellcode:

      repeat
        R := MsgWaitForMultipleObjects(1, ShExecInfo.hProcess, False, INFINITE,QS_ALLINPUT);
        if r <> WAIT_OBJECT_0 then
          Application.ProcessMessages;
      until r = WAIT_OBJECT_0;

Und danke für die Code Verschönerungstips, sieht jetzt auch viel übersichtlicher aus!

[Luckie]

Zitat:

Zitat von QuickAndDirty (Beitrag 1115750)

Und danke für die Code Verschönerungstips, sieht jetzt auch viel übersichtlicher aus!

Und warum nutzt du sie nicht und verhunzt den Code wieder? Wozu dieser komische try-finally-Block? Wo erwartest du da eine Exception? Und du hast ja immer noch diese doofe Fehlerbehandlung da drin.

[QuickAndDirty]

Zitat:

Zitat von Luckie (Beitrag 1115751)

Zitat:

Zitat von QuickAndDirty (Beitrag 1115750)

Und danke für die Code Verschönerungstips, sieht jetzt auch viel übersichtlicher aus!

Und warum nutzt du sie nicht und verhunzt den Code wieder? Wozu dieser komische try-finally-Block? Wo erwartest du da eine Exception? Und du hast ja immer noch diese doofe Fehlerbehandlung da drin.

habe eigentlich
die von dir empfohlene

SysErrorMessage

funktion benutzt.

sehr praktisch, danke.

Ich packe Handle Freigaben usw. immer in ein Finally. warum magst du das nicht?

wie würdest du es denn machen?

[Luckie]

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: string; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFO;
  RetValue: DWORD;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := Application.Handle ; //GetForegroundWindow;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFO);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteEx(@ShExecInfo) then
  begin
    repeat
      RetValue := MsgWaitForMultipleObjects(1, ShExecInfo.hProcess, False, INFINITE, QS_ALLINPUT);
      if RetValue <> WAIT_OBJECT_0 then
        Application.ProcessMessages;
    until RetValue = WAIT_OBJECT_0;
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '');
    ShowMessage('Fertig');
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
end;

[himitsu]

Für INFINITE könnte man noch einen ausreichend langen Timeout setzen, damit eventuelle Deadlocks gleich mit abgefangen werden.

[samso]

Ich würde vielleicht noch einmal überdenken, ob die verwendeten Flags wirklich zielführend sind. Vielleicht sollte man ja die folgende Kombination verwenden:

SEE_MASK_NOCLOSEPROCESS or SEE_MASK_WAITFORINPUTIDLE or SEE_MASK_NOZONECHECKS

Dann kann man sich vermutlich auch all dieses Application.ProcessMessages-gefrickel sparen.

[ChrisE]

Hallo,

da seh ich gerade noch:

Delphi-Quellcode:

  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOA);

Hier sollte das A hinten noch weg.
Und dann noch eine Frage zu dem WaitFor:
Sollte man hier nicht auch auf Application.Terminated prüfen? Ist vielleicht eine Glaubensfrage für den Anwendungsfall aber ich würde es machen. Also etwa so:

Delphi-Quellcode:

repeat
RetValue := MsgWaitForMultipleObjects(1, ShExecInfo.hProcess, False, INFINITE, QS_ALLINPUT);
if RetValue <> WAIT_OBJECT_0 then
  Application.ProcessMessages;
until (RetValue = WAIT_OBJECT_0) or Application.Terminated;

Gruß, Chris

[himitsu]

Das ProcessMessages sorgt dafür, das der Thread (Hauptthread) nicht "einschläft"

WAITFORINPUTIDLE wartet "nur" bis das gestartete programm "aufnahmebereit" ist, wärend das MsgWaitFor (ohne MsgWaitFor) auf die komplette Beendigung des Programms wartet.

[QuickAndDirty]

Zitat:

Zitat von himitsu (Beitrag 1115757)

Für INFINITE könnte man noch einen ausreichend langen Timeout setzen, damit eventuelle Deadlocks gleich mit abgefangen werden.

ja aber das setup macht auch updates und die können je nach kunde auch mal 2 tage dauern....
oder hat das damit nichts zu tun?

[QuickAndDirty]

Zitat:

Zitat von samso (Beitrag 1115758)

Ich würde vielleicht noch einmal überdenken, ob die verwendeten Flags wirklich zielführend sind. Vielleicht sollte man ja die folgende Kombination verwenden:

SEE_MASK_NOCLOSEPROCESS or SEE_MASK_WAITFORINPUTIDLE or SEE_MASK_NOZONECHECKS

Dann kann man sich vermutlich auch all dieses Application.ProcessMessages-gefrickel sparen.

ich habe auch so ein paar sorgen...weil ja aus application.processmessages wieder Excpetions kommen können.... je nach dem was da verarbeitet wird.

Aber wieso erspart mir diese flag kombination das ProcessMessages?

[Luckie]

Zitat:

Zitat von ChrisE (Beitrag 1115761)

da seh ich gerade noch:

Delphi-Quellcode:

  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOA);

Hier sollte das A hinten noch weg.

Copy and waste. ;) Ist korrigiert.

[QuickAndDirty]

Noch ne frage

wo wir gerade am tunen sind...

Delphi-Quellcode:

  ShExecInfo.Wnd := application.MainFormHandle;

Oder

Delphi-Quellcode:

  ShExecInfo.Wnd := application.Handle;

Oder

Delphi-Quellcode:

  ShExecInfo.Wnd := GetForegroundWindow;

[QuickAndDirty]

Zitat:

Zitat von Luckie (Beitrag 1115769)

Zitat:

Zitat von ChrisE (Beitrag 1115761)

da seh ich gerade noch:

Delphi-Quellcode:

  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOA);

Hier sollte das A hinten noch weg.

Copy and waste. ;) Ist korrigiert.

dito

[Luckie]

MainFormHandle kannte mein D7 nicht, deswegen nur Handle. Und GetForeGroundWindow ist gefährlich, da dein Programmfenster beim ausführen des Codes nicht das oberste Fenster sein muss.