Canvas.TextOut zentrieren

[Nicodius]

Hallo Leute,

ich würde gerne eine Ausgabe per TextOut auf dem Form zentrieren.

Delphi-Quellcode:

x := Form1.Width div 2 - (Canvas.TextWidth(text) div 2);

kommt bei der Schriftgröße schon einigermaßen hin, aber bei manchen texten hängt es.
Habt ihr da vl eine schöne Lösung oder irgendwelche Parameter die ich hier gebrauchen könnte?

lg Nico

[Nicodius]

sorry alter code

Delphi-Quellcode:

x := round((Form1.Width - Canvas.TextWidth(text)) / 2);

ist der aktuelle. Leider genau das gleiche problem.
canvas.TextOut(round((form1.ClientWidth - canvas.TextWidth('ZENTRIERT')) / 2),200,'ZENTRIERT');
von http://www.delphipraxis.net/2634-tex...usrichten.html
bringt leider nicht das gewünschte ergebnis

EDIT: Das Problem scheint nur bei bold texten zu bestehen. da geht anscheinend die textwidth nicht richtig drauf?

[DeddyH]

IMHO geht das mit DrawText wesentlich einfacher.

[Bummi]

Delphi-Quellcode:

var
 r:TRect;
 s:String;
begin
  r.Left := 0;
  r.Top := 0;
  r.Right := 300;
  r.Bottom := 100;
  s := 'Testtest';
  Canvas.TextRect(r,s,[tfVerticalCenter,tfCenter,tfSingleLine]);
end;

[Nicodius]

Hi! Vielen Dank für eure Antworten,

beide Möglichkeiten scheinen aber Formatierungen wie bold/underline nicht zuzulassen oder?

lg Nico

[stahli]

Du musst vorher Canvas.Font.Style einstellen.

[Nicodius]

Ah schon müde :)
Danke für die Antwort, gerade selber gesehen dass das eh ganz normal über die Canvas lauft.

Vielen Dank erstmal an alle!

lg und einen schönen Abend


Nico

[Nicodius]

@Bummi, das ist leider mit Delphi 7 nicht möglich, da ist die Graphics wohl aufgewertet worden.

[ASM]

Zitat:

Zitat von Nicodius (Beitrag 1141416)

das ist leider mit Delphi 7 nicht möglich, da ist die Graphics wohl aufgewertet worden.

Ja leider. Die Möglichkeit zur Übergabe der Formatierung ist erst in den neueren Delphiversionen durch Overload-Prozeduren vorhanden.

Man kann sich das aber für Delphi 7 leicht selber zusammenbauen:

Code:

procedure TextOutEx(canvas: TCanvas; r: TRect; s: string; Font: TFont = nil);
var
  x, y: integer;
  StringWidthInPixel, StringHeightInPixel: integer;
begin
  if Font <> nil then Canvas.Font := Font;
  StringWidthInPixel := Canvas.Textwidth(s);
  StringHeightInPixel := Canvas.Textheight(s);
  with r do
  begin
    x := (right - left - StringWidthInPixel) div 2;
    y := (bottom - top - StringHeightInPixel) div 2;
  end;
  Canvas.TextOut(x, y, s);
end;

In der Anwendung:

Code:

procedure TForm1.Button1Click(Sender: TObject);
var
  r: TRect;
  Font: TFont;
begin
  // hier ist der Canvas der eines TImage
  r:=Image1.ClientRect;
  // falls benötigt:
  Font := TFont.Create;
  try
    with Font do
    begin
      color := clRed;
      Style := [fsbold, fsItalic];
      size := 14;
    end;
    // oder Font als Parameter weglassen, falls nichts Spezielles gewünscht
    TextOutEx(Image1.canvas, r, 'Test-Test', Font);
  finally
    Font.Free;
  end;
end;

[Nicodius]

Erstens: Vielen Dank für eure Bemühungen.

Hab es jetzt auch mit deiner Methode probiert asm aber leider kommt folgendes heraus(Anhang)

Der Bold Text wird verschoben, da kommt anscheinend das Textwidth nicht zusammen, kann das sein?

lg Nico

[DeddyH]

Also bei mir sieht das hier ganz ordentlich aus:

Delphi-Quellcode:

procedure TFormTest.FormPaint(Sender: TObject);
const
  DRAWFLAGS = DT_SINGLELINE or DT_CENTER or DT_VCENTER;
  YOffset = 35;
var
  s: string;
  R: TRect;
  OldFont: TFont;

  procedure DrawRect;
  begin
    R.Top := R.Top + YOffset;
    R.Bottom := R.Bottom + YOffset;
    DrawText(Canvas.Handle, PChar(s), -1, R, DRAWFLAGS);
  end;

begin
  OldFont := TFont.Create;
  try
    //alten Font sichern
    OldFont.Assign(Canvas.Font);
    R := Rect(0, 0, ClientWidth, YOffset);
    s := 'Erste Zeile';
    DrawRect;
    Canvas.Font.Size := 14;
    Canvas.Font.Style := [fsBold];
    s := 'Zweite Zeile';
    DrawRect;
    Canvas.Font.Size := 12;
    Canvas.Font.Style := [fsBold, fsItalic];
    s := 'Dritte Zeile';
    DrawRect;
    Canvas.Font.Size := 20;
    Canvas.Font.Name := 'Times New Roman';
    Canvas.Font.Style := [fsItalic];
    s := 'Vierte Zeile';
    DrawRect;
    //Gesicherten Font wiederherstellen
    Canvas.Font.Assign(OldFont);
  finally
    OldFont.Free;
  end;
end;

[Nicodius]

Danke DeddyH! Das hat prima funktioniert.

Würde mich trotzdem itneressieren warum das TextWidth mit dem fsbold nicht umgehen kann.

lg Nico

[DeddyH]

Das kann ich aus dem Hut leider auch nicht sagen. Evtl. bringt ein Blick in die Delphi-Sourcen Licht ins Dunkel.

[Bummi]

kann es sein dass Du TextWidth nicht neu berechnen lässt nach der Umstellung auf Bold ?

[FrankJ28]

Vielleicht ein Reihenfolgeproblem,
erst Bold, dann TextWidth setzen?
Ciao
Frank

EDIT: Thomas war schneller

[DeddyH]

Wenn er ASMs Code 1:1 übernommen hat, kann es daran ja eigentlich nicht liegen, da dort der Font erzeugt, übergeben und anschließend ausgewertet wird.

[Nicodius]

Nein wurde zuerst bold gesetzt und dann berechnet. Wirklich seltsam.

[mz23]

Zitat:

Zitat von Nicodius (Beitrag 1141545)

Nein wurde zuerst bold gesetzt und dann berechnet. Wirklich seltsam.

Vielleicht hat der Canvas nicht mehr dieselbe Breite nach dem Style
setzen?!

Nur Vermutung:
Image1.Picture.Graphic.Width := Image1.Width;
Image1.Picture.Graphic.Height := Image1.Height;
neu setzen.

Schöne Grüße aus Nürnberg,
Manfred

[DeddyH]

Wieso Image? Er hat doch direkt auf das Formular gezeichnet.