1-Byte-Char in BDS2010

[LeisureSuitLarry]

Hallo,

ich habe folgendes Problem:

beim Einlesen einer Textdatei mit mehreren Char-Feldern ist die Satzlänge doppelt so hoch. Delpi2010 scheint für ein Char 2 Byte zu verwenden.

Die Projekteinstellungen habe ich angehängt. Gibt es eine Art ShortChar?

Grüße
Manfred

[himitsu]

Nicht nur scheint, sondern es ist so.
Seit Delphi/RAD 2009 ist Unicode der Standard und davor war es ANSI.

Char
AnsiChar
WideChar
PChar
PAnsiChar
PWideChar
String
ShortString
AnsiString
WideString
UnicodeString

BDS? Es heißt jetzt RAD. :wink:

[DeddyH]

Oder anders ausgedrückt:
Delphi bis 2007
- Char = AnsiChar
- PChar = PAnsiChar
- String = AnsiString

Delphi ab 2009
- Char = WideChar
- PChar = PWideChar
- String = UnicodeString

[LeisureSuitLarry]

Danke für die schnellen Antworten.

Wie bekomme ich jetzt Daten eingelesen, die Daten mit fester Feldlänge enthält?

Zum Beispiel:
000001Herr Max Mustermann Testr. 1 12345Musterhausen

Grüße
Manfred

[DeddyH]

Z.B. mit einem Array of AnsiChar oder einem String mit fester Länge (z.B. string[50]), die sind AFAIK immer Ansi.

[LeisureSuitLarry]

Danke.
Die Satzlänge ist leider 361 Zeichen.

[vagtler]

Zitat:

Zitat von LeisureSuitLarry (Beitrag 1153597)

[...] Die Satzlänge ist leider 361 Zeichen.

Äh, ja. Und?

[DeddyH]

Dann nimm doch das Array of AnsiChar, oder deklarier einfach einen AnsiString und kopier da die 361 Zeichen raus (je nachdem, wie Du einliest).

[LeisureSuitLarry]

Einen Ansistring einlesen geht erst mal.
Dummerweise ist die Datei CP850 kodiert.

[DeddyH]

Hilft Dir OemToChar evtl. weiter?

[edit] Oder wohl besser OemToCharBuff, wenn man die Warnung beachtet. [/edit]

[Bummi]

vielleicht willst Du die Funktion LoadFileWithEncoding verwenden ....

Delphi-Quellcode:

unit ConvertCodePage;
// 20120116 by Thomas Wassermann
interface
uses Classes,Sysutils;

Procedure ConverCodePage(Const fn:String; FromCP, ToCP:Integer);
Procedure LoadFileWithEncoding(const fn:String; CodePage:Integer;sl:TStringList);
Procedure SaveFileWithEncoding(const fn:String; CodePage:Integer;sl:TStringList);

implementation

Procedure LoadFileWithEncoding(const fn:String; CodePage:Integer;sl:TStringList);
var
  enc:TEncoding;
begin
   enc := TEncoding.GetEncoding(CodePage);
   try
   sl.LoadFromFile(fn,enc);
   finally
     enc.Free;
   end;
end;

Procedure SaveFileWithEncoding(const fn:String; CodePage:Integer;sl:TStringList);
var
  enc:TEncoding;
begin
   enc := TEncoding.GetEncoding(CodePage);
   try
   sl.SaveToFile(fn,enc);
   finally
     enc.Free;
   end;
end;

Procedure ConverCodePage(Const fn:String; FromCP, ToCP:Integer);
var
 sl : TStringList;
begin
  sl := TStringList.Create;
  LoadFileWithEncoding(fn, FromCP , sl);
  SaveFileWithEncoding(fn, ToCP   , sl);
  sl.Free;
end;


end

[himitsu]

Man kann dem AnsiString auch direkt die CodePage mitgeben, wobei Delphi dann (meistens) die gewünschte CodePage nutzt, wenn es automatisch konvertieren soll.

SetAnsiString

StringElementSize
StringCodePage
StringRefCount
SetCodePage

Es gibt sogar ein

Delphi-Quellcode:

ReadLString(var t: TTextRec; var s: AnsiString; CodePage: Word);

, wobei ich nicht genau weiß, wie man das nutzt.
Theoretisch sollte es eine der internen Funktionen für Read und ReadLn sein.
Eventuell wird es ja automatisch genutzt, wenn man dem StringTyp die Codepage mitgibt, so wie z.B. die Codepage 65001 für den UTF8String.

Delphi-Quellcode:

type
  UTF8String = type AnsiString(65001);
  OEMString  = type AnsiString(850);  // oder = type AnsiString(CP_OEMCP)

[LeisureSuitLarry]

Bummis Vorschlag klingt gut...
Kann aber erst später weiter machen...

Danke für Eure Hilfe!

Grüße
Manfred

[DeddyH]

@Bummi: wieso in Gottes Namen übergibst Du die Listen als Variablenparameter?

[Bummi]

@Deddy
war ein nicht endbereinigter Code, bei dem Ursprünglich wenn nicht assigned Stringlisten erzeugt wurden

[DeddyH]

Das macht in dem Zusammenhang aber auch keinen Sinn, was soll denn dann gespeichert werden? Naja, egal, das "var" weg (und vielleicht TStringlist durch TStrings ersetzen) und gut is ;)

[Iwo Asnet]

Zitat:

Zitat von DeddyH (Beitrag 1153621)

...und gut is ;)

Nen Class Helper draus machen und 'besser' is?

[DeddyH]

Class Helper für welche Klasse?

[vagtler]

Zitat:

Zitat von DeddyH (Beitrag 1153628)

Class Helper für welche Klasse?

Lass mal raten: TStrings? ;)

[DeddyH]

Wenn es sonst niemand macht:

Delphi-Quellcode:

type
  TStringsCodePageHelper = class helper for TStrings
  public
    procedure ConvertFileCodePage(const Filename: string; FromCP, ToCP: Integer);
    procedure LoadFileWithEncoding(const Filename: String; CodePage: Integer);
    procedure SaveFileWithEncoding(const Filename: String; CodePage: Integer);
  end;

procedure TStringsCodePageHelper.ConvertFileCodePage(const Filename: string; FromCP,
  ToCP: Integer);
begin
  LoadFileWithEncoding(Filename, FromCP);
  SaveFileWithEncoding(Filename, ToCP);
end;

procedure TStringsCodePageHelper.LoadFileWithEncoding(const Filename: String;
  CodePage: Integer);
var
  Encoding: TEncoding;
begin
  Encoding := TEncoding.GetEncoding(CodePage);
  try
    LoadFromFile(Filename, Encoding);
  finally
    Encoding.Free;
  end;
end;

procedure TStringsCodePageHelper.SaveFileWithEncoding(const Filename: String;
  CodePage: Integer);
var
  Encoding: TEncoding;
begin
  Encoding := TEncoding.GetEncoding(CodePage);
  try
    SaveToFile(Filename, Encoding);
  finally
    Encoding.Free;
  end;
end;

Vielleicht könnte man künftig den schlauen Worten dann aber auch selbst Taten folgen lassen.

[himitsu]

PS: LoadFromFile kennt noch einen Encoding-Parameter, welchen man vielleicht sogar verwenden könnte.