Datensatz in einer Datenbank kopieren

[philubb]

Hallo

habe eine procedure geschrieben, die einen ausgewählten Datensatz in einer Datenbank kopieren soll. Diese wird per Klick auf einen Button aufgerufen.

Code entspricht in etwa diesem hier von USER shmia:

http://www.delphipraxis.net/17291-ak...plizieren.html

Nun zu meinem Problem:

Immer wenn ich die beiden letzten Zeilen

aDataSet.Append; <- Funktioniert noch
aDataSet.SetFields(aRecord); <- kommt Exception

aufrufe kommt eine Exception: "ClientDataSet: Datenmenge weder im Einfüge - noch im Editiermodus"

Wenn ich den Button direkt danach nochmal klicke, funktioniert es plötzlich.

Jemand eine Idee woran das liegt?

Hab keine Lust andauernd den Aufruf doppelt machen zu müssen.

[Blup]

Versuch mal direkt AppendRecord, AutoInc-Felder müssen mit Variants.NULL gefüllt werden.

[philubb]

Danke für die schnelle Antwort.

An AppendRecord hab ich auch schon gedacht.

Aber ich verwende schon ganz bewusst Append, weil hierbei die Datenmenge nach dem einfügen im Editmodus bleibt, damit der Anwender die kopierten Daten kontrolliert, gegebenfalls ändert und dann erst bestätigt, dass der Datensatz hinzugefügt wird.

Benutze ich nun AppendRecord, wird nach dem hinzufügen, gleich ein POST gesendet und der Anwender kann den Datensatz nicht mehr bearbeiten.

[Furtbichler]

Zitat:

Zitat von philubb (Beitrag 1172612)

...Code entspricht in etwa diesem hier von USER shmia:

'In etwa' klingt schon mal verdächtig.

Zeige mal deinen Code.

[jobo]

Zitat:

Zitat von philubb (Beitrag 1172617)

Aber ich verwende schon ganz bewusst Append, weil hierbei die Datenmenge nach dem einfügen im Editmodus bleibt

Wahrscheinlich hast Du Dir da schon die Antwort gegeben.
Setz doch selbst den Editmodus, bevor Du Daten änderst.

[philubb]

hier mein code:

Aufruf einfach per OnClickEvent eines Buttons.

Delphi-Quellcode:

procedure TFormMain.Kopieren(aDataSet:TDataSet);
var
  Data : array of Variant;
  aRecord : array of TVarRec;
  i : integer;
  max : integer;
begin

  max := 8;
  SetLength(arecord,max+1);
  SetLength(data,max+1);

  for i := 0 to max do
  begin
    arecord[i].VType := vtVariant;
    arecord[i].VVariant := @data[i];
  end;

  Data[1] := aDataSet.FieldValues['BESCHREIBUNG'];
  Data[2] := aDataSet.FieldValues['NENNSTROM'];
  Data[3] := aDataSet.FieldValues['NENNSPANNUNG'];      //Felder die ich kopieren möchte, andere bleiben leer;
  Data[4] := aDataSet.FieldValues['HZ'];
  Data[5] := aDataSet.FieldValues['DREHM_ZAHL'];
  Data[6] := aDataSet.FieldValues['KAUFPREIS'];
  Data[7] := aDataSet.FieldValues['PRIORITAET'];
  Data[8] := aDataSet.FieldValues['BESTELL_NR'];


  aDataSet.Append;
  aDataSet.SetFields(aRecord);

end;

[DeddyH]

Abgesehen von der Bereichsüberschreitung (Indizes von 1 bis 8 statt von 0 bis 7) kann ich da nichts Falsches entdecken.

[Uwe Raabe]

Zitat:

Zitat von philubb (Beitrag 1172649)

Delphi-Quellcode:

  Data[1] := aDataSet.FieldValues['BESCHREIBUNG'];
  Data[2] := aDataSet.FieldValues['NENNSTROM'];
  Data[3] := aDataSet.FieldValues['NENNSPANNUNG'];      //Felder die ich kopieren möchte, andere bleiben leer;
  Data[4] := aDataSet.FieldValues['HZ'];
  Data[5] := aDataSet.FieldValues['DREHM_ZAHL'];
  Data[6] := aDataSet.FieldValues['KAUFPREIS'];
  Data[7] := aDataSet.FieldValues['PRIORITAET'];
  Data[8] := aDataSet.FieldValues['BESTELL_NR'];


  aDataSet.Append;
  aDataSet.SetFields(aRecord);

1. DeddyH hat ja schon angemerkt, daß der Index von Data von 0..7 und nicht von 1..8 geht.
2. Du erwähnst im Kommentar zu Data[3] "Felder die ich kopieren möchte, andere bleiben leer;". Woher soll SetFields denn wissen, welche Felder es mit den Daten des Variant-Arrays setzen soll? SetFields geht davon aus, daß das Array Daten für alle Felder in der richtigen Reihenfolge enthält. Willst du nur einzelne Felder befüllen, dann musst du jedes Feld einzeln setzen.

[philubb]

1.INDEX:

Setze ich den INDEX von 0 - 7 bekomme ich eine EBcdException: "Test hge (//Wert in Feld "Beschreibung") ist kein gültiger BCD-Wert"

Wenn ich den Index von 1 - 8 setze, kommt diese Meldung nicht, sondern nur die vom Anfang :)


2.Felder:

Es sind schon die richtigen Felder. Diese sind auch in dieser Reihenfolge vorhanden.
Die Felder die leer bleiben sollen, kommen nach denen die ich kopieren möchte.

Oder muss ich das so verstehen, dass SetFields alle Felder belegt, auch wenn ich nur ein paar angebe?

[philubb]

Habe mich jetzt für folgende Lösung entschieden.

Habe um die letzten beiden Zeilen ein TRY ... EXCEPT Block gemacht und rufe im EXCEPT Teil nochmal beide auf
Ist zwar nicht ganz sauber, aber es funktioniert zumindest so wie es soll :roll:

[mkinzler]

Warum nicht per SQL?

[shmia]

Zitat:

Zitat von philubb (Beitrag 1172612)

Code entspricht in etwa diesem hier von USER shmia:
http://www.delphipraxis.net/17291-ak...plizieren.html

Was gefällt Dir denn an meinem Code nicht?
Die Procedure

Delphi-Quellcode:

DuplicateCurrentRecord()

ist sauber und fehlerfrei.
Sie ist so konstruiert, dass dem Programmierer nach dem Duplizieren eines Datensatzes alle Wege offenstehen.

[philubb]

gefallen tut sie mir schon.

ich wollte nur nicht alle felder kopieren, sondern nur ein paar ausgewählte.
deshalb hab ich mur manche sachen bei dir abgeschaut

[shmia]

Zitat:

Zitat von philubb (Beitrag 1172679)

ich wollte nur nicht alle felder kopieren, sondern nur ein paar ausgewählte.

Du hast ja die Möglichkeit nach dem Kopieren aller Felder bestimmte Felder wieder zu löschen:

Delphi-Quellcode:

// alle Felder löschen die in der Liste übergeben wurden
procedure ClearDbFields(ds:TDataset; feldliste:array of string);
var
   i : Integer;
   f : TField;
begin
   for i:=Low(feldliste) to High(feldliste) do
   begin
      f := ds.FindField(feldliste[i]);
      if Assigned(f) then
         f.Clear;   // Set Field to NULL
   end;
end;

Auf jeden Fall macht es Sinn deine Anforderung durch Benutzung von "Basisfunktionen" zu lösen, als nur eine Funktion zu haben, die Alles macht.

Delphi-Quellcode:

DuplicateCurrentRecord(aDataset);  // zuerst alles kopieren
ClearDbFields(aDataset, ['Feld1', 'Feld2']); // dann das Löschen was nicht erwünscht ist

Du kannst auch das Property Tag verwenden, um zwischen erwünschten und unerwünschten Feldern zu unterscheiden:

Delphi-Quellcode:

procedure ClearTaggedDbFields(ds:TDataset; mask:integer);
var
   i : Integer;
   f : TField;
begin
   for i:=0 to ds.fields.Count-1 do
   begin
      f := ds.fields[i];
      if (f.Tag and mask) <> 0 then
         f.Clear;
   end;
end;

Auf jeden Fall sind die hier gezeigten Funktionen wiederverwendbar und können so für jede Tabelle benützt werden.

[mschaefer]

Da SQL in der Datenbankangabe steht, könnte es auch sein, dass folgendes über eine abgesetzte Query geht:

Code:

Select * into employee_backup from employee

Grüße in die Runde

Martin

[Furtbichler]

Es geht doch eher darum, einen einzelnen Datensatz zu kopieren

[mschaefer]

In der Tat, der Vorschlag ist updatefähig, z. B. mit folgendem Schnipsel:

Code:

 var V:Variant; 
     i:integer; 
 begin 
       with Query1 do 
       begin 
         if (not Active)or(isEmpty) then exit;
         // Variant Array aufbauen 
         V := VarArrayCreate([0,FieldCount-1], varVariant); 
         for i:=0 to FieldCount-1 
         do 
           // Für alle Felder die Beschreibbar sind hole Werte ins Array
           if (not Fields[i].ReadOnly)
               and(Fields[i].FieldName <> KeyFieldName) 
               then V[i]:=Fields[i].Value; 
           // Leeren Datensatz in Memory anlegen
           Insert; 
           // Wo Werte im Array sind, diese in die Felder eintragen
           for i:=0 to FieldCount-1 do 
             if (not Fields[i].ReadOnly) 
           then Fields[i].Value := V[i]; 
           // schreiben, eventuell auch später
           post;
         end; 
 end;

Grüße in die Runde // Martin

[philubb]

Hauptächlich ist ja das Problem, dass ich die Funktionen 2x aufrufen muss, bis sie richtig funktioniert.

Sonst bekomme ich die genannte Exception.

Mir ist aufgefallen, dass die Exception meistens eintritt, wenn ich einen Datensatz in der Mitte der Tabelle auswähle. Mit dem letzten angezeigten Datensatz ist das kein Problem. Hat das vielleicht dann etwas mit den Einstellungen der CDS oder so zu tun?

[Iwo Asnet]

Wenn Du in einem Event den Datensatzzeiger veränderst, dann passiert genau das: Obskurer und sporadischer Verlust des Einfügemodus.

Ich würde mir eine kleines Projekt bauen, das das Problem beschreibt, also z.B.:
1x Form, 1x Button (zum Start des Tests) 1x CDS, 1x Beispieldaten. Von mir aus noch ne Datasource und ein Grid, damit man die Daten sieht.

Im Click-Event des Buttons dann der Code, der den aktuellen Record ans Ende dupliziert. Sonst nix! Probieren.

Gehts? Aha, liegt der Fehler wohl woanders.
Geht nicht? Dann stell dein Projekt hier rein und andere sehen, ob sie das reproduzieren können oder einen robusten Workaround parat haben.

Wenn Du alle Probleme, bei denen Du nicht sofort weiterkommst, mit der Holzfällermethode umgehst, na denn 'Gute Nacht'.

Mein Versuch wäre:

Delphi-Quellcode:

Procedure DuplicateRecord(aDS : TDataset);
Var
  Data : Array Of Variant;
  I : Integer;

Begin
  SetLength (Data, aDS.FieldCount);
  For i:=0 to aDS.FieldCount - 1 do 
    Data[i] := aDS.Fields[i].Value;
  aDS.Append;
  For i:=0 to aDS.FieldCount - 1 do 
    If CanCopyField(aDS.Fields[i]) then 
      aDS.Fields[i].Value := Data[i];
  aDS.Post;
End;

Wenn Das nicht geht, liegst am CDS (glaube ich nicht) oder an erwähnten Seiteneffekten (Events, OnCalcField etc.)
Ja, der Code ist fast identisch mit dem von mschaefer. Hab ich eben erst gemerkt.

[philubb]

habe die lösung gefunden :)

hab in der DataSource beim OnStateChange ein SetFocus gemacht und deshalb ist er immer wieder rausgesprungen :oops:

aber noch vielen dank für die hilfe!!:thumb:

[Furtbichler]

Zitat:

Zitat von Iwo Asnet (Beitrag 1172841)

Wenn Du in einem Event den Datensatzzeiger veränderst, dann passiert genau das: Obskurer und sporadischer Verlust des Einfügemodus.

Also das.