Mehrdimensionalles Dynamisches Array Kopieren.

[Lombok]

Moin,

Ist es möglich ein Mehrdimensionalles Dynamisches(2 Dimensionen)Array was in den Spalten ungleich ist 1 zu 1 mithilfe von Copy zu kopieren?

Ich will nur wissen ob es geht nicht wie.

[mkinzler]

Ja. Copy() funktioniert auch bei dyn. Arrays

[Lombok]

Auch bei wie gesagt Mehrdimensionallen die ungleich sind in den Spalten?

[mkinzler]

Copy kopiert einfach nur den Speicherbereich. Wenn sich das Zielarray signifikant vom quellarray unterscheidet, kommt natürlich Müll raus.

9x9 -> 10x9 OK
9x9 -> 9x10 Müll

[p80286]

Für den unwahrscheinlichen Fall, daß doch jemand fragt wie es geht:

Zitat:

Copy Routine

Gibt einen Teilstring eines Strings oder ein Segment eines dynamischen Arrays zurück.

Unit
System

Syntax


[Delphi] function Copy(S: string; Index: Integer; Count: Integer): string;


Beschreibung
S ist ein Ausdruck des Typs String oder dynamisches Array. Index und Count sind Integer-Ausdrücke. Copy gibt einen Teilstring oder ein Teilarray zurück, das Count Zeichen oder Elemente ab S[Index] enthält. Der Teilsstring oder das Teilarray ist eine eindeutige Kopie (d.h., Speicher wird nicht gemeinsam mit S genutzt, obwohl Zeiger- oder Objekt-Elemente des Arrays nicht kopiert werden).

Ist Index größer als die Länge von S, gibt Copy einen leeren String oder ein leeres Array zurück.

Gibt Count mehr Zeichen oder Array-Elemente an, als verfügbar sind, werden nur die Zeichen oder Elemente von S[Index] bis zum Ende von S zurückgegeben.
Hinweis:
Wenn S ein dynamisches Array ist, brauchen Sie die Parameter Index und Count nicht anzugeben. Copy kopiert dann das gesamte Array.

[mkinzler]

Das funktioniert aber nur wenn das Speicherlayout von Quelle und Ziel kompatibel sind.

[Peter1999]

NEIN!

Copy kopiert immer nur EINE Dimension!
Wenn man ein mehrdimensionales Array mit Copy kopiert erhält man also nur eine Kopie der Zeiger auf die 2. Dimension.
Folglich bewirkt eine Änderung der Werte in der Kopie auch eine Änderung der Werte im Original!

Um das mehrdimensionale Array zu kopieren musst du dich über eine Schleife und alle Dimensionen durcharbeiten!

Delphi-Quellcode:

var a,b: array of array of Integer;

begin
  setlength(a,5,5);
  a[2,2] := 5;
  b := copy(a);
  a[2,2] := 9;
  b[3,3] := 3;

  showmessage(inttostr(a[3,3])); // --> 3
  showmessage(inttostr(b[2,2])); // --> 9


end;

[p80286]

Zitat:

Zitat von mkinzler (Beitrag 1206410)

Das funktioniert aber nur wenn das Speicherlayout von Quelle und Ziel kompatibel sind.

[korinthenmodus an]
funktionieren sollte es immer, wenn genügend Speicher da ist. Es soll sogar Leute geben, die unterschiedliche Layouts nutzen um die Daten anders zu interpretieren. Aber es ging ja nur um das "ob"
[korintenmodus aus]

Gruß
K-H

[Lombok]

Also ist es jetzt nicht möglich so ein Array:

1 O O O
2 O O
3 O O O O O

(Zahlen Zeilen)
(O = Werte der Spalten)

1 zu 1 nur mithilfe von Copy zu Kopieren?

[Bummi]

Delphi-Quellcode:

Type
TARR=Array of Array Of Array of String;

procedure TForm1.Button1Click(Sender: TObject);
var
 a,b:TArr;
 i,j,k:Integer;
begin
  SetLength(a,10);
  for I := 0 to High(a) do
    begin
    SetLength(a[i],i+1);
    for j := 0 to High(a[i]) do
      begin
       SetLength(a[i][j],j+1);
       for k := 0 to High(a[i][j]) do a[i][j][k] := Format('%d - %d - %d',[i,j,k]);
      end;
    end;

  b := Copy(a,0,Length(a));


  for I := 0 to High(a) do
    begin
    SetLength(a[i],i+1);
    for j := 0 to High(a[i]) do
      begin
       SetLength(a[i][j],j+1);
       for k := 0 to High(a[i][j]) do a[i][j][k] := '';
      end;
    end;
 SetLength(a,0);


  for I := 0 to High(b) do
    begin
    for j := 0 to High(b[i]) do
      begin
       for k := 0 to High(b[i][j]) do
       Memo1.Lines.add(b[i][j][k]);
      end;
    end;


end;

[Lombok]

Ein einfaches Nein hätte gereicht Danke an alle. :D


Bitte Schließen Frage ist beantwortet.

Mfg Lombok.

[Bummi]

@Lombok

Wie kommst Du auf nein? Mein Post war zum nachvollziehen des JA gedacht.

Der Firlefanz

Delphi-Quellcode:

 
  for I := 0 to High(a) do
    begin
    SetLength(a[i],i+1);
    for j := 0 to High(a[i]) do
      begin
       SetLength(a[i][j],j+1);
       for k := 0 to High(a[i][j]) do a[i][j][k] := '';
      end;
    end;
 SetLength(a,0);

zum leeren und zurücksetzen von a war gedacht um den den Effekt der Auftritt wenn man meint durch eine Zuweisung arbeiten zu können (b=a) wo auch erst mal alles richtig aussieht, bis a verändert wird, gegenüberzustellen einer echten Kopie

Delphi-Quellcode:

 b := Copy(a,0,Length(a));

die funktioniert.

[Lombok]

Hi,

Also ich habe 2x Dynamische Array of Byte mit je 2 Dimensionen.

Wenn ich jetzt

Code:

var

KandidatenListen2   : array of array of Byte;
KandidatenListen   : array of array of Byte;
         
KandidatenListen2 := Copy(KandidatenListen,0,Length(KandidatenListen));

eingebe.

Bekomm ich nur die Fehlermeldung das es Inkompatible Typen sind.

Habe es jetzt mit 2 For Schleifen selber gelöst.

Code:

   for i:=0 to (high(kandidatenlisten)) do begin
      SetLength(Kandidatenlisten2,i+1);
         for a:=1 to length(kandidatenlisten[i])do begin
          SetLength(Kandidatenlisten2[i],a);
          KandidatenListen2[i,a-1]:= KandidatenListen[i,a-1];

Ich wollte aber halt wissen ob man das auch mit Copy geht um mir das mal zu ersparen immer mit For Schleifen zu arbeiten.

Deine Syntax die du mir Geschrieben hast funktionierd aber bei mir nicht da kommt wie gesag die oben genannte Fehlermeldung.
Liegt es vieleicht daran das ich Delphi 5 benutze?.

Mfg Lombok.

[Medium]

Code:

type
  TArrayOfArrayOfByte = array of array of Byte;

var
KandidatenListen2   : TArrayOfArrayOfByte;
KandidatenListen   : TArrayOfArrayOfByte;
         
KandidatenListen2 := Copy(KandidatenListen,0,Length(KandidatenListen));

Und schon ist es zuweisungskompatibel. Aus den zwei getrennten array-Deklarationen bei dir macht Delphi intern auch zwei Typen, die für Delphi intern unterschiedlich sind - auch wenn sie es strukturell nicht sind. Mit einer eigenen Typdeklaration definiert man das für den Compiler dann eindeutig.

[Lombok]

Hi,

Ok das wusste Ich nicht. Klingt für mich aber auch erstmal ziemlich seltsam auch wenns am Ende schlüssig ist. Bin da von Java wohl zuviel verwöhnt.

Fürs nächste Mal weiß ich dann Bescheid.
Danke.

[Peter1999]

Einmal musst du die Schleife trotzdem durchlaufen, denn Copy kopiert wie gesagt immer nur eine Dimension auf einmal.

Delphi-Quellcode:

type TIntArr2D = array of array of Integer;


function CopyIARR2D(aIArr: TIntArr2D): TIntArr2D;
var i: Integer;
begin
  Result := copy(aIArr);
  for i := 0 to high(Result) do
    Result[i] := copy(aIArr[i]);
end;

procedure TForm1.Button2Click(Sender: TObject);
var a,b,c,d: TIntArr2D;
begin
  setlength(a,5,5);
  a[2,2] := 5;
  a[3,3] := 1;
  b := copy(a);
  a[2,2] := 9;
  b[3,3] := 3;

  showmessage(inttostr(a[3,3])); // --> 3
  showmessage(inttostr(b[2,2])); // --> 9


//-----------------------------------------------
  setlength(c,5,5);
  c[2,2] := 5;
  c[3,3] := 1;
  d := CopyIArr2D(c);
  c[2,2] := 9;
  d[3,3] := 3;

  showmessage(inttostr(c[3,3])); // --> 1
  showmessage(inttostr(d[2,2])); // --> 5
end;

Andernfalls besteht die Gefahr, dass du dir dein "Orignial" veränderst, wenn du mit der "falschen" Kopie arbeitest, was ein gern gemachter Fehler ist und was man auch gern übersieht.

Viele Grüße...