Stringgrid Spaltenbreite an Fenstergröße anpassen

[BBoy]

Wie kann man verwirklichen damit sich die Spaltenbreite beim Maximieren/Wiederherstellen automatisch anpasst? Selbstverständlich sollte die Spaltenbreite dann realistisch angepasst werden, also nicht das eine Spalte zu groß wird....

[Bummi]

Du könntest StringGrid.Cols[X].Objects als Speicher für einen Prozentwert der Gridbreite verwenden und die Spaltenreiten bei Größenänderung entsprechend berechnen.

[sx2008]

http://www.delphipraxis.net/25365-op...ringgrids.html

[Back2Code]

Ist das auch mit nem DBGrid kompatibel?

[sx2008]

Zitat:

Zitat von Polymorphin (Beitrag 1211946)

Ist das auch mit nem DBGrid kompatibel?

Nein, die gemeinsame Basisklasse von TStringGrid und TDBGrid gibt das leider nicht her.
Ausserdem könnte es beim TDBGrid zu Performanceproblemen kommen, weil man über alle Datensätze gehen müsste um den längsten String in den jeweiligen Spalten zu finden.

[Back2Code]

Zitat:

Zitat von sx2008 (Beitrag 1211950)

Zitat:

Zitat von Polymorphin (Beitrag 1211946)

Ist das auch mit nem DBGrid kompatibel?

Nein, die gemeinsame Basisklasse von TStringGrid und TDBGrid gibt das leider nicht her.
Ausserdem könnte es beim TDBGrid zu Performanceproblemen kommen, weil man über alle Datensätze gehen müsste um den längsten String in den jeweiligen Spalten zu finden.

Gibts hier in der Codelib ne ähnliche Unit nur für's DBGrid? Bin schon seit ner Weile auf der Suche :cyclops:

[Bummi]

Du kannst das ja mal ausprobieren .....

Delphi-Quellcode:

Procedure FitGrid(Grid:TDBGrid);
//bummi 2013 
Const
 C_Add=3;
var
 ds:TDataset;
 bm:TBookmark;
 i:Integer;
 w:Integer;
 a:Array of Integer;
begin
   ds := Grid.DataSource.DataSet;
   if Assigned(ds) then
      begin
        ds.DisableControls;
        bm := ds.GetBookmark;
        try

        ds.First;
        SetLength(a,Grid.Columns.Count);
        ZeroMemory(@a[0],SizeOf(Integer)*Length(a));
        while not ds.Eof do
          begin
            for I := 0 to Grid.Columns.Count - 1 do
                begin
                  if Assigned( Grid.Columns[i].Field) then
                    begin
                     w :=  Grid.Canvas.TextWidth( ds.FieldByName( Grid.Columns[i].Field.FieldName).DisplayText);
                     if a[i] < w  then a[i] := w + C_Add;
                    end;

                end;
            ds.Next;
          end;
        for I := 0 to Grid.Columns.Count - 1 do Grid.Columns[i].Width := a[i];
        ds.GotoBookmark(bm);
        finally
          ds.FreeBookmark(bm);
          ds.EnableControls;
        end;
      end;
end;

procedure TForm1.Button1Click(Sender: TObject);

begin
  FitGrid(DBgrid1)
end;

[BBoy]

Es geht hier nicht darum die Spaltenbreite soweit zu ändern das der gesamte Text darin angezeigt werden kann!

Mein Form ist anfangs klein und das Grid passt perfekt mit den voreingestellten Breiten. Maximiere ich das Form, dann maximiert sich zwar das DBStringGrid weil align auf client steht. Die Spaltenbreite bleibt jedoch gleich und so entsteht rechts eine große Lücke wo nix steht. Und genau dies möchte ich nicht.

[DeddyH]

Was ist ein DBStringGrid?

[BBoy]

Sorry, ich meine DBGrid.

[DeddyH]

Nur so eine Idee: Du merkst Dir je Spalte deren prozentuale Breite relativ zur Clientbreite des Grids. Nach dem Resize errechnest Du dann aus dieser Zahl die neue Breite.

[Bummi]

Da ich mit meiner ersten Antwort neben den Anforderungen lag, hier die zweite Runde, gegf. kannst Du noch ein wenig feintunen.

Delphi-Quellcode:

Procedure SetDBGridColWidthAuto(Grid: TDBGrid);
var
  i: Integer;
  ws, w: Integer;
  dpl: Integer;
  CArray: Array of Integer;

    Function cWidth(idx: Integer): Integer;
    var
      f: TField;
    begin
      f := Grid.Columns[idx].Field;
      if Assigned(f) then
        Result := f.DisplayWidth
      else
        Result := Grid.Columns[idx].Width;
      CArray[idx] := Result;
    end;

begin
  ws := 0;
  w := Grid.ClientWidth;
  if dgColLines in Grid.Options then
    dpl := 1
  else
    dpl := 0;

  if dgIndicator in Grid.Options then
    w := w - 12;
  SetLength(CArray, Grid.Columns.Count);
  for i := 0 to Grid.Columns.Count - 1 do
    ws := ws + cWidth(i);

  for i := 0 to Grid.Columns.Count - 1 do
  begin
    Grid.Columns[i].Width := Round(w / ws * CArray[i] - dpl);
  end;

end;



procedure TForm3.FormResize(Sender: TObject);
begin
  SetDBGridColWidthAuto(DBGrid1);
end;

[BBoy]

Das konnte ich verwenden. Danke!