Wie iteriere ich durch eine Menge?

[Der schöne Günther]

Das ist eigentlich etwas, was spätestens am dritten Tag von Dingen wie "Jetzt lerne ich Delphi in 14 Tagen" vorkommen sollte. :oops: Aber ich stehe auf dem Schlauch.

Konkret geht es um

Delphi-Quellcode:

System.Classes.TShiftState

: Es ist definiert als

Delphi-Quellcode:

  TShiftState = set of (ssShift, ssAlt, ssCtrl,
    ssLeft, ssRight, ssMiddle, ssDouble, ssTouch, ssPen, ssCommand, ssHorizontal);

Der Enumerationstyp ist da direkt inline angegben. Wäre es ein "set of TEnumerationsTyp" wüsste ich, was ich zu tun habe. Nur wie kann ich, z.B. in einem "onMouseMove"-Event, jetzt da mit einem

Delphi-Quellcode:

for .. in

drüber? Von welchem Typ muss meine Iterationsvariable sein?

[DeddyH]

http://delphi.about.com/od/delphitip...for_in_set.htm

[Der schöne Günther]

Das dachte ich auch erst.

Aber das klappt nicht. Ganz konkretes Beispiel:

Delphi-Quellcode:

procedure TForm20.listViewMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
  var
   iterator: TShiftState;
  begin

   for iterator in shift do;

Ergibt: [dcc32 Fehler] Unit20.pas(271): E2010 Inkompatible Typen: 'TShiftState' und 'Enumeration'

[gammatester]

Du hast ja auch

Delphi-Quellcode:

iterator: TShiftState

, was ja schon ein Menge ist, iterator muß den Typ der Elemente haben. Definiere mal separate Typen TShiftState und TSetOfShiftState.

[Namenloser]

Das liegt daran, dass der Iterator natürlich vom Typ her ein Element der Menge sein muss und nicht selbst wieder eine Menge.

Leider ist TShiftState laut Online-Hilfe so deklariert:

Delphi-Quellcode:

TShiftState = set of (ssShift, ssAlt, ssCtrl, ssLeft, ssRight, ssMiddle, ssDouble);

Normalerweise definiert man ein Extra-Enum

Delphi-Quellcode:

TMyEnum = (meFoo, meBar);
TMySet = set of TMyEnum;

Delphi-Quellcode:

var
  mySet: TMySet;
  iterator: TMyEnum;
begin
  for iterator in mySet do 
    {...}

Sieht schlecht aus für TShiftState :(

[Der schöne Günther]

Genau das war meine Befürchtung. Bitter. Würde doch niemandem weh tun, so etwas mal in eine ordentliche Definition für "Element der Menge" und "Menge" aufzudröseln.

[Medium]

Das sieht für mich nach einem Klassischen "ach hätten wir doch bloß nicht damals" aus. Man war seinerzeit sicherlich glücklich bei Borland inline-Set-Mengen angeben zu können, statt immer langatmig 2 Typen zu deklarieren, wo man eigentlich nur die Menge braucht (nutzen soll). Das wurde dann intensiv in der VCL umgesetzt. Jetzt kam man ein paar Jahre später zu dem Trend der Iteratoren, und stellt im Nachgang fest: Ja Mist, was damals so elegant war, beisst uns jetzt in den Hintern.
(Konsequenterweise hätte man hier fast ein neues Sprachelement einfügen können:

Delphi-Quellcode:

var iterator: element of TShiftState;

, aber entweder kam da keiner drauf, oder der Roll-Out Termin hat schon Nackenklatscher verteilt.)

[Der schöne Günther]

Finde ich auch, das würde ja auch nichts kaputt machen. Wenn man schon so coole Dinge wie z.B.

Delphi-Quellcode:

reference to procedure

hat, dann geht sicherlich auch so etwas wie "element of"...

Und selbst wenn nicht, dann würde das doch auch nichts kaputt machen, wenn die VCL-Leute im Nachhinein die Definition in Menge und Mengenelement aufsplitten?

[DeddyH]

Einen fiesen Trick hätte ich da noch, allerdings ist das nicht ganz ungefährlich und sicherlich nicht zukunftsorientiert, da das wohl in die Hose gehen dürfte, sobald sich mal die Deklaration von TShiftState ändern sollte:

Delphi-Quellcode:

procedure TFormTest.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
type
  TMyState = (ssShift, ssAlt, ssCtrl, ssLeft, ssRight, ssMiddle, ssDouble,
    ssTouch, ssPen);
  TMyStates = set of TMyState;
const
  STATESTR: array [TMyState] of string = ('ssShift', 'ssAlt', 'ssCtrl',
    'ssLeft', 'ssRight', 'ssMiddle', 'ssDouble', 'ssTouch', 'ssPen');
var
  MyState: TMyStates absolute Shift;
  State: TMyState;
begin
  for State in MyState do
    ShowMessage(STATESTR[State]);
end;

[Union]

Deshalb macht man das ja auch lieber so:

Delphi-Quellcode:

GetEnumname(GetTypeData(TypeInfo(TShiftState))^.CompType^, Ord(ssCtrl));

[DeddyH]

Ich hatte mit meinen Einwänden aber nicht die Ermittlung des Namens gemeint, das war ja nur zur Veranschaulichung.

[Union]

Na dann verwendet man MinValue und MaxValue von GetTypeData.

[DeddyH]

Trotzdem ist mir immer noch nicht klar, wie man damit dann durch eine Inline-Enumeration iterieren kann :gruebel:

[Der schöne Günther]

Könnte man mit einem Record-Helper für das Set etwas bauen? Eigentlich auch nicht... :pale:

[Union]

Nicht schön aber selten... Bei neueren Delphi-Versionen muß man die Byte-typen evtl. durch Word ersetzen.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
   Shift : TShiftState;
   bMin, bMax : Byte;
   bShift : Byte;
   b : Byte;
   s : string;
begin
   // das hier wollen wir untersuchen
   Shift := [ssAlt, ssCtrl, ssShift];
   // Umwandeln damit's geht. Hier der Einfachheit halber fest als Byte, sonst über OrdType unterscheiden
   bShift := byte(Shift);
   // Über TypInfo den Bereich holen
   bMin := GetTypeData(GetTypeData(TypeInfo(TShiftState))^.CompType^)^.MinValue;
   bMax := GetTypeData(GetTypeData(TypeInfo(TShiftState))^.CompType^)^.MaxValue;
   // Iterieren über das Set
   for b := bMin to bMax do
   begin
      // Ist das drin?
      if bShift and (1 shl b)  <> 0 then
         // Dann Namen holen
         s := s + ' '+ GetEnumname(GetTypeData(TypeInfo(TShiftState))^.CompType^, b);
   end;
   ShowMessage(s);
end;

[Dust Signs]

Hallo!

Ich habe zwar eine gefühlte Ewigkeit nicht mehr Delphi programmiert, aber was spricht gegen Folgendes?

Delphi-Quellcode:

var
  state: SmallInt;
begin
  for state := Ord(Low(TShiftState)) to Ord(High(TShiftState)) do //Iteriere über alle möglichen Werte
  begin
    if (state = Ord(ssAlt)) then //Beispiel für einen Vergleich
      WriteLn('Test Alt');
  end;
end;

Ich habe gerade keine aktuelle Delphi-Version installiert, aber mit fpc funktioniert das einwandfrei. Oder habe ich die Fragestellung falsch verstanden?

Grüße
Dust Signs

[Union]

Dagegen spricht dass TShiftState ein Set ist. Von daher kannst Du dort kein Low / High anwenden.

Delphi-Quellcode:

TShiftState = set of (ssShift, ssAlt, ssCtrl,ssLeft, ssRight, ssMiddle, ssDouble);

Bei Enums geht es so wie Du schreibst, z.b:

Delphi-Quellcode:

TBorderIcon = (biSystemMenu, biMinimize, biMaximize, biHelp);

[Dust Signs]

Warum nicht? Folgender Code funktioniert einwandfrei (siehe http://ideone.com/LfRwI8)

Delphi-Quellcode:

program x;
type
  TShiftState = set of (ssShift, ssAlt, ssCtrl, ssLeft, ssRight, ssMiddle, ssDouble, ssTouch, ssPen, ssCommand, ssHorizontal);
var
  state: SmallInt;
begin
  for state := Ord(Low(TShiftState)) to Ord(High(TShiftState)) do
  begin
    case state of
      Ord(ssShift): WriteLn('Shift');
      Ord(ssAlt): WriteLn('Alt');
      Ord(ssCtrl): WriteLn('Ctrl');
      Ord(ssLeft): WriteLn('Left');
      Ord(ssRight): WriteLn('Right');
      Ord(ssMiddle): WriteLn('Middle');
      Ord(ssDouble): WriteLn('Double');
      Ord(ssTouch): WriteLn('Touch');
      Ord(ssPen): WriteLn('Pen');
      Ord(ssCommand): WriteLn('Command');
      Ord(ssHorizontal): WriteLn('Horizontal');
    end;
  end;
end.

Output:

Code:

Shift
Alt
Ctrl
Left
Right
Middle
Double
Touch
Pen
Command
Horizontal

Das ist also genau die verlangte Iteration durch die Werte.

Grüße
Dust Signs

[Union]

Zitat:

Zitat von Dust Signs (Beitrag 1225912)

Warum nicht? Folgender Code funktioniert einwandfrei (siehe http://ideone.com/LfRwI8)

Aber nicht mit Delphi.

[Uwe Raabe]

Zitat:

Zitat von Dust Signs (Beitrag 1225912)

Das ist also genau die verlangte Iteration durch die Werte.

Das war aber gar nicht gefragt. Es sollen doch nur die Werte iteriert werden, die aktuell um Parameter Shift enthalten sind, nicht alle möglichen TShiftState-Werte.

[Uwe Raabe]

Ist zwar auch nicht im Sinne des Erfinders, aber dies geht (auch mit Range-Checking):

Delphi-Quellcode:

var
  I: ssShift..ssShift;
begin
  for I in Shift do begin
    ...
  end;
end;

EDIT:
Aber warum dann nicht auch gleich richtig?

Delphi-Quellcode:

var
  I: ssShift..ssHorizontal;