Polygon schraffieren (ohne Canvas.Polygon)

[Bjoerk]

Hat jemand eine Idee, wie man ein Polygon schraffieren könnte, mir fällt nix Gescheites ein. Vorgehensweise oder Pseudoquellcode reicht mir völlig. Thanx.

[Aphton]

Sofern wir unter Schraffieren dasselbe verstehen (z.B. soetwas hier), kann ich folgendes vorschlagen:
- Je nach Art der Schraffur gewisse Schritte in der Y-Achse machen
- dann für jeden Y Wert die Schnittpunkte einer waagrechten (EDIT: oder halt andere irgendeine Richting) Linie von (x,y) wobei x = [-unendlich,unendlich]~ & y der aktuelle y-Wert
(das geht ganz einfach - ein Punkt ist in einem Polygon, wenn die Anzahl der Schnitte, die es bis zum aktuellen x Punkt macht, ungerade ist -> Beispiel: )

Code:

  +-----+
  |     |
--|-----|----
  +-----+

Nachdem die Linie links zum ersten Mal das Polygon schneidet (Schnittanzahl = 1 = ungerade), befindet sie sich im Polygon, bis sie wieder zum Schnitt kommt (2 = ungerade).

PS: -unendlich .. unendlich wird schwer gehen - ermittle am besten zuvor eine Bounding Box um dein Polygon, damit du die Min-Max x Werte hast!

[Uwe Raabe]

Du kannst auch aus dem Polygon eine Clip-Region machen (such mal nach CreatePolygonRgn und SelectClipRgn) und dann einfach den ganzen Zeichenbereich schraffieren.

[Bjoerk]

Aphton, Ja, so ging’s und das wäre sicher auch eine schmucke Klasse. Auf die Idee mit dem Boundrect bin ich auch gekommen. Davon ausgehend ein InflateRect und los gehts. Die entsprechenden functions Schnittpunkte berechnen und ob innerhalb oder nicht hab ich sogar (brauch in anderer Stelle). Denke mal, der Algo dauert aber viel zu lang? Vielleicht mach ich's dann doch mit Canvas Polygon, aber mit einer Brush.Bitmap (falls das geht, hab ich noch nie benutzt?). Uwe, ich brauch nicht nur Diagonalen.

[Uwe Raabe]

Zitat:

Zitat von Bjoerk (Beitrag 1240676)

Uwe, ich brauch nicht nur Diagonalen.

Das habe ich ja auch gar nicht behauptet. Das Clipping erlaubt es lediglich, auf dem gesamten Canvas zu malen (was auch immer), wobei sich das nur auf den geclipten Bereich auswirkt.

Wenn es wirklich um Performance geht, dann solltest du aber wirklich auf Canvas.Polygon setzen.

[Aphton]

Uwe's Methode ist um eine Größenordnung eleganter!
Ich habe nie mit Regionen effektiv gearbeitet (das einzige, was ich gemacht habe, ist, ein nicht viereckiges Fenster zu erstellen).
Sonst hätt ich das auch vorgeschlagen ^^

Der Algorithmus sollte eigentlich akzeptabel flott funktionieren.. Ein Bottleneck wäre evt. die Schnittpunktberechnung..
Ich schlage aber vor, du implementierst und testest das ganze mal!

[Medium]

Die Schnittpunktberechnung wird extrem billig, wenn man das ganze auf einem bereits gezeichneten Polygon macht (bei dem Hintergrund- und Polygonfarbe genau unterschieden werden können): Bei einem Farbwechsel befindet man sich im nächsten Pixel auf der anderen Seite des Polygons als vorher. Man muss nur den Sonderfall horizontaler Linien bedenken, d.h. so lange nach einem Wechsel die neue Farbe in weiteren Pixeln auch ist, ist man noch nicht angekommen.
Einziges Problem ist dabei, dass es Grenzfälle gibt. Beispiel:

Code:

XXXXXX
 X   X
  XX   <- unfein
 X   X
XXXXXX

Der "Scanline"-Ansatz ist insgesamt aber auch der gängige. Wie man genau die Schnittpunkte ermittelt ist dann zweitrangig, und man muss eben schauen was für den jeweiligen Fall praktikabel ist. (In der Graphics32 gibt es für TPolygon32 z.B. ein Event OnFillScanline() o.ä., mit dem man einen Custom-Filler anflanschen kann. Die Klasse nutzt intern das gleiche Verfahren.)

Die o.g. Grenzfälle kann man "schmutzig" eliminieren, wenn du dein Polygon performant komplett ausfüllen kannst: Pixel hat Füllfarbe -> du bist drin und kannst deine Schraffur drauf los lassen. Da braucht es dann aber spätestens eine Kopie in einem separaten Bitmap; eine für gefülltes Arbeitspolygon, eine im eigentlichen Bild. (Was es auch beim anderen Ansatz bräuchte, wenn der Hintergrund bereits vorbemalt ist.)
Das Verfahren sollte aber erst dann wirklich merkbar schneller werden, wenn die Polygone sehr viele Segmente haben, die man sonst mathematisch schneiden müsste. Das geht bei Gerade-Gerade ja wirklich sehr flott.

[Popov]

Da ich gerade etwas ähnliches brauchte (eigentlich einen Farbverlauf in einem Polygon - aber ob Farbverlauf oder Schraffur, nur der Inhalt ändert sich) habe ich Uwes Tipp in Code umgesetzt.

Und weil es kurz vor Weihnachten ist, habe ich das mit Schraffur auch ausprobiert:

Delphi-Quellcode:

procedure Dreieck(ABmp: TBitmap);
var
  P: array[0..3] of TPoint;
  Rgn : HRGN;
begin
  with ABmp do
  begin
    P[0] := Point(0, Height);
    P[1] := Point((Width div 2), 0);
    P[2] := Point(Width, Height);
    P[3] := P[0];

    Rgn := CreatePolygonRgn(P[0], Length(P), WINDING);
    SelectClipRgn(Canvas.Handle, Rgn);

    Canvas.Brush.Style := bsDiagCross;
    Canvas.FillRect(Canvas.ClipRect);

    DeleteObject(Rgn);
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  with Image1 do
  begin
    Picture.Bitmap.Width := Width;
    Picture.Bitmap.Height := Height;

    Dreieck(Picture.Bitmap);
  end;
end;

Ich denke es ist alles richtig so.

[Bjoerk]

Fragt man sich, was da jetzt der Unterschied zu Canvas.Polygon(P) sein soll?

[Popov]

Mit Canvas.Polygon(P) zeichnest du ein Polygon. Das Polygon wird mit den eingestellten Eigenschaften gefüllt, zu Not auch mit Schraffur. Soweit nichts Besonderes und nichts Neues.

Hier (oberes Beispiel) erstellst du aber einen Cliping-Bereich. Du kannst somit alles in das Polygon zeichen, auch das Bild von deiner Oma, Farbverlauf und eigene Schrafuren. Da du einen Cliping-Bereich hast, kannst du drüberkleckern und alles landet innerhalb des Polygons.

[Neutral General]

Ich denke mal das ist ihm klar, Er frag sich wahrscheinlich nur was der Sinn sein soll es so zu machen statt einfach Canvas.Polygon zu benutzen

[Aphton]

Die Antwort zu seiner Frage ist - man muss nicht die Schnittpunkte der Schraffurlinien mit dem Polygon berechnen. Man kann die Schraffur einfach auf die Schablone/Clipbereich draufmalen - ohne irgendwelche jeglichen Sorgen -- diese werden sich dann durchs Clipping im Polygon befinden!

[Uwe Raabe]

Um das nochmal zu verdeutlichen: wenn die Schraffur mit dem Brush.Style gemacht wird, kann man direkt Canvas Polygon verwenden. Will man die Schraffur direkt zeichnen, weil es die passende nicht gibt und einem die Erstellung einer Bitmap zu aufwändig ist (oder das Bild von der Oma als Schraffur herhalten soll), kann man das Clipping verwenden.

[Bjoerk]

Genauso so sieht's aus, Ihr habt vollkommen recht. :thumb:
Beispiel:

Delphi-Quellcode:

procedure HatchSolidDash(Canvas: TCanvas; const Polygon: array of TPoint;
  HatchColor: TColor; Frequency: integer);
var
  I, J: integer;
  ClipRgn: HRGN;
  CanvasWidth, CanvasHeight: integer;
begin
  ClipRgn := CreatePolygonRgn(Polygon[0], Length(Polygon), WINDING);
  try
    SelectClipRgn(Canvas.Handle, ClipRgn);
    CanvasWidth := Canvas.ClipRect.Right - Canvas.ClipRect.Left;
    CanvasHeight := Canvas.ClipRect.Bottom - Canvas.ClipRect.Top;
    Canvas.Pen.Color := HatchColor;
    Canvas.Pen.Width := 1;
    I := 0;
    J := 0;
    while (I < CanvasHeight) or (I < CanvasWidth) do
    begin
      Canvas.MoveTo(0, I * Frequency);
      Canvas.LineTo(I * Frequency, 0);
      Inc(I, Frequency);
      Inc(J);
      if Odd(J) then
        Canvas.Pen.Style := psSolid
      else
        Canvas.Pen.Style := psDash;
    end;
  finally
    DeleteObject(ClipRgn);
    SelectClipRgn(Canvas.Handle, 0);
  end;
end;

procedure TForm2.Button4Click(Sender: TObject);
var
  Points: array of TPoint;
begin
  SetLength(Points, 12);
  Points[0] := Point(100, 150);
  Points[1] := Point(200, 150);
  Points[2] := Point(250, 200);
  Points[3] := Point(200, 350);
  Points[4] := Point(100, 350);
  Points[5] := Point(50, 400);
  Points[6] := Point(400, 150);
  Points[7] := Point(500, 50);
  Points[8] := Point(55, 100);
  Points[9] := Point(500, 250);
  Points[10] := Point(400, 350);
  Points[11] := Point(350, 400);
  HatchSolidDash(Canvas, Points, clRed, 3);
  Canvas.Pen.Width := 1;
  Canvas.Brush.Style := bsClear;
  Canvas.Pen.Style := psSolid;
  Canvas.Pen.Color := clBlack;
  Canvas.Polygon(Points);
end;

[Bjoerk]

BTW, bei mir (D2007) macht er psDash, psDot und Co. nur bei Pen.Width 1. Ist das normal? :gruebel:

[Uwe Raabe]

Jupp! http://docwiki.embarcadero.com/RADSt...en_%C3%A4ndern

Zitat:

Anmerkung: Unter Windows werden breitere Strichstärken als 1 immer als durchgezogene Linien gezeichnet, unabhängig vom Wert der Eigenschaft Style.