SendMessage überträgt String nicht zuverlässig

[Kostas]

Hallo zusammen,

ich sende über SendMessage eine Nachricht an ein anderes Programm.
Dabei wird die Nachricht manchmal am Ende verfälscht. Sie wird abgeschnitten und teilweise andere Zeichen hinzugedichtet.

Zu senden der Nachricht:

Delphi-Quellcode:

type TNachrichtTyp = (ntCreateSnapShot);

var 
  copyDataStruct : TCopyDataStruct;
  res : integer;
  Nachricht : string; 

begin
  Nachricht := 'B;2;160569;Di, 12.06.2012  14:08;DAH-TH480;DAH-TH481';
  copyDataStruct.dwData := Ord(ntCreateSnapShot);
  copyDataStruct.cbData := Length(Nachricht);
  copyDataStruct.lpData := PChar(Nachricht);


  res := SendMessage(HWND_BROADCAST, WM_COPYDATA, Integer(Handle), Integer(@copyDataStruct)) ;

Ich sende also
B;2;160569;Di, 12.06.2012 14:08;DAH-TH480;DAH-TH481;
und Manchmal empfängt das andere Programm:
B;2;160569;Di, 12.06.2012 14:08;DAH-TH480;DAH-TH481D


//zum Empangen der Nachricht.

Delphi-Quellcode:

procedure TfrKamera1.WMCopyData(var Msg: TWMCopyData) ;
var
  NachrichtTyp : TNachrichtTyp;
  Nachricht:string;
begin
  NachrichtTyp := TNachrichtTyp(Msg.CopyDataStruct.dwData);
  Nachricht := PChar(Msg.copyDataStruct.lpData);  //Die Nachricht ist nicht immer identisch!!!


  //Send something back
  msg.Result := SizeOf(Msg.CopyDataStruct);
end;

Hat jemand eine Idee?


Gruß Kostas

[DeddyH]

Was mir zuerst auffällt: das cbData-Feld des CopyDatastructs gibt die Größe in Byte an, nicht die Länge Deines Strings, er ist also falsch belegt. Versuch es also zuerst einmal mit

Delphi-Quellcode:

copyDataStruct.cbData := Length(Nachricht) * SizeOf(Char);

[Bernhard Geyer]

In XE2 ist ein Zeichen eines String 2 Byte lang.
Du verheimslichst damit Windows die Wirkliche länge deiner Daten.

Du brauch also

Delphi-Quellcode:

copyDataStruct.cbData := Length(Nachricht) * Sizeof(Char)

[himitsu]

Und dann wurde noch etwas ganz Wichtiges vergessen.

Am Ziel wird das als PChar ausgelesen, also muß dort auch zwingend das String-Ende mit übertragen werden.

Delphi-Quellcode:

copyDataStruct.cbData := (Length(Nachricht) + 1) * Sizeof(Char);

Alternativ muß man beim Auslesen des Textes die Länge (copyDataStruct.cbData) verwenden und darf eben nicht bis zum nichtübertragenen/fehlenden Stringende lesen.

Ach ja, wenn hier auch noch zwischen zwei Programmen übertragen wird, dann ist und was es schon immer FALSCH, wenn hier PChar verwendet wird, denn wenn ein Programm Unicode ist und das Andere nicht, dann hat man ein Problem.

Bei Datenübertragungen muß immer ein fest definiertes und unveränderliches Format verwendet werden, also hier entweder PAnsiChar oder PWideChar. :warn:
Oder man übergibt das Format mit und liest dann entsprechend aus.



PS: Ist HWND_BROADCAST hier nicht ein klein bissl gefährlich?
Man stelle sich mal vor ein anderes Programm empfängt und wertet ebenfalls WM_COPYDATA mit copyDataStruct.dwData=0 aus,
das wird da bestimmt kanllen, wenn es unverständliche/ungültige Daten empfängt. :angel:

[Sir Rufo]

Es gibt auch noch TEncoding.GetBytes und passend dazu TEncoding.GetString.

Wenn sich beide Seiten auf die gleiche Kodierung einigen, dann geht das eigentlich sehr schön damit.

[Kostas]

Hallo zusammen,

ich glaube das ist der richtige Weg aber es hat noch nicht funktioniert.
Beide Anwendungen sind in Delphi5 geschrieben. Da ist das Char noch 1 Byte lang.

Delphi-Quellcode:

copyDataStruct.cbData := Length(Nachricht) * Sizeof(Char);

//hat nicht funktioniert.

Was himitsu meinte habe ich nicht verstanden. Vermutlich wird das die Lösung sein. :-)


himitsu, wie müsste ich ein String aufbereiten um ihn zu übertragen?

[himitsu]

Ein Delphi-String besitzt eine Längenangabe (Integer) und braucht daher eigentlich die #0 am Ende nicht.

PChar wird aber ausschließlich durch ein #0 am Stringende begrenzt und wenn man Dieses nicht mit überträgt, dann liest man mit PChar bis zum nächsten #0, welches zufällig irgendwo danach im Arbeitsspeicher liegt und wenn es danach keinen reservierten Speicher mehr gibt, dann gibt es eine Zugriffsverletzung.

Delphi besitzt aber implizit zwei Zeichen mehr im Text, nämlich zwei #0, hinter dem letzten Zeichen im String, welches für die Kompatibilität zum PChar vorhanden ist, damit man den Delphi-String problemlos in einen PChar casten kann.
(#0 ist das Ende eines PChar und #0#0 sind das Ende einer Stringliste aus PChars)




Auslesen bis zum #0.

Delphi-Quellcode:

var
  copyDataStruct : TCopyDataStruct;
  Nachricht : AnsiString;

begin
  copyDataStruct.dwData := ...;
  copyDataStruct.cbData := (Length(Nachricht) + 1{die abschließende #0}) * SizeOf(AnsiChar);
  copyDataStruct.lpData := PAnsiChar(Nachricht);

  SendMessage(HWND_BROADCAST, WM_COPYDATA, LPARAM(Handle), WPARAM(@copyDataStruct));


Nachricht := PAnsiChar(Msg.copyDataStruct.lpData);

Auslesen über Längenangabe:

Delphi-Quellcode:

var
  copyDataStruct : TCopyDataStruct;
  Nachricht : AnsiString;

begin
  copyDataStruct.dwData := ...;
  copyDataStruct.cbData := Length(Nachricht) * SizeOf(AnsiChar);
  copyDataStruct.lpData := PAnsiChar(Nachricht);

  SendMessage(HWND_BROADCAST, WM_COPYDATA, LPARAM(Handle), WPARAM(@copyDataStruct));



SetString(Nachricht, PAnsiChar(Msg.copyDataStruct.lpData), Msg.copyDataStruct.cbData div SizeOf(AnsiChar));

Oder WideString/UnicodeString mit WideChar und PWideChar.

Oder als UTF8String mit AnsiChar und PAnsiChar.

[himitsu]

Bezüglich dem PS meines ersten Posts:

Zitat:

ich sende über SendMessage eine Nachricht an ein anderes Programm

Nein, das machst du nicht. Du sendest diese Nachricht an alle anderen Programme. (abgesehn von Denen mit höheren Rechten, an die dein Programm keine Messages senden darf)

[Kostas]

Hallo himitsu,

eigentlich möchte ich die Nachricht an alle Programm(nur Eigene Programme) senden
die genau diese Nachricht konsumieren können. Die Anwendungen können auch mehrfach gestartet sein.
Gibt es dafür eine bessere Möglichkeit? Du hast natürlich recht, das fremde Programm die Nachricht erst garnicht bekommen sollen.

Leider hat die Variante "Auslesen bis zum #0." nicht funktioniert.
Ich versuche mal die Variante "Auslesen über Längenangabe:"

Dankeschönen für deine Unterstützung.

Gruß Kostas

[hathor]

Hier ist es gut beschrieben:
http://delphi.about.com/od/windowssh...m_copydata.htm

Programm-Beispiel:
http://delphi.about.com/library/week...m_copydata.zip

Erforderliche Änderungen bei XE2:

Delphi-Quellcode:

procedure TReceiverMainForm.HandleCopyDataString(
  copyDataStruct: PCopyDataStruct);
var
  s : ANSIstring;  //th
begin
  s := PANSIChar(copyDataStruct.lpData); //th
...
...
procedure TSenderMainForm.SendString();
var
  stringToSend : ANSIstring; //th
...

[theunreplicated]

vllt. könntest du es auch mal mit SendMessageW versuchen.
Denn das W als letzter Buchstabe im Funktionsname steht nämlich für den Unicode-Funktion Aufruf der WinAPI.
Ich schätze mal,dass es daran liegen wird.
Denn n Delphi-String baut afaik auf Unicode auf, mit SendMessage ohne W(ist eigentlich n Makro für SendMessageA) rufst du aber die Funktion für Ansi-Strings auf.

[himitsu]

Das hat hier keinerlei Auswirkung, da diese Message binär ist und nichts mit Texten zu tun hat.


Und nein, ein Delphi-String ist nicht immer Unicode.

Bis Delphi 2007 ist String ein Alias für AnsiString und SendMessage ist ein Alias für SendMessageA.
Ab Delphi 2009 ist String ein Alias für UnicodeString und SendMessage ein Alias für SendMessageW.
Ach ja, ganz am Anfang war String das, was heutzutage der ShortString ist.

[Kostas]

Hallo zusammen,

ach, ein dummer Fehler ist mit da passiert.
Ich habe eine public Variable vom Typ TCopyDataStruct angelegt
und mit Werten befüllt. Danach über einen Thread zugegriffen und gesendet.
Jetzt erzeuge ich das TCopyDataStruct innerhalb vom Thread und es funktioniert
einwandfrei.

Sorry dass ich bemüht habe.
Gruß Kostas

[himitsu]

Jaja, es ist immer besser, alles zu sagen und wenn möglich auch den Originalcode zu zeigen, da sonst wichtige Informationen fehlen.

Ich hoffe du hast die Zugriffe auch orgendlich abgesichert. !:!
- z.B. synchronisieren oder über CriticalSections sperren

Dein Fehler war also nicht der Thread, sondern die Speicherverwaltung.
Wenn du schon sowas machst, dann soltest du unbedingt lernen und verstehen, wie das mit den Pointern so funktioniert.

Zitat:

Delphi-Quellcode:

copyDataStruct.lpData := PChar(Nachricht);

Hier wird nur ein Zeiger auf die Daten des Strings "Nachricht" in lpData gespeichert.
Wenn jetzt der String zwischenzeitlich verändert oder freigegeben wird, dann ist auch der Zeiger ungültig.

[Kostas]

Hallo himitsu,

mein Problem war ich habe zwar den Thread Syncronisiert jedoch nicht an dieser Stelle wo ich auf die TCopyDataStruct
zugegriffen habe. Das war alles. Übrigens, merke ich das SendMessage über HWND_BROADCAST ein paar Sekunden braucht
bis es versendet werden kann. Sende ich jedoch mit dem Handle von der Receiver Anwendung Funktionier das Senden sofort
und brauche daher kein Thread mehr. Ich versuche jetzt mal WM_user + 100 oder aber auch RegisterWindowMessage.
Mal sehen mir besser gefehlt.

Dir noch eine schöne Zeit.
Gruß Kostas

[EWeiss]

Zitat:

Übrigens, merke ich das SendMessage über HWND_BROADCAST ein paar Sekunden braucht

Es ist nun mal halt so das eine SendMessage auf eine Rückantwort wartet.
Willst du das nicht verwende PeakMessage ops.. PostMessage.

gruss

[himitsu]

Meinst du nicht PostMessage? :zwinker:

Wobei hier SendMessage eh keine sinnvolle Antwort zurückgeben kann.
Denn, wie gesagt, sendet HWND_BROADCAST die Meldung an alle Programme (TopLevelWindows), hat nur ein Result und kann da natürlich nicht taustende Antworten drin unterbekommen.

Und das Tausende mein ich ernst. (nja, zumindestens paar Hundert sind es bestimmt)

[Sir Rufo]

Zitat:

Übrigens, merke ich das SendMessage über HWND_BROADCAST ein paar Sekunden braucht

Bei

Delphi-Quellcode:

SendMessage

kann man den Rückgabewert auswerten und das geht eben nur, wenn so lange gewartet wird, bis

Delphi-Quellcode:

SendMessage

seine Arbeit verrichtet hat.

Bei

Delphi-Quellcode:

HWND_BROADCAST

wird jedes Top-Level-Fenster besucht und bei jedem wird gewartet bis das Fenster diese Nachricht bearbeitet hat.

Mehr muss man wohl nicht erklären, warum das ein paar Sekunden benötigen kann und bei einer tollen Anwendung mit einem blockierendem GUI-Thread kann das auch noch länger dauern.

[EWeiss]

Zitat:

Zitat von himitsu (Beitrag 1262324)

Meinst du nicht PostMessage? :zwinker:

Wobei hier SendMessage eh keine sinnvolle Antwort zurückgeben kann.
Denn, wie gesagt, sendet HWND_BROADCAST die Meldung an alle Programme (TopLevelWindows), hat nur ein Result und kann da natürlich nicht taustende Antworten drin unterbekommen.

Und das Tausende mein ich ernst. (nja, zumindestens paar Hundert sind es bestimmt)

JA natürlich.. ;)
Sorry war spät gestern.

Zitat:

@Sir Rufo.. Bei SendMessage kann man den Rückgabewert auswerten und das geht eben nur, wenn so lange gewartet wird, bis SendMessage seine Arbeit verrichtet hat.

Mach aber in seinem Fall nicht wirklich sinn. Oder?

gruss

[Sir Rufo]

Zitat:

Zitat von EWeiss (Beitrag 1262344)

Zitat:

@Sir Rufo.. Bei SendMessage kann man den Rückgabewert auswerten und das geht eben nur, wenn so lange gewartet wird, bis SendMessage seine Arbeit verrichtet hat.

Mach aber in seinem Fall nicht wirklich sinn. Oder?

Nö, nicht wirklich ;)

[Dejan Vu]

Ist das schon erwähnt worden?
1. WM_COPYSTRUCT soll/darf nur mit SendMessage aufgerufen werden.
2. Die zu übertragenden Daten sollen/dürfen keine Pointer enthalten.
3. Der Empfänger soll die Daten schnellstmöglich aus der übergebenen Struktur kopieren und die Abarbeitung beenden.
4. Schneller geht es mit Pipes.

[himitsu]

Zitat:

Zitat von Sir Rufo (Beitrag 1262350)

Nö, nicht wirklich ;)

Genauso, wie es keinen Sinn macht das an ALLES zu senden.

http://www.flounder.com/wm_copydata.htm

Zitat:

So sending a message like this using HWND_BROADCAST is to be considered a seriously antisocial act.

Der Meinung bin ich auch, obwohl das noch nett formuliert ist.

[Kostas]

Tausend Dank an alle beteiligten,

so funktioniert es einwandfrei und ausreichend schnell.

//zum Senden

Delphi-Quellcode:

procedure SendData;
var receiverHandle : THandle;
    copyDataStruct : TCopyDataStruct;
begin
  receiverHandle := FindWindow(PChar('TfrKamera1'),PChar('frKamera1'));

  if receiverHandle > 0 then
  begin
    copyDataStruct.dwData := Ord(ntCreateSnapShot);
    copyDataStruct.cbData := 1 + Length(SendMsgText);
    copyDataStruct.lpData :=  PChar(SendMsgText);

    SendMessage(receiverHandle, WM_COPYDATA, LPARAM(Handle), WPARAM(@copyDataStruct)) ;
  end;
end;

//zum Empfangen

Delphi-Quellcode:

procedure TfrKamera1.WMCopyData(var Msg: TWMCopyData) ;
var
  NachrichtTyp : TNachrichtTyp;
begin
  NachrichtTyp := TNachrichtTyp(Msg.CopyDataStruct.dwData);

  case NachrichtTyp of
    ntCreateSnapShot: HandleCopyDataString(Msg.CopyDataStruct);
  end;
end;

Für mein aktuelles Projekt ist es ausreichend.

Gruß Kostas

[himitsu]

Zitat:

Zitat von Kostas (Beitrag 1262358)

so funktioniert es einwandfrei

Zitat:

Zitat von Kostas (Beitrag 1262242)

Beide Anwendungen sind in Delphi5 geschrieben. Da ist das Char noch 1 Byte lang.

Bis jemand auf die abwägige Idee kommt eines oder beide Programme mit seinem neueren Delphi zu kompilieren,
da diesbezüglich alles ignoriert wurde, aber was soll.

[Kostas]

Für Delphi5 habe ich nun mal keine andere Möglichkeit.
Für zukünftige IDEs habt ihr ja bereits die passenden Hinweise gleich mittgeliefert. :-)
Schönen Dank dafür.

Gruß Kosats

[EWeiss]

Zitat:

Zitat von himitsu (Beitrag 1262360)

Zitat:

Zitat von Kostas (Beitrag 1262358)

so funktioniert es einwandfrei

Zitat:

Zitat von Kostas (Beitrag 1262242)

Beide Anwendungen sind in Delphi5 geschrieben. Da ist das Char noch 1 Byte lang.

Bis jemand auf die abwägige Idee kommt eines oder beide Programme mit seinem neueren Delphi zu kompilieren,
da diesbezüglich alles ignoriert wurde, aber was soll.

Das sind die Nachteile wenn man sich bei so einem Thema mit einbringt.
Man will nichts lernen sondern nur übernehmen wenn es denn passt.
Aber wie du schon sagst... was soll's

gruss

[himitsu]

Gute Erlärung, nur die genannten Pips und eigentlich nahezu alles Andere, was mit IPC zu tun hat, funktioniert auch mit alten Delphis.

[Kostas]

Hallo EWeiss,

ich bin mir nicht sicher ob du mich damit meinst. Falls doch,
ich habe schon gelernt dabei, das habe ich auch umgesetzt.
-Ich verwende keine Broadcast sondern sende an das Fensterhandle des Empfängers.
-Ich habe erfahren dass WM_COPYDATA nur mit SendMessage und nicht mit PostMessage geht.
-Jetzt ist mir klar warum Broadcast so langsam war.
-Ich weis jetzt dass in meinem Fall das Result unbrauchbar ist.

Oder habe ich etwas übersehen? Ich bin für Jede Info dankbar.

Gruß Kostas

[EWeiss]

Zitat:

Zitat von Kostas (Beitrag 1262367)

Hallo EWeiss,

ich bin mir nicht sicher ob du mich damit meinst. Falls doch,
ich habe schon gelernt dabei, das habe ich auch umgesetzt.
-Ich verwende keine Broadcast sondern sende an das Fensterhandle des Empfängers.
-Ich habe erfahren dass WM_COPYDATA nur mit SendMessage und nicht mit PostMessage geht.
-Jetzt ist mir klar warum Broadcast so langsam war.
-Ich weis jetzt dass in meinem Fall das Result unbrauchbar ist.

Oder habe ich etwas übersehen? Ich bin für Jede Info dankbar.

Gruß Kostas

:thumb:

gruss

[Kostas]

Zitat:

Zitat von himitsu (Beitrag 1262366)

Gute Erlärung, nur die genannten Pips und eigentlich nahezu alles Andere, was mit IPC zu tun hat, funktioniert auch mit alten Delphis.

Ja, verstehe. Sicherlich gibt es mehrere Wege. Für das aktuelle Projekt finde ich die Lösung mit SendMessage ausreichend.
Es geht um zwei Programme die beide auf dem gleichen Rechner laufen. Das eine erstellt ein Wägeschein und das andere
zeigt den Stream einer LAN-Kamera die auf die Ladefläche des LKWs schaut. Sobald ein Wägeschein erstellt wird, werden
ein paar Daten wie Datum, WägescheinNr, Kennzeichen u.s.w. an die andere Anwendung gesendet die gerade den Stream von der
LAN-Kamera zeigt. Der String wird empfangen, auf das Bild Projiziert und ein jpg als screen shot zur Dokumentation
erstellt. Beide Programme werden immer auf dem gleichen PC laufen. Deshalb schien mir die SendMessage Technik dir richtige
zu sein.

Übrigens, ich habe Messages immer vermieden wie der Teufel das Weihwasser. :-) War für mich also sehr Lehrreich.
Gruß Kostas

[MyRealName]

Es gibt da noch eine Function RegisterWindowsMessage oder so, gibt man einen Namen (String) und kriegt dafür eine eindeutige ID für Send/Post-Message. Und alle anderen, die die gleiche Nachricht (mit dem gleichen Namen) anmelden, kriegen die gleiche ID. Damit kann man sich auf eien "Kommunikationskanal" dynamisch festlegen.

[Kostas]

Danke für die Info.

Der Vorschlag ist auch mehrfach gemacht worden.
Ich habe das Result von RegisterWindowsMessage in eine DWord Variable gespeichert und als
Ersatz für das receiverHandle übergeben doch das hat nicht funktioniert.
Ich bin noch am schauen wie genau das geht. Anhand den Beispiel die ich bis jetzt gesehen habe,
kann ich wahrscheinlich WMCopyData nicht verwenden. So wie es jetzt ist, funktioniert es auch einwandfrei.
Schöne wäre RegisterWindowsMessage schon.

Gruß Kostas