Form ohne Rahmen bewegen

[mm1256]

Hallo,

ich habe eine Form mit einem Image und ein paar Buttons. BorderStyle = bsNone und BorderIcons = [].

Wie bekomme ich es nun hin, dass der Anwender das Fenster trotz fehlender Titelleiste mit der Maus bewegen (zur Seite schieben) kann, wenn es in der Fensteranordnung stört?

[pelzig]

Willst Du
"Form ohne Ramen bewegen"
oder
"Form bewegen ohne Rahmen"
oder
"Fenster ohne Titelzeile verschieben"`

Oder einfach nur Klicken?

MfG

[mm1256]

Der Anwender soll eine Form ohne Rahmen bewegen können. Vielleicht etwas besser erklärt: Die Form beinhaltet wie gesagt ein Image. Das Image ist eine runde transparente Grafik mit ein paar Buttons. Die Form hat keinen Rahmen und ist transparent, d.h. es ist nur die runde Grafik mit den Buttons zu sehen.

Diese Form soll bei gedrückter Maustaste verschoben werden können. Ich habe schon alles mögliche versucht, z.B. beim Mouse-Down die Koordinaten gemerkt und beim Mouse-Move wenn die Taste noch gedrückt ist die Position des Fensters neu berechnet. Das flackert wahnsinnig, und sieht einfach besch... aus. Und da dachte ich eben, es gibt sicher eine elegante Lösung. Der Gockel hat nichts ausgespuckt, die Suche hier auch nicht, und darum dachte ich eben, frag ich mal die Spezialisten.

[pelzig]

Wenn's auf dem Formular nur das Bild gibt, musst Du für das Verschieben halt die Maus mit einer zusätzlich gedrückten Taste(nkombination) auswerten!

Was spricht denn gegen ein 2-5 Pixel hohes Panel am oberen Formularrand?

MfG von einem Nicht-Spezialisten :?

[DeddyH]

Ganz unspektakuläre Möglichkeit:

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    Image1: TImage;
    procedure Image1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
  private
    { Private-Deklarationen }
    FInitialPos: TPoint;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  FInitialPos := Point(X, Y);
end;

procedure TForm1.Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  if ssLeft in Shift then
    begin
      Left := Left + X - FInitialPos.X;
      Top := Top + Y - FInitialPos.Y;
    end;
end;

[mm1256]

Hallo Detlef,

danke für den Versuch! Wie schon geschrieben, genau nach diesem Prinzip habe ich es ja probiert...das flackert

[OrNEC]

Ich habe da eine gute Lösung, muss danach suchen... dauert eine Weile.

[DeddyH]

DoubleBuffered ist aktiv?

[mm1256]

Hallo,

DoubleBuffered ist nicht aktiviert. Jetzt hab ich das mal mit einer neu erstellten Form probiert, die flackert nicht, oder zumindest fast nicht. Sieht auf jeden Fall besser aus. Da muss also noch irgend was anderes im Busch sein. Muss ich suchen :oops:

Vielen Dank jedenfalls für die Bemühungen!

[himitsu]

Welche Windowsversion?
Seit Vista und dem Desktop-Window-Manager sollte sich die Form nicht mehr ständig neu zeichnen, wenn sie blos verschoben wird.

Was ist auf der Form drauf, bzw. was flackert da eigentlich?

[mm1256]

Hallo,

jetzt habe ich die Form einfach mal neu erstellt, und siehe da, kein Flackern mehr. Implementierung exakt so wie von Detlef vorgeschlagen.

Ich hatte es vorher so ähnlich, nur mit XY-Koordinaten anstelle des TPoint. Doch das dürfte ja eigentlich keinen Unterschied machen. Das Formular war schon etwas älter und ursprünglich mit D7 (oder vielleicht sogar noch mit D5) erzeugt. Genau weiß ich das nicht mehr. Vielleicht hat sich ja was eingeschlichen bei den Konvertierungen. Wird wohl ein Rätsel bleiben.

Jedenfalls tut es jetzt und darum nochmals vielen Dank an alle.

[Daniela.S]

Hast du schon versucht das Verschieben Windows zu überlassen?
OnMouseDown Ereignis einfach auch im TImage zuweisen.

Delphi-Quellcode:

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X,
  Y: Integer);
begin
  ReleaseCapture;
  Perform( wm_SysCommand, $F012, 0 );
end;

[BadenPower]

Hallo zusammen,

am einfachsten ist es wohl WMNCHitTest zu überscheiben.
Sind dann ganz einfach nur 6 Zeilen.

Delphi-Quellcode:

type
  TMyForm = class(TForm)
    // ...
  private
    procedure WMNCHitTest(var AMessage: TWMNCHitTest); message WM_NCHITTEST;
  end;

und

Delphi-Quellcode:

procedure TMyForm.WMNCHitTest(var AMessage: TMessage);
begin
  inherited;
  AMessage.Result := HTCAPTION;
end;

Dann wird das Fenster genau so verschoben, als hättest Du eine Titelzeile.

.