Menu funktionalität ohne MainMenu

[Mavarik]

Hallo Zusammen!

Ich möchte die Funktionalität eines MainMenus ohne das Menu haben. Bedeutet...

Ich definieren

&Aufrufen
&Nichtaufruf
&Sonderfunktion
CooleFunktion STRG+C

Wenn keines der MDI-Childs auf Alt-A, Alt-N, Alt-S reagiert hat, möchte ich die Funktionen die hinter meinen Menüpunkten stehen aufrufen...
Das Ganze aber bitte ohne das ein MainMenu dargestellt wird...

Ich brauche also kein Keypreview.... sondern ein Shortcut/Accelerator wurde nicht verwendet Aufruf...

Jemand ne Idee hierfür?

Mavarik

[Dalai]

TActionList?

MfG Dalai

[Harry Stahl]

Ich verwende hier ein TApplicationEvent-Object in der Mainform. Mit der folgenden Abfrage kann ich die Shortcuts aus dem Main-Manu verwenden und die Alt+Buchstabe-Abfrage machen, um z.B. den entsprechenden Menübandeintrag (Alt+S für "Start") anzeigen zu lassen. Gleichzeitig wird sichergestellt, dass bestimmte Alt (+Strg)-Kombinationen von den üblichen Objekten (z.T. TEdit für "@-Zeichen", das man normalerweise mit Alt+Strg+E aufruft) verarbeitet werden können.

Delphi-Quellcode:

procedure Tfrm_Main.AppEvents1ShortCut(var Msg: TWMKey; var Handled: Boolean);
begin
  //Shortcut für mein nicht angezeigtes MainMenu?
  Handled := Menu1.IsShortCut(Msg);

  //Shortcut bzw. Key kam nicht aus dieser Form, daher hier keine weitere Prüfung
  //und statt dessen Verarbeitung in anderer Form (z.B. MDI)
  if Application.ActiveFormHandle <> self.handle then exit;

  if not handled then begin
    // Alt+Strg gedrückt?
    if (Getkeystate (VK_MENU) shr 15 <> 0) and (Getkeystate (VK_Control) <> 0) then begin
      if (msg.CharCode in [69,81]) then begin  // @ und €-Zeichen wurden gedrückt
        Handled := false;
        exit;
      end;
    end;
  end;

  if not handled then begin
    // Tasten Alt+Buchstaben (A-Z) gedrückt?
    if Getkeystate (VK_MENU) shr 15 <> 0 then begin
      if (msg.CharCode in [65..90]) or (msg.CharCode.ToString = '186') then begin
        handled := True;
        sleep (10);
        // Tatsächliche Verarbeitung in der Form-KeyUp-Prozedur
        FormKeyup(NIL, msg.CharCode, [ssAlt]);
      end;
    end;
  end;
end;

Beispiel für eine Anwendung im anliegenden Screenshot: Mainmenu ist in Form, wird aber nicht angezeigt (Stattdessen arbeite ich mit eigenen Menübändern, nutze aber die Menüeinstellungen des Mainmenus, für die der User auch benutzerdefinierte Einstellungen vornehmen kann, um so z.B. eigene Shortcuts festzulegen).

[Popov]

In jedem Buch alla "Wie diskutiere ich richtig" steht gleich am Anfang der Tipp: vereinbaren sie zuerst ein gemeinsames Glossar, so dass die Wörter für beide das gleiche bedeuten. Sonst reden sie evtl. aneignender vorbei.

Was meinst du mit "Menu funktionalität ohne MainMenu". Du hast kein Menü oder willst du nicht ein Menü aufklappen?

[Dejan Vu]

Komisch, die anderen drei (Dalai, Harry und ich) haben die Frage verstanden. Vielleicht liegts doch an Dir? ;-)

[Popov]

@Dejan Vu

Und jetzt?

[Dejan Vu]

Und jetzt könntest Du deinen Beitrag überdenken. Ne wahr? ;-)

[Daniel]

Alternativ könnte man auch einfach zum Thema zurück kommen. :roll:

[Captnemo]

Zitat:

Zitat von Popov (Beitrag 1303439)

Was meinst du mit "Menu funktionalität ohne MainMenu". Du hast kein Menü oder willst du nicht ein Menü aufklappen?

Der Maverik möchte die Tastaturfunktionalität, die in einem Mainmenu gegeben ist, ohne Mainmenu auf in seinem Programm nutzen.
So hab ich es jedenfalls verstanden.

[Union]

Du könntest das mit RegisterHotkey / WM_HOTKEY machen. Wobei ich nicht weiß, ob diese Hotkeys dann nicht evtl. durch die MDI-Childs verwendeten, gemergeten Menü-Hotkeys übersteuern.

[Mavarik]

Danke für die Antworten...

HotKey nach dem Motto STRG+F2 sind kein Thema sondern eher z.B. Alt+A

Wenn ich in "Meinem Menu" Alt-A drin stehen habe, soll das natürlich nur ausgelöst werden, wenn nicht ein anderes (MDI-Child) Fenster
nicht auch ALT+A benutzt um zum Beinspiel einen Button "@Aufrufen" aus zu lösen.
Ich muss also wissen ob der Accelerator schon "verbraucht" ist.

[Mavarik]

Zitat:

Zitat von Harry Stahl (Beitrag 1303436)

Ich verwende hier ein TApplicationEvent-Object in der Mainform. Mit der folgenden Abfrage kann ich die Shortcuts aus dem Main-Manu verwenden und die Alt+Buchstabe-Abfrage machen, um z.B. den entsprechenden Menübandeintrag (Alt+S für "Start") anzeigen zu lassen. Gleichzeitig wird sichergestellt, dass bestimmte Alt (+Strg)-Kombinationen von den üblichen Objekten (z.T. TEdit für "@-Zeichen", das man normalerweise mit Alt+Strg+E aufruft) verarbeitet werden können.

Das Handel kann die aber nicht die Info geben, oder? Wieso Exit?

Bei einem MDI-Form ist das ActiveFormHandle immer das Form...?!?

[Union]

Das wäre vielleicht ein Ansatz, als Basis habe ich ein mit der "MDI-Anwendung" erstelltes Standardprojekt verwendet. Umgebogen wird Strg+V. Ist ein MDI-Child aktiv, wird der Tastendruck wieder an dieses per PostMessage weitergeleitet.

Delphi-Quellcode:

    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
    const VK_V = $56;      // "V"
    var idVK_V : Integer;
    procedure WMHotKey(var Msg: TWMHotKey); message WM_HOTKEY;

// Implementation
procedure TMainForm.FormCreate(Sender: TObject);
const
  MOD_CONTROL = 2;
begin
  idVK_V := GlobalAddAtom('Control+V');
  RegisterHotKey(Handle, idVK_V, MOD_CONTROL, VK_V);
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  UnregisterHotKey(Handle, idVK_V);
  GlobalDeleteAtom(idVK_V);
end;

procedure TMainForm.WMHotKey(var Msg: TWMHotKey);
begin
  if Msg.HotKey = idVK_V then
  begin
    if ActiveMDIChild <> nil then
    begin
      PostMessage(ActiveMDIChild.Handle, WM_KEYDOWN, VK_CONTROL, 0);
      PostMessage(ActiveMDIChild.Handle, WM_KEYDOWN, VK_V, 0);
      PostMessage(ActiveMDIChild.Handle, WM_KEYUP, VK_CONTROL, 0);
      PostMessage(ActiveMDIChild.Handle, WM_KEYUP, VK_V, 0);
    end
    else
      Showmessage('Strg+V');
  end;
end;

[Perlsau]

Zitat:

Zitat von Captnemo (Beitrag 1303466)

Der Maverik möchte die Tastaturfunktionalität, die in einem Mainmenu gegeben ist, ohne Mainmenu auf in seinem Programm nutzen.

Wird diese Tastaturfunktionalität nicht bereits durch die Verwendung einer TActionList zur Verfügung gestellt? Also wenn ich eine ActionList in meiner Form platziere, dort Aktionen eintrage, selbige mit entsprechenden Hotkeys versehe und die Ereignisbehandlungen dazu schreibe, brauche ich nicht zwangsläufig ein MainMenu, um die Ereignisse auszulösen. Das MainMenu würde hier lediglich der visuellen Darstellung der Menüpunkte dienen, die Mavarick ja explizit nicht wünscht.

@Mavarick: Was meinst du dazu?

[Mavarik]

Zitat:

Zitat von Perlsau (Beitrag 1303505)

Zitat:

Zitat von Captnemo (Beitrag 1303466)

Der Maverik möchte die Tastaturfunktionalität, die in einem Mainmenu gegeben ist, ohne Mainmenu auf in seinem Programm nutzen.

Wird diese Tastaturfunktionalität nicht bereits durch die Verwendung einer TActionList zur Verfügung gestellt? Also wenn ich eine ActionList in meiner Form platziere, dort Aktionen eintrage, selbige mit entsprechenden Hotkeys versehe und die Ereignisbehandlungen dazu schreibe, brauche ich nicht zwangsläufig ein MainMenu, um die Ereignisse auszulösen. Das MainMenu würde hier lediglich der visuellen Darstellung der Menüpunkte dienen, die Mavarick ja explizit nicht wünscht.

@Mavarick: Was meinst du dazu?

Hmm gute Frage muss ich testen..

Was ist ein ein Child Fenster einen La&bel mit Focus Control auf ein TEdit hat...
Kommt der Alt+B noch durch? Was fatal wäre! [Edit] Jo und so ist es auch...

Eine ActionList klaut alle Tasten...

@Union Aufwendig.. Muss ich mir auch näher anschauen...
[EDIT] Leider falsche Reigenfolge..
bzw.. Selbst wenn ein MDI-Child active ist aber die Taste "nicht gebrauchen" kann... Wird diese ja ans Menu weitergeleitet...

[Dalai]

Zitat:

Zitat von Mavarik (Beitrag 1303507)

Eine ActionList klaut alle Tasten...

Naja klar. Genau dazu ist sie da. Du müsstest innerhalb der Behandlungsroutine also noch prüfen, ob das richtige Formular aktiv ist, bevor die Aktion ausgelöst wird.

MfG Dalai

[Mavarik]

Zitat:

Zitat von Dalai (Beitrag 1303511)

Zitat:

Zitat von Mavarik (Beitrag 1303507)

Eine ActionList klaut alle Tasten...

Naja klar. Genau dazu ist sie da. Du müsstest innerhalb der Behandlungsroutine also noch prüfen, ob das richtige Formular aktiv ist, bevor die Aktion ausgelöst wird.

MfG Dalai

Cool... Bei jeder Taste alle offenen MDI-Childs durchsuchen, ob da auf irgendeinem Unterpanel oder Button ein Accelerator gebraucht wird?

[Union]

Zitat:

Zitat von Mavarik (Beitrag 1303507)

Leider falsche Reigenfolge..
bzw.. Selbst wenn ein MDI-Child active ist aber die Taste "nicht gebrauchen" kann... Wird diese ja ans Menu weitergeleitet...

Das macht aber nichts. Wenn das Menü diesen Shortcut nicht bearbeitet, läuft der ja in's Leere.

[Sir Rufo]

Und wieso alle offnen MDIChilds durchsuchen? Das TForm.ActiveMDIChild sollte da doch genügen.

Man kann natürlich auch Funktionen über ein Interface zur Verfügung stellen:

Delphi-Quellcode:

IPrintable = interface
  [{GUID}]
  function CanPrint : Boolean;
  procedure DoPrint;
end;

und dann ganz simpel abfragen

Delphi-Quellcode:

procedure TMainForm.PrintActionExecute(Sender:TObject);
var
  LPrintable : IPrintable;
begin
  if Supports( ActiveMDIChild, IPrintable, LPrintable ) then
    LPrintable.DoPrint;
end;

procedure TMainForm.PrintActionExecute(Sender:TObject);
var
  LPrintable : IPrintable;
begin
  TAction( Sender ).Enabled := Supports( ActiveMDIChild, IPrintable, LPrintable ) and LPrintable.CanPrint;
end;

[Sir Rufo]

Eine weitere Alternative ist das Versenden einer Nachricht

Delphi-Quellcode:

unit UserCommand;

interface

uses
  System.Messaging;

type
{$SCOPEDENUMS ON}
  TUserCommand = ( Print, Save, SaveAs );

  TUserCommandMessage = class( TMessage )
  private
    FCommand: TUserCommand;
    FIsQuery: Boolean;
    FHandled: Boolean;
  public
    constructor Create( ACommand : TUserCommand; AIsQuery : Boolean = False );
    property Command: TUserCommand read FCommand;
    property IsQuery: Boolean read FIsQuery;
    property Handled: Boolean read FHandled write FHandled;
  end;

implementation

{ TUserCommandMessage }

constructor TUserCommandMessage.Create(ACommand: TUserCommand;
  AIsQuery: Boolean);
begin
  inherited Create;
  FCommand := ACommand;
  FIsQuery := AIsQuery;
  FHandled := False;
end;

end.

die von der Action verschickt wird

Delphi-Quellcode:

procedure TMainForm.FilePrint1Execute( Sender: TObject );
begin
  TMessageManager.DefaultManager.SendMessage( Self, TUserCommandMessage.Create( TUserCommand.Print ), True );
end;

procedure TMainForm.FilePrint1Update( Sender: TObject );
var
  LCmd: TUserCommandMessage;
begin
  LCmd := TUserCommandMessage.Create( TUserCommand.Print, True );
  try
    TMessageManager.DefaultManager.SendMessage( Self, LCmd, False );
    TAction( Sender ).Enabled := LCmd.Handled;
  finally
    LCmd.Free;
  end;
end;

und von den Empfängern entsprechend behandelt wird

Delphi-Quellcode:

procedure TMDIChild.AfterConstruction;
begin
  inherited;
  TMessageManager.DefaultManager.SubscribeToMessage( TUserCommandMessage, HandleUserCommand );
end;

procedure TMDIChild.BeforeDestruction;
begin
  TMessageManager.DefaultManager.UnSubscribe( TUserCommandMessage, HandleUserCommand );
  inherited;
end;

procedure TMDIChild.HandleUserCommand( const Sender: TObject; const M: TMessage );
var
  LCmd: TUserCommandMessage absolute M;
begin
  if not Self.Active then
    Exit;

  case LCmd.Command of
    TUserCommand.Print:
      if LCmd.IsQuery then
        LCmd.Handled := ( Memo1.Text <> '' );
      else
        // Dokument drucken
    TUserCommand.Save:
      ;
    TUserCommand.SaveAs:
      ;
  end;

end;

Das geht dann ohne Interfaces ... :)

[Mavarik]

Zitat:

Zitat von Union (Beitrag 1303525)

Zitat:

Zitat von Mavarik (Beitrag 1303507)

Leider falsche Reigenfolge..
bzw.. Selbst wenn ein MDI-Child active ist aber die Taste "nicht gebrauchen" kann... Wird diese ja ans Menu weitergeleitet...

Das macht aber nichts. Wenn das Menü diesen Shortcut nicht bearbeitet, läuft der ja in's Leere.

Ne umgekehrt... Erst wenn kein Fenster es gebrauchen kann, darf das "Menue" die Taste nutzen!

[Harry Stahl]

Zitat:

Zitat von Mavarik (Beitrag 1303490)

Zitat:

Zitat von Harry Stahl (Beitrag 1303436)

Ich verwende hier ein TApplicationEvent-Object in der Mainform. Mit der folgenden Abfrage kann ich die Shortcuts aus dem Main-Manu verwenden und die Alt+Buchstabe-Abfrage machen, um z.B. den entsprechenden Menübandeintrag (Alt+S für "Start") anzeigen zu lassen. Gleichzeitig wird sichergestellt, dass bestimmte Alt (+Strg)-Kombinationen von den üblichen Objekten (z.T. TEdit für "@-Zeichen", das man normalerweise mit Alt+Strg+E aufruft) verarbeitet werden können.

Das Handle kann die aber nicht die Info geben, oder? Wieso Exit?

Bei einem MDI-Form ist das ActiveFormHandle immer das Form...?!?

Welche Info meinst Du?

Die Abfrage auf ActiveFormHandle erfolgt, weil ich im Hauptformular neben MDI-Fenstern auch noch normale Formulare habe, welche auch einen modalen Fokus haben können (das sind Einstellflächen als Alternative zu modalen Dialogen, aber eben innerhalb der Form). Dann sollen natürlich Shortcuts nicht ausgeführt werden können (daher dann Exit).

Habe hier übrigens beim rüber kopieren aus meinem Source die Abfrage auf das Formhandle versehentlich hinter die IsShortCut-Abfrage kopiert, richtig muss es aber so lauten:

Delphi-Quellcode:

procedure THauptformular.ApplicationEvents1ShortCut(var Msg: TWMKey;
  var Handled: Boolean);
begin
  if Application.ActiveFormHandle <> self.handle then exit;

  handled := MainMenu1.IsShortCut(Msg);

  ...

Jedenfalls funktioniert hier die Nutzung von Actions, Shortcuts (aus ActionList oder dem unsichtbaren Mainmenu), Tastaturabfragen für Form, MDI, integrierte Forms usw. wie gewünscht.