Funktion / Stream in Richmemo laden ( Lazarus )

[manfred_h]

Hallo zusammen

vor einiger Zeit habe ich damit begonnen meine Delphianwendung nach Lazarus zu migrieren.
Da ich in Lazarus keine Richtext-Memokomponente mit DB anbindung gefunden habe verwende ich richmemo http://wiki.lazarus.freepascal.org/RichMemo

Ich verwende gerade diese Funktion ( die noch unschön ist ).

Delphi-Quellcode:

procedure TDM.rtf_stream_load(aTable: TDAMemDataTable; aField: String);
var
    rtfString : String;
begin
     //Get the data from the database as AnsiString
     rtfString := aTable.FieldByName(aField).AsAnsiString;

     //Write the string into a stream
     stream := TMemoryStream.Create;
     stream.Clear;
     stream.Write(PAnsiChar(rtfString)^, Length(rtfString));
     stream.Position := 0;

     //aForm.aElement.LoadRichText(stream);

     //stream.Free;
end;

Der Aufruf erfolgt so:

Delphi-Quellcode:

procedure TDM_testimony.rtf_stream_read(Sender: TObject);
begin
     DM.rtf_stream_load(tbl_testimony,'TESTIMONY');
     frm_testimony.RichMemo1.LoadRichText(stream);

     stream.Free;
end;

Frage:
Wie kann ich der Funktion auch noch das zu verwendende Form übergeben?

Danke für Eure Tipps.:P

[Perlsau]

Wozu mußt du TForm übergeben? Du machst dir im Datemodul eine Funktion, die den Tabellennamen, den Datensatz-Identifier (Primary-Key) und den Stream entgegennimmt, den Stream dann befüllt und bei Erfolg True zurückgibt. Zum Speichern des Memo-Inhalts machst du dir eine Kopie dieser Funktion und baust sie derart um, daß der Stream in der Datenbank gespeichert wird:

Delphi-Quellcode:

// ----- Übergibt den Inhalt eines Blobfelds an Stream
Function TDatMod.BlobToStream(Stream: TMemoryStream; Feld: TField): Boolean;
Var
  S : TStream;
begin
   Result := False;
   If Not Feld.IsBlob Then Exit;
   If Feld.IsNull     Then Exit;

   S := Nil;

   Try
     S := Feld.DataSet.CreateBlobStream(Feld, bmRead);
     Stream.Clear;
     Stream.CopyFrom(S,S.Size);
     Result := True;
   Finally
     S.Free;
   End;
end;

// ----- Übergibt den Inhalt eines Streams
Function TDatMod.StreamToBlob(Stream: TMemoryStream; Feld: TField): Boolean;
Var
  S : TStream;
begin
   Result := False;
   If Not Feld.IsBlob Then Exit;
   S := Nil;

   Try
     S := Feld.DataSet.CreateBlobStream(Feld, bmReadWrite);
     S.CopyFrom(Stream,Stream.Size);
     Result := True;
   Finally
     S.Free;
   End;
end;

Bei mir fehlt die Lokalisierung des Datensatzes, weil ich in meinen Anwendungen bereits in jeweiligen Datensatz bin. Auch die Übergabe des Tabellennamens erübrigt sich, wenn man das Feld vom Typ TField übergibt:

Delphi-Quellcode:

Procedure MemoAktualisieren;
Var
  Feld : TField;
  S : TMemoryStream;

begin
  Feld := DatenModul.MyQuery.FieldByName('BEMERKUNGEN');
  S := TMemoryStream.Create;

  Try
    Memo.Lines.SaveToStream(S);
    If Not DatenModul.BlobToStream(S,Feld) Then
    ShowMessage('Fehler');
  Finally;
    S.Free;
  End;
end;

Den Stream kannst du dann jeweils mit LoadFromStream bzw. SaveToStream ins Memo einlesen bzw. aus dem Memo extrahieren.

Nachtrag: Dein geposteter Quelltest enthält keine Functions, sondern lediglich zwei Procedures. Will man beide, Function und Procedure, die zu einer Klasse gehören, umschreiben, spricht man von Methoden.

Alles ungetestet.

[mkinzler]

Einfach einen weiteren Parameter hinzufügen.

[manfred_h]

Danke für die Tipps.
Werde es gleich bei mir testen. :thumb:

[manfred_h]

Versuche nur meine Ursprüngliche Idee zum laufen zu bringen...
Irgendwie fehlt mir da das Grundverständniss.....

Delphi-Quellcode:

procedure TDM.rtf_stream_load(aTable: TDAMemDataTable; aField: String; aForm: TForm; aComponent: TObject);
var
    rtfString : String;
begin
     //Get the data from the database as AnsiString
     rtfString := aTable.FieldByName(aField).AsAnsiString;

     //Write the string into a stream
     stream := TMemoryStream.Create;
     stream.Clear;
     stream.Write(PAnsiChar(rtfString)^, Length(rtfString));
     stream.Position := 0;

     aForm.aComponent.LoadRichText(stream);
     //
     stream.Free;

end;

Ich erhalte hier:

Code:

udm.pas(229,12) Error: identifier idents no member "aComponent"

Sorry wenn ich da nochmals nachfrage:oops:

[mkinzler]

Die Angabe der Form ist auch nicht nötig. Dafür aber ein cast auf die richtige Kllase bzw. gleich die richtige Vorgabe auf eine Komponenetnklasse, welche die Methode unterstützt.

[manfred_h]

Danke schon mal...
Hab's ein wenig angepasst.. Bin mir nur nicht sicher wie ich das mit der Form mache....

Delphi-Quellcode:

procedure TDM.rtf_stream_load(aTable: TDAMemDataTable; aField: String; ARichMemo: TCustomRichMemo);
var
    rtfString : String;
begin
     //Get the data from the database as AnsiString
     rtfString := aTable.FieldByName(aField).AsAnsiString;

     //Write the string into a stream
     stream := TMemoryStream.Create;
     stream.Clear;
     stream.Write(PAnsiChar(rtfString)^, Length(rtfString));
     stream.Position := 0;

     ARichMemo.LoadRichText(stream);
     //
     stream.Free;
end;

Der Aufruf:

Delphi-Quellcode:

procedure TDM_testimony.rtf_stream_read(Sender: TObject);
begin
    DM.rtf_stream_load(tbl_testimony,'TESTIMONY',RichMemo1);
end;

Ich erhalte den Fehler:

Code:

udm_testimony.pas(137,64) Error: Identifier not found "RichMemo1"

Ich hab Ihm ja auch nicht gesagt wo die Richmemo liegt... :?

[manfred_h]

Habs...:P

Der Aufruf war falsch...

Delphi-Quellcode:

procedure TDM_testimony.rtf_stream_read(Sender: TObject);
begin
    DM.rtf_stream_load(tbl_testimony,'TESTIMONY',frm_testimony.RichMemo1);
end;

Besten Dank für Eure Hilfe:thumb:

[DeddyH]

Wieso übergibst Du eigentlich Tabellen- und Feldnamen statt gleich das Feld, das eigentlich gemeint ist?

[manfred_h]

Guten Morgen

Code:

Wieso übergibst Du eigentlich Tabellen- und Feldnamen statt gleich das Feld, das eigentlich gemeint ist?

DM.rtf_stream_load(tbl_testimony,'TESTIMONY',frm_t estimony.RichMemo1);

tbl_testimony: TDAMemDataTable
TESTIMONY: Feldname
frm_testimony: Formname
RichMemo1: Name der Komponente

Was darf dann hier fehlen?

[mkinzler]

Man könnte auch direkt die TField-Instanz übergeben:

Delphi-Quellcode:

procedure TDM.rtf_stream_load( aField: TField; ARichMemo: TCustomRichMemo);

Delphi-Quellcode:

DM.rtf_stream_load(tbl_testimony.FieldByName('TESTIMONY'),frm_testimony.RichMemo1);

[manfred_h]

Hört sich gut an.
Danke für den Tipp.

Shalom
Manfred

[manfred_h]

Noch eine Frage

Habe eben diesen Post gefunden:
http://www.delphipraxis.net/107884-m...eichern-2.html

Bietet TReader, TWriter vorteile gegenüber meiner gefundenn Lösung?

Delphi-Quellcode:

procedure TForm1.ButtonLadenClick(Sender: TObject); 
Var Stream:TFilestream; 
begin 
  Stream:=TFileStream.Create('D:\TestStream',fmOpenRead or fmShareDenyNone); 
  try 
    //TReader objekt erstellen und Daten aus den Stream laden 
    with TReader.create(Stream,1024) do 
      try 
        Memo1.Text := ReadString; 
        Edit1.Text := ReadString; 
        SpinEdit1.Value := ReadInteger; 
        CheckBox1.Checked := ReadBoolean; 
      finally 
        free; 
      end; 
   finally 
     Stream.free; 
   end; 
end;

Delphi-Quellcode:

procedure TForm1.ButtonSpeichernClick(Sender: TObject); 
Var Stream:TFilestream; 
begin 
  Stream:=TFileStream.Create('D:\TestStream',fmcreate); 
  try 
    //TWriter objekt erstellen und Daten in den Stream speichern 
    with TWriter.create(Stream,1024) do 
      try 
        WriteString(Memo1.Text); 
        WriteString(Edit1.Text); 
        WriteInteger(SpinEdit1.Value); 
        WriteBoolean(CheckBox1.Checked); 
      finally 
        free; 
      end; 
   finally 
     Stream.free; 
   end; 
end;

[Perlsau]

Manfred, wieso probierst du nicht einfach die Universal-Lösung, die ich oben bereits gepostet hatte, einmal aus? Diese beiden Methoden kannst du für alle Blob-To-Stream- und Stream-To-Blob-Aufgaben einsetzen. Du mußt lediglich den Stream und das Feld übergeben. Das Feld legst du in der aufrufenden Methode fest:

Delphi-Quellcode:

Procedure TForm1.AufrufendeMethode(Sender : TObject);
Var
  Feld : TField;
  S : TMemoryStream;
begin
  S := TMemoryStream.Create;
  Try
    Feld := DatenModul.MyQuery.FieldByName('MeinBlobFeld'); // oder wie auch immer deine Tabellenkomponente und dein Blobfeld benannt sind
    Memo.Lines.SaveToStream(S);
    If Not DatenModul.StreamToBlob(S,Feld) Then
       ShowMessage('Fehler'); // oder eben ein globaler Fehlerstring, wie ich ihn verwende
  Finally
    S.Free;
  End;
end;

Wenn du das Feld angibst, mußt du weder Tabellenname noch sonstwas übergeben, denn das Feld führt ja ein Property mit, welches das Dataset beinhaltet: Feld.Dataset. Du mußt also nicht mit der Kirche ums ganze Dorf fahren :)

Ungetestet, da nur schnell als Beispiel reingetippt ...

[manfred_h]

Hallo Perlsau

Hab Deinen Vorschlag nicht vergessen und auch schon ausprobiert.
"Meine" urspründliche Lösung war für mich nur verständlicher.
Aber ich versuche auch gerne die von Dir nochmals angepasste Version.
Danke Nochmals für Deinen Tipp. :thumb:

Zitat:

Du mußt also nicht mit der Kirche ums ganze Dorf fahren

Immer gut wenn man die Kirche im Dorf lässt. ;-)

Shalom
Manfred

[Sir Rufo]

Ich weiß ja nicht, ob das unter Lazarus auch geht, aber ein ganz simples

Delphi-Quellcode:

RichMemo1.Lines.Assign( DBField1 );

macht das unter Delphi genauso (ist nur kürzer in der Schreibweise).

Und zurück geht das mit

Delphi-Quellcode:

DBField1.Assign(RichMemo1.Lines);

.

[manfred_h]

Delphi-Quellcode:

RichMemo1.Lines.Assign( DBField1 )

Sieht ja super kurz aus. :-D
Erhalte aber den Fehler :
Cannot assign a TDAField to a TWin32RichMemoString.

Muss das Morgen mal anschauen.

[mkinzler]

Funktioniert es mit RichMemo1.Lines.Assign( DBField1.asString ) ?

[Sir Rufo]

Voraussetzung dafür ist natürlich das Lines ein Nachfahr von

Delphi-Quellcode:

TStrings

ist und das Feld ein

Delphi-Quellcode:

TBlobField

.

So geht es auf jeden Fall mit Delphi, dort findet man das in den Sourcen bei

Delphi-Quellcode:

TBlobField.Assign

und

Delphi-Quellcode:

TBlobField.AssignTo

.

[manfred_h]

Habe es getestet:

Delphi-Quellcode:

frm_testimony.RM_Testimony.Lines.Assign( tbl_testimony.FieldByName('TESTIMONY').AsString)

Erhalte aber leider die Fehlermeldung:
Error: Incompatible type for arg no. 1: Got "WideString", expected "TPersistent"

[Sir Rufo]

Zitat:

Zitat von mkinzler (Beitrag 1316005)

Funktioniert es mit RichMemo1.Lines.Assign( DBField1.asString ) ?

Für einen Aprilscherz ist es jetzt aber zu spät oder zu früh :shock:

Dokumentation zu TPersistent.Assign (da wird diese Methode eingeführt).