uhr in delphi--> wie die zeiger?

[XeRo]

Ich hab ein problem...ich wollte jetzt mal nebenbei eine uhr in delphi programmieren, mit stunden, minuten und sekunden zeiger, aber ich anscheinend zu blöd... :wall:

1) Wie kann ich einen zeiger proggren, der sich von einem punkt aus kreisförmig um sich selbst dreht:?:

2) Wie unterteile ich diese Rotation dann in Sekunden, Minuten u. Stunden Schritte. :?:

[edit]verdammte rechtschreibung :evil: [/edit]

[Neuni]

Also 2. is doch ganz einfach, denk ich...

1. Einfach nen timer, der dann jede Sekunde eine Variable (die die Sekunden angibt) um 1 erhöht.

2. Wenn die Variable bi 60 ist (wegen 60 Sek. = 1 Minute :)), dann erhöht man die nächste Variable (die gibt die Minuten an) um 1, und stellt die 1 Variable wieder auf 1.

3. Wenn die 2. Variable (für die Minuten) bei 60 ist, erhöht sie eine Variable (die Variable für die Stunden) um 1 und setzt die für die Minuten wieder auf 0.

So zählt der Schon mal.

Nun müsste halt der zeiger für die Sekunden je nach Inhalt der Variable auf eine gewisse Position gesetzt werden.
:!: Mit dem Minutenzeiger und dem Std. Zeiger dann das selbe :!:

Wie sich der Zeiger nu dreht...keine Ahnung.

[Tortus]

Zu 1): Zuerst die Sekunden per dreisatz auf 360 umrechnen (ein kreis hat bekanntlich 360°) und dann setze man die Kreisfunktionen Sinus und cosinus ein, um sich die Kreiskoordinaten zu berechnen. Wenn dus net inner Schule gelernt hast, sinus cosinus, da gibts nen paar schöne Java's, die einem die sachen gut verdeutlichen, so habichs auch gelernt. Naja, wir machens eh demnächst inner Schule, dann hab ich schon vorsprung :-D

[alcaeus]

Bsp. Minutenzeiger:
Ein Kreis = 360° = 1 Stunde
Daraus folgt: 1 Minute = 1/60 Stunde = 360°/60 = 6°

Somit hast du schon einmal den Winkel. Der Startpunkt des Zeigers sei (x0|y0)
(x1|y1) sei die Zielposition...daraus folgt:

x1 := x0+Round(Radius*cos(Winkel));
y1 := y0+Round(Radius*sin(Winkel));

Wichtig: Minute 0 wäre ein Winkel von 90°, 15 wäre 0, 30 ist 270, 45 Minuten sind 180 Grad. Darauf musst du noch achten.

Sobald du die Position hast, zeichnest du eine Schwarze Linie von (x0|y0) nach (x1|y1). Vor dem Neuzeichnen musst du aber den alten Zeiger überzeichnen.

[edit]Hoppla, da war wohl jemand etwas schneller...[/edit]

[Wheelie]

Wenn du eine richtige Analoguhr proggen willst, dann hilft dir das bestimmt weiter:

Delphi-Quellcode:

procedure TForm1.Berechne_stunde(winkel: Real;
                             var xi, yi: Integer);
var x,y: Real;
begin
  winkel := winkel - pi / 2;

  x := Cos(Winkel);
  y := Sin(Winkel);
  x := x * (Width div 4);
  y := y * (Height div 4);
  x := x + (Width div 2);
  y := y + (Height div 2);

  xi := Trunc(x);
  yi := Trunc(y);
end;

procedure TForm1.Berechne_xy(winkel: Real;
                             var xi, yi: Integer);
var x,y: Real;
begin
  winkel := winkel - pi / 2;

  x := Cos(Winkel);
  y := Sin(Winkel);
  x := x * (Width div 3);
  y := y * (Height div 3);
  x := x + (Width div 2);
  y := y + (Height div 2);

  xi := Trunc(x);
  yi := Trunc(y);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
var winkel: Integer;
    hour, min, sec, msec: Word;
    x, y: Integer;
begin
  Refresh;

  Label1.Caption := DateToStr(Now);
  Label2.Caption := TimeToStr(Now);
  DecodeTime(Now, hour, min, sec, msec);

  //Sekundenzeiger zeichnen
  Berechne_xy(((2 * Pi) / 60) * sec, x, y);
  Canvas.Pen.Color:=clNavy;
  Canvas.Pen.Width := 1;
  Canvas.MoveTo(Width div 2, Height div 2);
  Canvas.LineTo(x, y);

  //Minutenzeiger zeichnen
  Berechne_xy(((2 * Pi) / 60) * min, x, y);
  Canvas.Pen.Color:=clBlack;
  Canvas.Pen.Width := 2;
  Canvas.MoveTo(Width div 2, Height div 2);
  Canvas.LineTo(x, y);

  //Stundenzeiger zeichnen
  if hour > 12 then hour := hour - 12;
  Berechne_stunde(((2 * Pi) / 12) * hour, x, y);
  Canvas.Pen.Color:=clBlack;
  Canvas.Pen.Width := 3;
  Canvas.MoveTo(Width div 2, Height div 2);
  Canvas.LineTo(x, y);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DoubleBuffered := True;  // Damit flackern die Zeiger nicht so ;)
end;

[XeRo]

Vielen Dank...werd eure beiträge jetzt mal durcharbeiten

[sCrAPt]

hiho

@Wheelie: hast du den code aus "Jetzt lerne ich Delphi" von Markt+Technik ?

:angle:, sCrAPt

[Wheelie]

Zitat:

Zitat von sCrAPt

hiho

@Wheelie: hast du den code aus "Jetzt lerne ich Delphi" von Markt+Technik ?

:angle:, sCrAPt

du weißt auch alles :lol:

habe den code diesem schönen buch entnommen:

http://images-eu.amazon.com/images/P...3.LZZZZZZZ.jpg

[sCrAPt]

hiho

ich kenn mein buch in und auswendig :D

:angle:, sCrAPt

[sCrAPt]

hiho

Habs ein bischen total überarbeitet...

pbUhr war bei mir eine (T)Paintbox (größe is egal)

Delphi-Quellcode:

procedure TForm1.Timer1Timer(Sender: TObject);
  procedure Berechne_xy(Winkel: real; Art: real; var xi, yi: integer);
  // Empfohlende Art-Werte:
  // Stunde: 0.48
  // Minute: 0.38
  // Sekunde: 0.28
  var
    x, y: real;
  begin
    Winkel := Winkel - pi / 2;
    x := Cos(Winkel);
    y := Sin(Winkel);

    x := x * (pbUhr.Width * art);
    y := y * (pbUhr.Height * art);
    x := x + (pbUhr.Width div 2);
    y := y + (pbUhr.Height div 2);

    xi := trunc(x);
    yi := trunc(y);
  end;
const
  stundenzeigercl = clred;
  minutenzeigercl = clblue;
  sekundenzeigercl = cllime;
  uhrkreiscl = $000080FF;
  mittelpunktcl = clblack;
  umkreisstrichecl = clyellow;
var
  std, min, sek, msek: word;
  x, y, winkel: integer;
begin
  DecodeTime(now, std, min, sek, msek);
  if std > 12 then dec(std, 12);

  with pbUhr do
  begin
    Refresh;

    Canvas.Pen.Color := uhrkreiscl;
    Canvas.Ellipse(0, 0, pbUhr.Width, pbUhr.Height);

    // Stunden
    Berechne_xy(((2 * pi) / 12) * std, 0.48, x, y);
    canvas.Pen.Color := stundenzeigercl;
    canvas.MoveTo(width div 2 - 2, height div 2);
    canvas.LineTo(x, y);

    // Minuten
    Berechne_xy(((2 * pi) / 60) * min, 0.38, x, y);
    canvas.Pen.Color := minutenzeigercl;
    canvas.MoveTo(width div 2 - 2, height div 2);
    canvas.LineTo(x, y);

    // Sekunden
    Berechne_xy(((2 * pi) / 60) * sek, 0.28, x, y);
    canvas.Pen.Color := sekundenzeigercl;
    canvas.MoveTo(width div 2 - 2, height div 2);
    canvas.LineTo(x, y);

    // Design
    Canvas.Brush.Color := mittelpunktcl;
    Canvas.Pen.Color := mittelpunktcl;
    Canvas.Ellipse(pbUhr.Width div 2 - 4, pbUhr.Height div 2 - 4, pbUhr.Width div 2 + 2, pbUhr.Height div 2 + 2);

    Canvas.Pen.Color := umkreisstrichecl;
    Canvas.MoveTo(width div 2, 1);
    Canvas.LineTo(width div 2, 5);

    Canvas.MoveTo(width - 5, height div 2);
    Canvas.LineTo(width - 1, height div 2);

    Canvas.MoveTo(width div 2, height - 5);
    Canvas.LineTo(width div 2, height + 1);

    Canvas.MoveTo(5, height div 2);
    Canvas.LineTo(1, height div 2);
  end
end;

^^ Viel Spaß damit :D

:angle:, sCrAPt

[KingofWerlte]

würde aber auch anders gehn ohne die procedur berechne_xy

Delphi-Quellcode:

procedure TForm1.Timer1Timer(Sender: TObject);
VAR winkel: Real;
    x, y, x1, y1, r, i: Integer;
    hour, min, sec, msec: Word; 

begin
Form1.Caption := DateTimeToStr(Now);

        (*alte Grafik löschen*) 
        Refresh; 

        (*Einpssen des Kreises in das Fenster*) 
         if Width <= Height 
                then r := Width div 3 
                else r := Height div 3; 


        (*Umwandlung in einzelne Integer-Werte*) 
        DecodeTime(Now, hour, min, sec, msec); 

        (*Sekundenzeiger*) 
        winkel := sec * (((2 * pi) / 60)) - pi / 2; 

        x := Trunc(Cos(winkel)* r); 
        y := Trunc(Sin(winkel)* r); 

        x := x + (Width div 2); 
        y := y + (Height div 2); 

        Canvas.Moveto(Width div 2, Height div 2); 
        Canvas.LineTo(x, y); 

        (*Minutenzeiger*) 
        winkel := min * (((2 * pi) / 60)) - pi / 2; 

        x := Trunc(Cos(winkel)* r); 
        y := Trunc(Sin(winkel)* r); 

        x := x + (Width div 2); 
        y := y + (Height div 2); 

        Canvas.Moveto(Width div 2, Height div 2); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2) + 1, (Height div 2) + 1); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2) + 1, (Height div 2) - 1); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2 - 1), (Height div 2) + 1); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2 - 1), (Height div 2) - 1); 
        Canvas.LineTo(x, y); 

        (*Stundenzeiger*) 
        if hour > 12 then hour := hour -12; 
        winkel := (hour * (2 * pi) / 12) + (min * (2 * pi) / 720) - pi / 2; 

        x := Trunc(Cos(winkel)* r * 0.61); 
        y := Trunc(Sin(winkel)* r * 0.61); 

        x := x + (Width div 2); 
        y := y + (Height div 2); 

        Canvas.Moveto(Width div 2, Height div 2); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2) + 1, (Height div 2) + 1); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2) + 1, (Height div 2) - 1); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2 - 1), (Height div 2) + 1); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2 - 1), (Height div 2) - 1); 
        Canvas.LineTo(x , y); 
        Canvas.Moveto((Width div 2) + 2, (Height div 2) + 2); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2) + 2, (Height div 2) - 2); 
        Canvas.LineTo(x , y); 
        Canvas.Moveto((Width div 2 - 2), (Height div 2) + 2); 
        Canvas.LineTo(x, y); 
        Canvas.Moveto((Width div 2 - 2), (Height div 2) - 2); 
        Canvas.LineTo(x , y); 

        (*Mittelpunkt*) 
        Canvas.Ellipse((Width div 2)-4, (Height div 2)-4,(Width div 2)+ 4,(Height div 2)+ 4); 

        (*Ziffernstriche*) 
         i := 0; 
         FOR i := 0 TO 11 DO 
         begin 
         winkel := i * (((2 * pi) / 12)) - pi / 2; 

         x := Trunc(Cos(winkel)* 1.1*r); 
         x1 := Trunc(Cos(winkel)* r); 
         y := Trunc(Sin(winkel)* 1.1*r); 
         y1 := Trunc(Sin(winkel)* r); 

         x := x + (Width div 2); 
         x1 := x1 + (Width div 2); 
         y := y + (Height div 2); 
         y1 := y1 + (Height div 2); 
        Canvas.Moveto(x, y); 
        Canvas.LineTo(x1, y1); 
         end; 

        (*Minutenpunkte*) 
         i := 0; 
         FOR i := 0 TO 59 DO 
         begin 
         winkel := i * (((2 * pi) / 60)) - pi / 2; 

         x := Trunc(Cos(winkel)* 1.1*r); 
         y := Trunc(Sin(winkel)* 1.1*r); 

         x := x + (Width div 2); 
         y := y + (Height div 2); 
          Canvas.Pixels[x, y] := clRed; 
         Canvas.Ellipse(x-2, y-2,x+2,y+2); 
         end; 


end;

procedure TForm1.FormCreate(Sender: TObject);
begin
DoubleBuffered := True;
end;

end.

[Lillebrohr]

Hi,

scrapt schrieb:

Zitat:

ich kenn mein buch in und auswendig

AutorOfBook := scrapt; ????

[XeRo]

Zitat:

Zitat von Lillebrohr

Hi,

scrapt schrieb:

Zitat:

ich kenn mein buch in und auswendig

AutorOfBook := scrapt; ????

:mrgreen:

so...nachdem ich jetzt genug wuelltext hab werd ich mal alle austesten und dann auch versuchen selbst einen zu schreiben...

[sCrAPt]

Zitat:

Zitat von Lillebrohr

Hi,

scrapt schrieb:

Zitat:

ich kenn mein buch in und auswendig

AutorOfBook := scrapt; ????

1. Ich heiß Robert, nicht Thomas ;)
2. Ab bisle zu jung um ein solches Buch rauszubringen :gruebel:
3. Ich beherrsche die Rechtschreibung genau so wenig wie meine Lampe...

^^ raise exception.create('''sCrAPt'' ist ein unzulässiger Autorname für das Buch');

@KingofWerlte: Meinet wegen kannste es auch in ASM schreiben ;)

:angle:, sCrAPt

[XeRo]

Ich will euch ja nicht zu nahe treten,aber wenn dass ein admin ließt, dann heißt es wieder: Offtopic :wink:

[KingofWerlte]

@sCrAPt rofl :mrgreen:

[Mr_Anderson]

Ich habe im internet auch noch einen Code für eine Klasse gefunden, jedoch sagt mit die klasse TRect nichts. Welchen Wert erwartet man wenn man eine Variable die Klasse TRect zuweist?

Anfgefügt habe ich den quellcode
//Edit:
Hab nun einen Tipp von einem "DPUser" erhalten :P
also dass ich einfach

Delphi-Quellcode:

kor.Top := 100;
kor.Left:= 200;
kor.Right:=100;
kor.Bottom:=100;

so eine TRect Variable aussehen kann, jedoch stürzt das Programm mit einer zugriffsverletzung ab:

Delphi-Quellcode:

test.Create(kor,Form1);

MfG

Delphi-Quellcode:

uses Forms,    {TForm}
     Windows,
     Messages,
     SysUtils,
     Variants,
     Classes,
     Controls,
     Dialogs,
     ExtCtrls,
     math,
     Graphics; {TCanvas, TColor}

type TClock = class (TObject)
  private
    FPicture: TPicture;
    FBrush,FPen  : TColor;
    FBack,FClock,FImage: TImage;
    FTimer: TTimer;
    procedure Circle;
    procedure FOnTimer(Sender: TObject);
    procedure SetBrush(AValue: TColor);
    procedure SetPen(AValue: TColor);
    procedure SetPicture(AValue: TPicture);
  public
    constructor Create(const ARect: TRect; const AParent: TWinControl);
    destructor Destroy; override;
  published
    property BrushColor: TColor read FBrush write SetBrush;
    property PenColor: TColor read FPen write SetPen;
    property Picture: TPicture read FPicture write SetPicture;
  end; //TClock

implementation

constructor TClock.Create(const ARect: TRect; const AParent: TWinControl);
begin
  inherited Create;
  FPen := clBlack;
  FBrush := clWhite;
  FPicture := TPicture.Create;
  FBack := TImage.Create(AParent);
  FClock := TImage.Create(AParent);
  FImage := TImage.Create(AParent);
  with FBack do
  begin
    Parent := AParent;
    Left := ARect.Left;
    Top := ARect.Top;
    Width := ARect.Right - Left;
    if Width < 50 then
      Width := 50;
    Height := ARect.Bottom - Top;
    if Height < 50 then
      Height := 50;
  end;
  with FClock do
  begin
    Parent := AParent;
    Transparent := TRUE;
    Left := FBack.Left;
    Top := FBack.Top;
    Width := FBack.Width;
    Height := FBack.Height;
    Circle;
  end;
  with FImage do
  begin
    Transparent := TRUE;
    Parent := AParent;
    Left := FBack.Left;
    Top := FBack.Top;
    Width := FBack.Width;
    Height := FBack.Height;
    Canvas.Pen.Width := (Width + Height) div 100;
  end;
  FTimer := TTimer.Create(AParent);
  with FTimer do
  begin
    Interval := 1000;
    OnTimer := FOnTimer;
    Enabled := TRUE;
  end;
end; //TClock.Create

procedure TClock.Circle;
begin
  with FClock do
    with Canvas do
    begin
      Pen.Width := (Width + Height) div 100;
      Pen.Color := Parent.Brush.Color;
      Brush.Color := Parent.Brush.Color;
      Font.Style := Font.Style + [fsBold];
      Font.Size := (Width + Height) div 30;
      Font.Color := FPen;
      Rectangle(Rect(Left, Top, Left + Width, Top + Height));
      Pen.Color := FPen;
      if (FBack.Picture.Graphic = nil) or
        (FBack.Picture.Graphic.Empty) then
        Brush.Color := FBrush;
      Ellipse(Rect(Left, Top, Left + Width, Top + Height));
      TextOut((Width - TextWidth('12')) div 2, Pen.Width + 2, '12');
      TextOut((Width - TextWidth('6')) div 2, Height - TextHeight('6') - Pen.Width, '6');
      TextOut(Left + 2 + Pen.Width, (Height - TextHeight('9')) div 2, '9');
      TextOut(Width - TextWidth('3') - 2 - Pen.Width, (Height - TextHeight('3')) div 2, '3');
    end;
end; //TClock.Circle

procedure TClock.FOnTimer(Sender: TObject);
var
  Default: Integer;
  Hour,
  Min,
  Sec,
  MSec: Word;
begin
  DecodeTime(Now, Hour, Min, Sec, MSec);
  Sec := Sec * 6;
  Min := Min * 6;
  Hour := Hour * 30;
  with FImage do
  begin
    with Canvas do
    begin
      if FPen <> clWhite then
        CopyMode := cmWhiteness
      else
        CopyMode := cmBlackness;
      CopyRect(FImage.BoundsRect, Canvas, FImage.BoundsRect);
      Pen.Color := FPen;
      MoveTo(Width div 2, Height div 2);
      LineTo(Width div 2 + Trunc(Sin(DegToRad(Sec)) * (Width div 2 - Width div 8)), Height div 2 + Trunc(Cos(DegToRad(Sec)) * - (Height div 2 - Height div 8)));
      MoveTo(Width div 2, Height div 2);
      Default := Pen.Width;
      Pen.Width := Pen.Width + 1;
      LineTo(Width div 2 + Trunc(Sin(DegToRad(Min)) * (Width div 2 - Width div 8)), Height div 2 + Trunc(Cos(DegToRad(Min)) * - (Height div 2 - Height div 8)));
      MoveTo(Width div 2, Height div 2);
      Pen.Width := Pen.Width + 1;
      LineTo(Width div 2 + Trunc(Sin(DegToRad(Hour)) * (Width div 3)), Height div 2 + Trunc(Cos(DegToRad(Hour)) * - (Height div 3)));
      Pen.Width := Default;
    end;
  end;
end; //TClock.FOnTimer

procedure TClock.SetBrush(AValue: TColor);
begin
  if FBrush <> AValue then
  begin
    FBrush := AValue;
    Circle;
    FOnTimer(FTimer);
  end;
end; //TClock.SetBrush

procedure TClock.SetPen(AValue: TColor);
begin

  if FPen <> AValue then
  begin
    FPen := AValue;
    Circle;
    FOnTimer(FTimer);
  end;
end; //TClock.SetPen

procedure TClock.SetPicture(AValue: TPicture);
begin
  FPicture.Assign(AValue);
  with FBack do
  begin
    Width := FImage.Width;
    Height := FImage.Height;
    Picture.Assign(FPicture);
    Stretch := TRUE;
    Circle;
    FOnTimer(FTimer);
  end;
end; //TClock.SetPicture

destructor TClock.Destroy;
begin
  FImage.Free;
  FPicture.Free;
  FBack.Free;
  FClock.Free;
  FTimer.Free;
  inherited Destroy;
end; //TClock.Destroy

[arbu man]

Schau dir mal JEDI an da ist eine richtige Uhr.

[Hansa]

Zitat:

Zitat von Mr_Anderson

...jedoch sagt mit die klasse TRect nichts. Welchen Wert erwartet man wenn man eine Variable die Klasse TRect zuweist?

Also, ich will ja nichts sagen. 8) Aber es liegt auf der Hand, daß die Delphi-Hilfe das weiß. Und "Rect" sieht doch in etwa schon wie "Rechteck" aus, oder ? Selbst wenn man die Bedeutung vom engl. "rectangle" nicht weiß. :zwinker:

[Muetze1]

Moin!

1. TRect ist nur ein Record und keine Klasse (zumindest in der alten Delphi Version die ich benutze - und ich weiss, im BCB ist es eine struct mit Methoden).
2. Du kannst ein Rechteck anstatt einzelnd die Werte zu füllen das ganze unter Benutzung der Rect() Funktion in einer Zeile füllen:

Delphi-Quellcode:

  MyRect := Rect(0, 0, 10, 10);

3. Wenn du damit die Klasse anlegen wolltest (instanziieren), dann ist das der Fehler:

Delphi-Quellcode:

test.Create(kor,Form1);

Versuchs mal lieber so:

Delphi-Quellcode:

 test := TClock.Create(kor, Form1);

4. Wenn du schon auf fremde Implementationen stehst, hier und hier noch zwei andere Komponenten.

MfG
Muetze1

[Luckie]

Und hier: http://www.luckie-online.de/Delphi/Sonstiges/ gibt es auch nochg mal eine analoge Uhr von mir.