Groß/Kleinschreibung (Pfad) Original erhalten?

[MicMic]

Hallo,
wenn ich in einer Variable "c:\windows\syswow64\" oder "c:\winDows\SYSwow64\" (als Beispiel) stehen habe, kann ich damit arbeiten aber zur Ansicht würde ich gerne die originale Groß-/Kleinschreibung nutzen. Original ist der Pfad "C:\Windows\SysWOW64".

Ich frage mich, wie ich mit einfachen Mitteln (ohne FindFirst/Next) da rankomme.
Vielleicht gibt es eine Win API Funktion die ich dafür nutzen/zweckentfremden kann?

Michael

[Papaschlumpf73]

Such mal hier im Forum nach CSIDL

[MicMic]

Zitat:

Zitat von Papaschlumpf73 (Beitrag 1411040)

Such mal hier im Forum nach CSIDL

Ist mir ein Begriff, kenne es aber nur in Verbindung mit Standard-Ordner/System-Ordner usw.
Wenn ich jetzt z.B. ein neuen Ordner anlege "C:\TeSt", würde ich gerne ohne FindFirst/Next da herankommen, sprich ich übergebe "c:\test" und bekomme "C:\TeSt" zurück.

Michael

[KodeZwerg]

Ich habs nicht getestet, vielleicht gibt Dir ExpandFileName den Namen in schön wieder?
Oder ExtractFilePath ?
Oder System.IOUtils.TPath.GetDirectoryName ?

Reines WinApi würde ich SHGetFileInfo eventuell mit PIDL verwenden, das sollte Dich auch ans Ziel bringen.

[Uwe Raabe]

Ich denke, du suchst ExpandFileNameCase

Intern wird dort aber auch auf FindFirst/FindClose zurückgegriffen.

[MicMic]

Danke für die Hilfestellung.
habe mal alles ausprobiert (ExtractFilePath, ExpandFileName, GetDirectoryName) und mit SHGetFileInfo auch herumexperimentiert.
Keine Erfolge und zu "ExpandFileNameCase"... (kannte ich noch nicht) da kann man etwas herausholen aber dennoch müsste man das Verzeichnis (z.B. "C:\Ich\bin\so\froh\wie\der\Mops\im\Hafenstroh \") splitten und in Strings aufteilen. Am Ende eines Pfads kann man noch "\." oder "\.." angeben um ein oder zwei Verzeichnisse zurück zu gehen und hier die originale Groß-/Kleinschreibung zu bekommen. Nur nicht alles auf einmal. Aber wegen diesem Splitten und stets erneuten Aufruf von FindFirst (auf die Idee bin ich nämlich auch gekommen) - was die Funktion ja macht, ist das alles nicht gerade Optimal. Naja, nicht so schlimm. Trotzdem Danke für eure Hilfestellung.

Michael

[Uwe Raabe]

Zitat:

Zitat von MicMic (Beitrag 1411061)

Keine Erfolge und zu "ExpandFileNameCase"... (kannte ich noch nicht) da kann man etwas herausholen aber dennoch müsste man das Verzeichnis (z.B. "C:\Ich\bin\so\froh\wie\der\Mops\im\Hafenstroh \") splitten und in Strings aufteilen.

Ich hatte jetzt angenommen, die Funktion tut bereits alles was du brauchst. Vielleicht habe ich die Anforderung aber auch nur falsch verstanden.

[KodeZwerg]

Habe es auch noch mit

Delphi-Quellcode:

FileCtrl.ProcessPath(s,drv,Dir,filename);

probiert, auch negativ.
Lustigerweise schlägt selbst ein FileCtrl.SelectDirectory() fehl, so ein Ergebnis hätte ich von so einer Funktion nicht erwartet. Anhang 49789

Ps, im Nachhinein ist mir auch eingefallen mit SHGetFileInfo bekommt man nur Infos, wie der Name selbst beinhaltet, nur leider nicht Deine benötigten. FindFirst() scheint wohl einzige Api zu sein, oder aus MFT auslesen.

[KodeZwerg]

Nun habe ich eine Lösung.

Delphi-Quellcode:

uses
  ActiveX, ShlObj, SHDocVw, ComObj;

function PathToPIDL(const Path: string): PItemIDList;
const
  SFGAO_STREAM = $00400000;
var
  Count: ULONG;
  Attributes: ULONG;
  ShellFolder: IShellFolder;
begin
  OleCheck(SHGetDesktopFolder(ShellFolder));
  Attributes := SFGAO_FOLDER or SFGAO_STREAM;
  OleCheck(ShellFolder.ParseDisplayName(0, nil, PWideChar(WideString(Path)), Count, Result, Attributes));
  if not ((Attributes and SFGAO_FOLDER = SFGAO_FOLDER) and (Attributes and SFGAO_STREAM <> SFGAO_STREAM)) then
   begin
     CoTaskMemFree(Result);
     raise Exception.Create('Could not convert string to PIDL');
   end;
end;

function PIDLToPath(const PIDL: PItemIDList): string;
var
  Path: array[0..Max_Path] of Char;
begin
  if ShGetPathFromIDList(PIDL, Path) then
   Result := Path
   else raise Exception.Create('Could not convert PIDL to string');
end;

procedure TfrmMain.FormCreate(Sender: TObject);
var
  s: string;
  PIDL: PItemIDList;
begin
  s := 'c:\uSERs\PUBlic\DeskTop';
  PIDL := PathToPIDL(s);
  s := PIDLToPath(PIDL);
  Memo1.Lines.Add(S);
end;

Zitat:

C:\Users\Public\Desktop

Viel Spass damit.

ps: Bearbeite das Uses, kann sein das da zuviel steht.

[MicMic]

Danke @KodeZwerg
Geht SUPER. Dankeschön

Habe noch zwei Fragen. Im "if not" Bereich steht "CoTaskMemFree". Sonst nicht.
Sollte es nicht so oder so ausgeführt werden? Aber es ist ja hier ein "Result" was ja gebraucht wird.

Dann kenne ich das "WideString" gar nicht. Bei "PWideChar(WideString(Path))". Ich mach sonst immer ein "PWideChar(Path)". Das geht auch aber was ist der Unterschied? Da ist mir sowieso noch etwas im Gedächtnis. Bin mir da nicht sicher, aber glaube gelesen zu haben das man bei PWideChar(stringvariable) noch ein "#0" dazutun soll. Also PWideChar(stringvariable+#0). Kann das sein?

Ich habe jedenfalls mal folgende Funktion aus den beiden gemacht. OleCheck kenne ich auch nicht und habe es mal Anhand ähnlicher Funktionen die ich nutze abgeändert. Dabei ist folgendes herausgekommen. Hier wird dann "CoTaskMemFree" auch stets freigegeben und im jeden Fehlerfall einfach der übergebene Pfad wieder zurückgegeben. Ein nachfolgender Attribut-Check der beiden "SFGAO_..." Flags habe ich auch weggelassen, da ich denke, dass dies nicht mehr nötig ist, wenn es bei der Funktion "ParseDisplayName" gesetzt wurde. Das ist aber weniger ein technisches Verständnis, eher so eine Überlegung :)

Code:

Function PathToCS(Const Path: UnicodeString): UnicodeString;
Var
  Count: ULONG;
  Attrs: ULONG;
  ShellFolder: IShellFolder;
  Pa: Array[0..Max_Path] Of Char;
  Pidl: PItemIDList;
Begin
  Attrs := SFGAO_FOLDER or SFGAO_STREAM;
  Count := 0;
  If SHGetDesktopFolder(ShellFolder) = S_OK Then
  Begin
    If ShellFolder.ParseDisplayName(0,Nil,PWideChar(Path),Count,Pidl,Attrs) = S_OK Then
    Begin
      If SHGetPathFromIDList(Pidl, Pa)
        Then Result := IncludeTrailingPathDelimiter(Pa)
        Else Result := IncludeTrailingPathDelimiter(Path);
      CoTaskMemFree(Pidl);
    End Else Result := IncludeTrailingPathDelimiter(Path);
  End Else  Result := IncludeTrailingPathDelimiter(Path);
End;

Gruß Michael

[KodeZwerg]

Zitat:

Zitat von MicMic (Beitrag 1411073)

Danke @KodeZwerg
Geht SUPER. Dankeschön

Gern geschehen, meine Priorität lag halt anders, deswegen auf zwei Funktionen verteilt.
Solange es das macht was Du möchtest ist ja alles im grünen Bereich :lol:

[KodeZwerg]

Zitat:

Zitat von MicMic (Beitrag 1411073)

Habe noch zwei Fragen. Im "if not" Bereich steht "CoTaskMemFree". Sonst nicht.
Sollte es nicht so oder so ausgeführt werden? Aber es ist ja hier ein "Result" was ja gebraucht wird.

Bei mir ist es richtig im Einsatz. Ich will damit bewusst das Result löschen.

Zitat:

Zitat von MicMic (Beitrag 1411073)

Dann kenne ich das "WideString" gar nicht. Bei "PWideChar(WideString(Path))".

Das garantiert mir das 16bit verwendet wird für Unicode characters conversion.

Ps:
Mag sein das neuere Delphi Version all das anders handhaben oder schon Routinen dafür besitzen. Für D2009 sollte das gelten was ich schrieb.

[Luckie]

Nur, bei der Lösung kannst du nie Prüfen, ob die Funktion nicht fehlgeschlagen ist. OK, mag nicht so wichtig sein, da es sich wohl nur um eine optische Spielerei handelt. Aber ich wollte es nur mal erwähnt haben. ;)

[KodeZwerg]

Zitat:

Zitat von Luckie (Beitrag 1411088)

Nur, bei der Lösung kannst du nie Prüfen, ob die Funktion nicht fehlgeschlagen ist. OK, mag nicht so wichtig sein, da es sich wohl nur um eine optische Spielerei handelt. Aber ich wollte es nur mal erwähnt haben. ;)

Hallo Luckie,
wenn sich das auf meinen Vorschlag bezieht, eigentlich sollte der nur zwei mögliche Resultate liefern. Entweder ein verwertbares oder eine Exception.
ps: Man kann auch Result als Boolean auswerten und in Functiom (var DasResult:Typ) definieren.

[MicMic]

@KodeZwerg... danke für die Info zum WideString.
@Luckie... Ja, die originale Groß-Kleinschreibung dient nur zur Ansicht. Deswegen keine weitere Fehlerbehandlung. Wenn's halt nicht geht, bleibt der Pfad halt so, wie er zuvor angegeben wurde.

Deswegen habe ich auch aus den zwei Funktionen (die ich ja nicht schlecht mache), eine gebaut. Ist ja dann auch einfach anzugeben "path := PathToCS(path);" So passt das für meine Zwecke ganz gut.

Also nochmals vielen Dank

Michael

[MicMic]

Zitat:

Zitat von KodeZwerg (Beitrag 1411065)

Nun habe ich eine Lösung.

Delphi-Quellcode:

uses
  ActiveX, ShlObj, SHDocVw, ComObj;

function PathToPIDL(const Path: string): PItemIDList;
const
  SFGAO_STREAM = $00400000;
var
  Count: ULONG;
  Attributes: ULONG;
  ShellFolder: IShellFolder;
begin
  OleCheck(SHGetDesktopFolder(ShellFolder));
  Attributes := SFGAO_FOLDER or SFGAO_STREAM;
  OleCheck(ShellFolder.ParseDisplayName(0, nil, PWideChar(WideString(Path)), Count, Result, Attributes));
  if not ((Attributes and SFGAO_FOLDER = SFGAO_FOLDER) and (Attributes and SFGAO_STREAM <> SFGAO_STREAM)) then
   begin
     CoTaskMemFree(Result);
     raise Exception.Create('Could not convert string to PIDL');
   end;
end;

function PIDLToPath(const PIDL: PItemIDList): string;
var
  Path: array[0..Max_Path] of Char;
begin
  if ShGetPathFromIDList(PIDL, Path) then
   Result := Path
   else raise Exception.Create('Could not convert PIDL to string');
end;

procedure TfrmMain.FormCreate(Sender: TObject);
var
  s: string;
  PIDL: PItemIDList;
begin
  s := 'c:\uSERs\PUBlic\DeskTop';
  PIDL := PathToPIDL(s);
  s := PIDLToPath(PIDL);
  Memo1.Lines.Add(S);
end;

Zitat:

C:\Users\Public\Desktop

Viel Spass damit.

ps: Bearbeite das Uses, kann sein das da zuviel steht.

Hallo, wenn du dich erinnern kannst...
An der Funktion (bzw. an meine Funktion die ich entsprechend für meine Bedürfnisse abgeändert habe <- nachfolgender Code), bin ich gerade noch am rumwerkeln.

Code:

Function PathToCS(Const Path: UnicodeString): UnicodeString;
Var
  Count: ULONG;
  Attrs: ULONG;
  ShellFolder: IShellFolder;
  Pa: Array[0..Max_Path] Of Char;
  Pidl: PItemIDList;
Begin
  Attrs := SFGAO_FOLDER or SFGAO_STREAM;
  Count := 0;
  If SHGetDesktopFolder(ShellFolder) = S_OK Then
  Begin
    If ShellFolder.ParseDisplayName(0,Nil,PWideChar(Path),Count,Pidl,Attrs) = S_OK Then
    Begin
      If SHGetPathFromIDList(Pidl, Pa)
        Then Result := IncludeTrailingPathDelimiter(Pa)
        Else Result := IncludeTrailingPathDelimiter(Path);
      CoTaskMemFree(Pidl);
    End Else Result := IncludeTrailingPathDelimiter(Path);
  End Else Result := IncludeTrailingPathDelimiter(Path);
End;

Ich probiere nämlich bei langen Verzeichnissen dies auch so zu lösen. Versuche mich an "SHGetPathFromIDListW" (anstatt "SHGetPathFromIDList" (ohne W)). Aber was ich auch mache, sobald mehr als 260 (glaub ich) Zeichen im Pfad sind (z.B. C:\Test\UnterOrdner\Unter\ganzvielunter\...\...\.. .), bekomme ich kurze Pfade zurück geliefert. Also z.B. diese "ICHGEH~1" verkürzten Namen. Hier im Pfad am Anfang "\\?\" anzuhängen klappt erst recht nicht.

Meine Versuche für den 2. Parameter für "SHGetPathFromIDListW":

Code:

Var Pa: PWideChar; // zuvor "Array[0..Max_Path] Of Char;"

const
  NTFS_MAX_PATH = 32767;

GetMem(Pa, (NTFS_MAX_PATH + 1) * 2);

If SHGetPathFromIDListW (Pidl, Pa)
...

Aber so geht das einfach nicht.

Vielleicht hast du (oder jemand anderes) eine Idee?

Micha

[KodeZwerg]

Ne, soviele Unterordner habe ich noch nicht getestet, hier zwei Funktionen um aus nem legitimen 8.3 wieder was langes zurück zu erhalten, ohne FindFirst() aufzurufen.

Delphi-Quellcode:

uses Windows, SysUtils, ActiveX, ShlObj;

Was zuviel ist, wirf raus.

Passend zum ersten PIDL Beispiel, hier ein weiteres

Delphi-Quellcode:

function LongPathFromShort(const ShortPath: string): string;
var
  iAttributes: Cardinal;
  iEaten: Cardinal;
  IntfDesktop: IShellFolder;
  IntfMalloc: IMalloc;
  pItemList: PItemIDList;
  sFile: WideString;
  szFile: array[0..MAX_PATH] of Char;
begin
  Result := ShortPath;
  if not FileExists(ShortPath) then
    Exit;
  if Succeeded(SHGetDesktopFolder(IntfDesktop)) then
  begin
    sFile := ShortPath;
    iAttributes := 0;
    if Succeeded(IntfDesktop.ParseDisplayName(0, nil, POleStr(sFile),
      iEaten, pItemList, iAttributes)) then
    begin
      SHGetPathFromIDList(pItemList, szFile);
      Result := szFile;
      SHGetMalloc(IntfMalloc);
      IntfMalloc.Free(pItemList)
    end
  end
end;

Oder lieber per WinApi:

Delphi-Quellcode:

function GetLongName(const APath: string): string;
var
  Buffer: array[0..MAX_PATH] of Char;
  Required: Integer;
begin
  Required := GetLongPathName(PChar(APath), Buffer, Length(Buffer));
  if Required > MAX_PATH then {Buffer too small}
  begin
    SetLength(Result, Required - 1);
    GetLongPathName(PChar(APath), Pointer(Result), Required);
  end
  else if Required = 0 then {Error}
    Result := APath
  else
    SetString(Result, Buffer, Required);
end;

Ich habe es nicht mit extrem langen/tiefen Ordner-Namen getestet, bei mir machts jedenfalls das was es soll, 8.3 entfalten.

[MicMic]

Danke KodeZwerg. Daran hatte ich auch schon gedacht aber wollte mal schauen ob sich's auch gleich lösen lässt. Zum Glück brauch ich dies nur für ein Programmstart. Dann ist es auch nicht so schlimm, wenn sie kurz werden und man sie wieder lang machen muss. Hab die API Version mal kurz getestet. Die andere noch nicht. Grad wenig Zeit für's programmieren. Also vielen Dank für die Hilfe. Micha